mirror of
https://git.savannah.gnu.org/git/emacs.git
synced 2024-11-29 07:58:28 +00:00
ecf08f0621
dc4e6b1329; Update copyright years in more files64b3777631; Run set-copyright from admin.el8e1c56ae46; Add 2024 to copyright years # Conflicts: # doc/misc/modus-themes.org # doc/misc/texinfo.tex # etc/NEWS # etc/refcards/ru-refcard.tex # etc/themes/modus-operandi-theme.el # etc/themes/modus-themes.el # etc/themes/modus-vivendi-theme.el # lib/alloca.in.h # lib/binary-io.h # lib/c-ctype.h # lib/c-strcasecmp.c # lib/c-strncasecmp.c # lib/careadlinkat.c # lib/cloexec.c # lib/close-stream.c # lib/diffseq.h # lib/dup2.c # lib/filemode.h # lib/fpending.c # lib/fpending.h # lib/fsusage.c # lib/getgroups.c # lib/getloadavg.c # lib/gettext.h # lib/gettime.c # lib/gettimeofday.c # lib/group-member.c # lib/malloc.c # lib/md5-stream.c # lib/md5.c # lib/md5.h # lib/memmem.c # lib/memrchr.c # lib/nanosleep.c # lib/save-cwd.h # lib/sha1.c # lib/sig2str.c # lib/stdlib.in.h # lib/strtoimax.c # lib/strtol.c # lib/strtoll.c # lib/time_r.c # lib/xalloc-oversized.h # lisp/auth-source-pass.el # lisp/emacs-lisp/lisp-mnt.el # lisp/emacs-lisp/timer.el # lisp/info-look.el # lisp/jit-lock.el # lisp/loadhist.el # lisp/mail/rmail.el # lisp/net/ntlm.el # lisp/net/webjump.el # lisp/progmodes/asm-mode.el # lisp/progmodes/project.el # lisp/progmodes/sh-script.el # lisp/textmodes/flyspell.el # lisp/textmodes/reftex-toc.el # lisp/textmodes/reftex.el # lisp/textmodes/tex-mode.el # lisp/url/url-gw.el # m4/alloca.m4 # m4/clock_time.m4 # m4/d-type.m4 # m4/dirent_h.m4 # m4/dup2.m4 # m4/euidaccess.m4 # m4/fchmodat.m4 # m4/filemode.m4 # m4/fsusage.m4 # m4/getgroups.m4 # m4/getloadavg.m4 # m4/getrandom.m4 # m4/gettime.m4 # m4/gettimeofday.m4 # m4/gnulib-common.m4 # m4/group-member.m4 # m4/inttypes.m4 # m4/malloc.m4 # m4/manywarnings.m4 # m4/mempcpy.m4 # m4/memrchr.m4 # m4/mkostemp.m4 # m4/mktime.m4 # m4/nproc.m4 # m4/nstrftime.m4 # m4/pathmax.m4 # m4/pipe2.m4 # m4/pselect.m4 # m4/pthread_sigmask.m4 # m4/readlink.m4 # m4/realloc.m4 # m4/sig2str.m4 # m4/ssize_t.m4 # m4/stat-time.m4 # m4/stddef_h.m4 # m4/stdint.m4 # m4/stdio_h.m4 # m4/stdlib_h.m4 # m4/stpcpy.m4 # m4/strnlen.m4 # m4/strtoimax.m4 # m4/strtoll.m4 # m4/time_h.m4 # m4/timegm.m4 # m4/timer_time.m4 # m4/timespec.m4 # m4/unistd_h.m4 # m4/warnings.m4 # nt/configure.bat # nt/preprep.c # test/lisp/register-tests.el
246 lines
9.3 KiB
EmacsLisp
246 lines
9.3 KiB
EmacsLisp
;;; version.el --- record version number of Emacs -*- lexical-binding:t -*-
|
||
|
||
;; Copyright (C) 1985, 1992, 1994-1995, 1999-2024 Free Software
|
||
;; Foundation, Inc.
|
||
|
||
;; Maintainer: emacs-devel@gnu.org
|
||
;; Keywords: internal
|
||
;; Package: emacs
|
||
|
||
;; This file is part of GNU Emacs.
|
||
|
||
;; GNU Emacs is free software: you can redistribute it and/or modify
|
||
;; it under the terms of the GNU General Public License as published by
|
||
;; the Free Software Foundation, either version 3 of the License, or
|
||
;; (at your option) any later version.
|
||
|
||
;; GNU Emacs is distributed in the hope that it will be useful,
|
||
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
||
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
||
;; GNU General Public License for more details.
|
||
|
||
;; You should have received a copy of the GNU General Public License
|
||
;; along with GNU Emacs. If not, see <https://www.gnu.org/licenses/>.
|
||
|
||
;;; Commentary:
|
||
|
||
;;; Code:
|
||
|
||
|
||
|
||
(defun android-read-build-system ()
|
||
"Obtain the host name of the system on which Emacs was built.
|
||
Use the data stored in the special file `/assets/build_info'.
|
||
Value is the string ``Unknown'' upon failure, else the hostname
|
||
of the build system."
|
||
(with-temp-buffer
|
||
(insert-file-contents "/assets/build_info")
|
||
(let ((string (buffer-substring 1 (line-end-position))))
|
||
(and (not (equal string "Unknown")) string))))
|
||
|
||
(defun android-read-build-time ()
|
||
"Obtain the time at which Emacs was built.
|
||
Use the data stored in the special file `/assets/build_info'.
|
||
Value is nil upon failure, else the time in the same format as
|
||
returned by `current-time'."
|
||
(with-temp-buffer
|
||
(insert-file-contents "/assets/build_info")
|
||
(end-of-line)
|
||
(let ((number (read (current-buffer))))
|
||
(time-convert number 'list))))
|
||
|
||
|
||
|
||
(defconst emacs-major-version
|
||
(progn (string-match "^[0-9]+" emacs-version)
|
||
(string-to-number (match-string 0 emacs-version)))
|
||
"Major version number of this version of Emacs.")
|
||
|
||
(defconst emacs-minor-version
|
||
(progn (string-match "^[0-9]+\\.\\([0-9]+\\)" emacs-version)
|
||
(string-to-number (match-string 1 emacs-version)))
|
||
"Minor version number of this version of Emacs.")
|
||
|
||
;; N.B. (featurep 'android) is tested for in addition to
|
||
;; `system-type', because that can also be Android on a TTY-only
|
||
;; Android build that doesn't employ the window system packaging
|
||
;; support. (bug#65319)
|
||
(defconst emacs-build-system (or (and (featurep 'android)
|
||
(eq system-type 'android)
|
||
(android-read-build-system))
|
||
(system-name))
|
||
"Name of the system on which Emacs was built, or nil if not available.")
|
||
|
||
(defconst emacs-build-time (if emacs-build-system
|
||
(or (and (featurep 'android)
|
||
(eq system-type 'android)
|
||
(android-read-build-time))
|
||
(current-time)))
|
||
"Time at which Emacs was dumped out, or nil if not available.")
|
||
|
||
(defconst emacs-build-number 1 ; loadup.el may increment this
|
||
"The build number of this version of Emacs.
|
||
This is an integer that increments each time Emacs is built in a given
|
||
directory (without cleaning). This is likely to only be relevant when
|
||
developing Emacs.")
|
||
|
||
(defvar motif-version-string)
|
||
(defvar gtk-version-string)
|
||
(defvar ns-version-string)
|
||
(defvar cairo-version-string)
|
||
|
||
(declare-function haiku-get-version-string "haikufns.c")
|
||
|
||
(defun emacs-version (&optional here)
|
||
"Display the version of Emacs that is running in this session.
|
||
With a prefix argument, insert the Emacs version string at point
|
||
instead of displaying it.
|
||
If called from Lisp, by default return the version string; but
|
||
if the optional argument HERE is non-nil, insert the string at
|
||
point instead.
|
||
|
||
Don't use this function in programs to choose actions according
|
||
to the system configuration; look at `system-configuration' instead."
|
||
(interactive "P")
|
||
(let ((version-string
|
||
(format "GNU Emacs %s (build %s, %s%s%s%s)%s"
|
||
emacs-version
|
||
emacs-build-number
|
||
system-configuration
|
||
(cond ((featurep 'motif)
|
||
(concat ", " (substring motif-version-string 4)))
|
||
((featurep 'gtk)
|
||
(concat ", GTK+ Version " gtk-version-string))
|
||
((featurep 'x-toolkit) ", X toolkit")
|
||
((featurep 'ns)
|
||
(format ", NS %s" ns-version-string))
|
||
((featurep 'haiku)
|
||
(format ", Haiku %s" (haiku-get-version-string)))
|
||
(t ""))
|
||
(if (featurep 'cairo)
|
||
(format ", cairo version %s" cairo-version-string)
|
||
"")
|
||
(if (and (boundp 'x-toolkit-scroll-bars)
|
||
(memq x-toolkit-scroll-bars '(xaw xaw3d)))
|
||
(format ", %s scroll bars"
|
||
(capitalize (symbol-name x-toolkit-scroll-bars)))
|
||
"")
|
||
(if emacs-build-time
|
||
(format-time-string (concat
|
||
(if (called-interactively-p
|
||
'interactive)
|
||
"" "\n")
|
||
" of %Y-%m-%d")
|
||
emacs-build-time)
|
||
""))))
|
||
(if here
|
||
(insert version-string)
|
||
(if (called-interactively-p 'interactive)
|
||
(message "%s" version-string)
|
||
version-string))))
|
||
|
||
;; We hope that this alias is easier for people to find.
|
||
(defalias 'version 'emacs-version)
|
||
|
||
(define-obsolete-variable-alias 'emacs-bzr-version
|
||
'emacs-repository-version "24.4")
|
||
|
||
;; Set during dumping, this is a defvar so that it can be setq'd.
|
||
(defvar emacs-repository-version nil
|
||
"String giving the repository revision from which this Emacs was built.
|
||
Value is nil if Emacs was not built from a repository checkout,
|
||
or if we could not determine the revision.")
|
||
|
||
(define-obsolete-function-alias 'emacs-bzr-get-version
|
||
'emacs-repository-get-version "24.4")
|
||
|
||
(defun emacs-repository-version-git (dir)
|
||
"Ask git itself for the version information for directory DIR."
|
||
(message "Waiting for git...")
|
||
(with-temp-buffer
|
||
(let ((default-directory (file-name-as-directory dir)))
|
||
(and (eq 0
|
||
(with-demoted-errors "Error running git rev-parse: %S"
|
||
(call-process "git" nil '(t nil) nil "rev-parse" "HEAD")))
|
||
(progn (goto-char (point-min))
|
||
(looking-at "[[:xdigit:]]\\{40\\}"))
|
||
(match-string 0)))))
|
||
|
||
(defun emacs-repository-version-android ()
|
||
"Return the Emacs repository revision Emacs was built from.
|
||
Value is nil if Emacs was not built from a repository checkout.
|
||
Use information from the `/assets/version' special file."
|
||
(with-temp-buffer
|
||
(insert-file-contents "/assets/version")
|
||
(let ((string (buffer-substring 1 (line-end-position))))
|
||
(and (not (equal string "Unknown")) string))))
|
||
|
||
(defun emacs-repository-get-version (&optional dir _external)
|
||
"Try to return as a string the repository revision of the Emacs sources.
|
||
The format of the returned string is dependent on the VCS in use.
|
||
|
||
If Emacs is built for Android, use the version information
|
||
embedded in the Emacs installation package.
|
||
|
||
Value is nil if the sources do not seem to be under version
|
||
control, or if we could not determine the revision. Note that
|
||
this reports on the current state of the sources, which may not
|
||
correspond to the running Emacs.
|
||
|
||
Optional argument DIR is a directory to use instead of `source-directory'.
|
||
Optional argument EXTERNAL is ignored."
|
||
(cond ((and (featurep 'android)
|
||
(eq system-type 'android))
|
||
(emacs-repository-version-android))
|
||
(t (emacs-repository-version-git
|
||
(or dir source-directory)))))
|
||
|
||
(defvar emacs-repository-branch nil
|
||
"String giving the repository branch from which this Emacs was built.
|
||
Value is nil if Emacs was not built from a repository checkout,
|
||
or if we could not determine the branch.")
|
||
|
||
(defun emacs-repository-branch-android ()
|
||
"Return the Emacs repository branch Emacs was built from.
|
||
Value is nil if Emacs was not built from a repository checkout.
|
||
Use information from the `/assets/version' special file."
|
||
(with-temp-buffer
|
||
(insert-file-contents "/assets/version")
|
||
(end-of-line)
|
||
(forward-char)
|
||
(let ((string (buffer-substring (point) (line-end-position))))
|
||
(and (not (equal string "Unknown")) string))))
|
||
|
||
(defun emacs-repository-branch-git (dir)
|
||
"Ask git itself for the branch information for directory DIR."
|
||
(message "Waiting for git...")
|
||
(with-temp-buffer
|
||
(let ((default-directory (file-name-as-directory dir)))
|
||
(and (zerop
|
||
(with-demoted-errors "Error running git rev-parse --abbrev-ref: %S"
|
||
(call-process "git" nil '(t nil) nil
|
||
"rev-parse" "--abbrev-ref" "HEAD")))
|
||
(goto-char (point-min))
|
||
(buffer-substring (point) (line-end-position))))))
|
||
|
||
(defun emacs-repository-get-branch (&optional dir)
|
||
"Try to return as a string the repository branch of the Emacs sources.
|
||
The format of the returned string is dependent on the VCS in use.
|
||
|
||
If Emacs is built for Android, use the version information
|
||
embedded in the Emacs installation package.
|
||
|
||
Value is nil if the sources do not seem to be under version
|
||
control, or if we could not determine the branch. Note that
|
||
this reports on the current state of the sources, which may not
|
||
correspond to the running Emacs.
|
||
|
||
Optional argument DIR is a directory to use instead of `source-directory'."
|
||
(cond ((and (featurep 'android)
|
||
(eq system-type 'android))
|
||
(emacs-repository-branch-android))
|
||
(t (emacs-repository-branch-git
|
||
(or dir source-directory)))))
|
||
|
||
;;; version.el ends here
|