mirror of
https://git.savannah.gnu.org/git/emacs.git
synced 2024-12-12 09:28:24 +00:00
f463633f00
Also remove various redundant `:group` arguments. * lisp/erc/erc-backend.el (define-erc-response-handler): Move `declare` after the docstring. * lisp/erc/erc-capab.el: Use lexical-binding. (erc-capab-identify-activate): Simplify with `member`. * lisp/erc/erc-dcc.el (erc-dcc): Move before erc-dcc-mode definition, which refers to it. (erc-dcc-chat-accept): Remove unused vars `nick` and `buffer`. * lisp/erc/erc-imenu.el: Use lexical-binding. (erc-create-imenu-index): Remove unused var `prev-pos`. * lisp/erc/erc-match.el: Use lexical-binding. (erc-match-message): Remove unused var `old-pt`. (erc-match-message): Strength-reduce `eval` to `symbol-value`. * lisp/erc/erc-page.el: Use lexical-binding. (erc-page): Move Custom group before `erg-page-mode` which refers to it. * lisp/erc/erc-replace.el: Use lexical-binding. (erc-replace-insert): Use `functionp`. * lisp/erc/erc-status-sidebar.el: Use lexical-binding. (erc-status-sidebar-open): Remove unused var `sidebar-window`. * lisp/erc/erc.el: Fix header to use the customary 3 semi-colons. (erc-fill-column): Declare variable. * lisp/erc/erc-autoaway.el: Use lexical-binding. * lisp/erc/erc-ezbounce.el: Use lexical-binding. * lisp/erc/erc-fill.el: Use lexical-binding. * lisp/erc/erc-goodies.el: Use lexical-binding. * lisp/erc/erc-ibuffer.el: Use lexical-binding. * lisp/erc/erc-identd.el: Use lexical-binding. * lisp/erc/erc-join.el: Use lexical-binding. * lisp/erc/erc-lang.el: Use lexical-binding. * lisp/erc/erc-log.el: Use lexical-binding. * lisp/erc/erc-menu.el: Use lexical-binding. * lisp/erc/erc-netsplit.el: Use lexical-binding. * lisp/erc/erc-networks.el: Use lexical-binding. * lisp/erc/erc-pcomplete.el: Use lexical-binding. * lisp/erc/erc-ring.el: Use lexical-binding. * lisp/erc/erc-speedbar.el: Use lexical-binding. * lisp/erc/erc-spelling.el: Use lexical-binding. * lisp/erc/erc-truncate.el: Use lexical-binding. * lisp/erc/erc-xdcc.el: Use lexical-binding.
119 lines
4.0 KiB
EmacsLisp
119 lines
4.0 KiB
EmacsLisp
;;; erc-identd.el --- RFC1413 (identd authentication protocol) server -*- lexical-binding: t; -*-
|
|
|
|
;; Copyright (C) 2003, 2006-2021 Free Software Foundation, Inc.
|
|
|
|
;; Author: John Wiegley <johnw@gnu.org>
|
|
;; Maintainer: Amin Bandali <bandali@gnu.org>
|
|
;; Keywords: comm
|
|
|
|
;; This file is part of GNU Emacs.
|
|
|
|
;; GNU Emacs is free software: you can redistribute it and/or modify
|
|
;; it under the terms of the GNU General Public License as published by
|
|
;; the Free Software Foundation, either version 3 of the License, or
|
|
;; (at your option) any later version.
|
|
|
|
;; GNU Emacs is distributed in the hope that it will be useful,
|
|
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
;; GNU General Public License for more details.
|
|
|
|
;; You should have received a copy of the GNU General Public License
|
|
;; along with GNU Emacs. If not, see <https://www.gnu.org/licenses/>.
|
|
|
|
;;; Commentary:
|
|
|
|
;; This module allows you to run a local identd server on port 8113.
|
|
;; You will need to set up DNAT to bind 113->8113, or use a proxy.
|
|
|
|
;; To use this module, add identd to `erc-modules' and run
|
|
;; `erc-update-modules'.
|
|
|
|
;; Here is an example /etc/inetd.conf rule that forwards identd
|
|
;; traffic to port 8113. You will need simpleproxy installed for it
|
|
;; to work.
|
|
|
|
;; 113 stream tcp nowait nobody /usr/sbin/tcpd /usr/bin/simpleproxy simpleproxy -i -R 127.0.0.1:8113
|
|
|
|
;;; Code:
|
|
|
|
(require 'erc)
|
|
|
|
(defvar erc-identd-process nil)
|
|
|
|
(defgroup erc-identd nil
|
|
"Run a local identd server."
|
|
:group 'erc)
|
|
|
|
(defcustom erc-identd-port 8113
|
|
"Port to run the identd server on if not specified in the argument for
|
|
`erc-identd-start'.
|
|
|
|
This can be either a string or a number."
|
|
:type '(choice (const :tag "None" nil)
|
|
(integer :tag "Port number")
|
|
(string :tag "Port string")))
|
|
|
|
;;;###autoload(autoload 'erc-identd-mode "erc-identd")
|
|
(define-erc-module identd nil
|
|
"This mode launches an identd server on port 8113."
|
|
((add-hook 'erc-connect-pre-hook #'erc-identd-quickstart)
|
|
(add-hook 'erc-disconnected-hook #'erc-identd-stop))
|
|
((remove-hook 'erc-connect-pre-hook #'erc-identd-quickstart)
|
|
(remove-hook 'erc-disconnected-hook #'erc-identd-stop)))
|
|
|
|
(defun erc-identd-filter (proc string)
|
|
"This filter implements RFC1413 (identd authentication protocol)."
|
|
(let ((erc-identd-process proc))
|
|
(when (string-match "\\([0-9]+\\)\\s-*,\\s-*\\([0-9]+\\)" string)
|
|
(let ((port-on-server (match-string 1 string))
|
|
(port-on-client (match-string 2 string)))
|
|
(send-string erc-identd-process
|
|
(format "%s, %s : USERID : %s : %s\n"
|
|
port-on-server port-on-client
|
|
system-type (user-login-name)))
|
|
(stop-process erc-identd-process)
|
|
(delete-process proc)))))
|
|
|
|
;;;###autoload
|
|
(defun erc-identd-start (&optional port)
|
|
"Start an identd server listening to port 8113.
|
|
Port 113 (auth) will need to be redirected to port 8113 on your
|
|
machine -- using iptables, or a program like redir which can be
|
|
run from inetd. The idea is to provide a simple identd server
|
|
when you need one, without having to install one globally on your
|
|
system."
|
|
(interactive (list (read-string "Serve identd requests on port: " "8113")))
|
|
(unless port (setq port erc-identd-port))
|
|
(when (stringp port)
|
|
(setq port (string-to-number port)))
|
|
(when erc-identd-process
|
|
(delete-process erc-identd-process))
|
|
(setq erc-identd-process
|
|
(make-network-process :name "identd"
|
|
:buffer nil
|
|
:host 'local :service port
|
|
:server t :noquery t :nowait t
|
|
:filter #'erc-identd-filter))
|
|
(set-process-query-on-exit-flag erc-identd-process nil))
|
|
|
|
(defun erc-identd-quickstart (&rest _ignored)
|
|
"Start the identd server with the default port.
|
|
The default port is specified by `erc-identd-port'."
|
|
(erc-identd-start))
|
|
|
|
;;;###autoload
|
|
(defun erc-identd-stop (&rest _ignore)
|
|
(interactive)
|
|
(when erc-identd-process
|
|
(delete-process erc-identd-process)
|
|
(setq erc-identd-process nil)))
|
|
|
|
(provide 'erc-identd)
|
|
|
|
;;; erc-identd.el ends here
|
|
;;
|
|
;; Local Variables:
|
|
;; generated-autoload-file: "erc-loaddefs.el"
|
|
;; End:
|