mirror of
https://git.savannah.gnu.org/git/emacs.git
synced 2024-11-30 08:09:04 +00:00
eba5b4dd16
* cus-edit.el (processes): Remove from development group. (oop, hypermedia): Delete group. (net): New group. * url/url-vars.el (url): * net/browse-url.el (browse-url): * net/xesam.el (xesam): * net/tramp.el (tramp): * net/goto-addr.el (goto-address): * net/ange-ftp.el (ange-ftp): Put in net group. * view.el (view): Remove from editing group. * uniquify.el (uniquify): Put in files group. * net/browse-url.el (browse-url): * ps-print.el (postscript): Put in external group. * cus-edit.el (outlines): * textmodes/text-mode.el (text-mode-hook): * textmodes/table.el (table): * textmodes/picture.el (picture): * outline.el (outlines): Put in wp group. * nxml/nxml-mode.el (nxml): Remove from wp group. * net/tramp-imap.el (tramp-imap): Put in tramp group. * mail/metamail.el (metamail): Remove from hypermedia group. * cus-edit.el (abbrev): * whitespace.el (whitespace): * vcursor.el (vcursor): * reveal.el (reveal): * hl-line.el (hl-line): Put in convenience group. * epg-config.el (epg): Put in data group. * emulation/pc-select.el (pc-select): Put in emulations group. * calculator.el (calculator): Put in applications group. * org/org.el (org): Remove from hypermedia group.
230 lines
9.6 KiB
EmacsLisp
230 lines
9.6 KiB
EmacsLisp
;;; reveal.el --- Automatically reveal hidden text at point
|
|
|
|
;; Copyright (C) 2000, 2001, 2002, 2003, 2004,
|
|
;; 2005, 2006, 2007, 2008, 2009, 2010 Free Software Foundation, Inc.
|
|
|
|
;; Author: Stefan Monnier <monnier@iro.umontreal.ca>
|
|
;; Keywords: outlines
|
|
|
|
;; This file is part of GNU Emacs.
|
|
|
|
;; GNU Emacs is free software: you can redistribute it and/or modify
|
|
;; it under the terms of the GNU General Public License as published by
|
|
;; the Free Software Foundation, either version 3 of the License, or
|
|
;; (at your option) any later version.
|
|
|
|
;; GNU Emacs is distributed in the hope that it will be useful,
|
|
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
;; GNU General Public License for more details.
|
|
|
|
;; You should have received a copy of the GNU General Public License
|
|
;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>.
|
|
|
|
;;; Commentary:
|
|
|
|
;; Reveal mode is a minor mode that makes sure that text around point
|
|
;; is always visible. When point enters a region of hidden text,
|
|
;; `reveal-mode' temporarily makes it visible.
|
|
;;
|
|
;; This is normally used in conjunction with `outline-minor-mode',
|
|
;; `hs-minor-mode', `hide-ifdef-mode', ...
|
|
;;
|
|
;; It only works with packages that hide text using overlays.
|
|
;; Packages can provide special support for it by placing
|
|
;; a function in the `reveal-toggle-invisible' property on the symbol
|
|
;; used as the value of the `invisible' overlay property.
|
|
;; The function is called right after revealing (or re-hiding) the
|
|
;; text with two arguments: the overlay and a boolean that's non-nil
|
|
;; if we have just revealed the text. When revealing, that function
|
|
;; may re-hide some of the text.
|
|
|
|
;;; Todo:
|
|
|
|
;; - find other hysteresis features.
|
|
;; - don't hide after a scroll command
|
|
;; - delay hiding by a couple seconds (i.e. hide in the background)
|
|
|
|
;;; Code:
|
|
|
|
(defgroup reveal nil
|
|
"Reveal hidden text on the fly."
|
|
:group 'convenience)
|
|
|
|
(defcustom reveal-around-mark t
|
|
"Reveal text around the mark, if active."
|
|
:type 'boolean
|
|
:group 'reveal)
|
|
|
|
(defvar reveal-open-spots nil
|
|
"List of spots in the buffer which are open.
|
|
Each element has the form (WINDOW . OVERLAY).")
|
|
(make-variable-buffer-local 'reveal-open-spots)
|
|
|
|
(defvar reveal-last-tick nil)
|
|
(make-variable-buffer-local 'reveal-last-tick)
|
|
|
|
;; Actual code
|
|
|
|
(defun reveal-post-command ()
|
|
;; Refresh the spots that might have changed.
|
|
;; `Refreshing' here means to try and re-hide the corresponding text.
|
|
;; We don't refresh everything correctly:
|
|
;; - we only refresh spots in the current window.
|
|
;; FIXME: do we actually know that (current-buffer) = (window-buffer) ?
|
|
(with-local-quit
|
|
(condition-case err
|
|
(let ((old-ols
|
|
(delq nil
|
|
(mapcar
|
|
(lambda (x)
|
|
;; We refresh any spot in the current window as well
|
|
;; as any spots associated with a dead window or
|
|
;; a window which does not show this buffer any more.
|
|
(cond
|
|
((eq (car x) (selected-window)) (cdr x))
|
|
((not (and (window-live-p (car x))
|
|
(eq (window-buffer (car x)) (current-buffer))))
|
|
;; Adopt this since it's owned by a window that's
|
|
;; either not live or at least not showing this
|
|
;; buffer any more.
|
|
(setcar x (selected-window))
|
|
(cdr x))))
|
|
reveal-open-spots))))
|
|
(setq old-ols (reveal-open-new-overlays old-ols))
|
|
(reveal-close-old-overlays old-ols))
|
|
(error (message "Reveal: %s" err)))))
|
|
|
|
(defun reveal-open-new-overlays (old-ols)
|
|
(let ((repeat t))
|
|
(while repeat
|
|
(setq repeat nil)
|
|
(dolist (ol (nconc (when (and reveal-around-mark mark-active)
|
|
(overlays-at (mark)))
|
|
(overlays-at (point))))
|
|
(setq old-ols (delq ol old-ols))
|
|
(when (overlay-start ol) ;Check it's still live.
|
|
(let ((inv (overlay-get ol 'invisible)) open)
|
|
(when (and inv
|
|
;; There's an `invisible' property. Make sure it's
|
|
;; actually invisible, and ellipsised.
|
|
(and (consp buffer-invisibility-spec)
|
|
(cdr (assq inv buffer-invisibility-spec)))
|
|
(or (setq open
|
|
(or (overlay-get ol 'reveal-toggle-invisible)
|
|
(and (symbolp inv)
|
|
(get inv 'reveal-toggle-invisible))
|
|
(overlay-get ol 'isearch-open-invisible-temporary)))
|
|
(overlay-get ol 'isearch-open-invisible)
|
|
(and (consp buffer-invisibility-spec)
|
|
(cdr (assq inv buffer-invisibility-spec))))
|
|
(overlay-put ol 'reveal-invisible inv))
|
|
(push (cons (selected-window) ol) reveal-open-spots)
|
|
(if (null open)
|
|
(overlay-put ol 'invisible nil)
|
|
;; Use the provided opening function and repeat (since the
|
|
;; opening function might have hidden a subpart around point
|
|
;; or moved/killed some of the overlays).
|
|
(setq repeat t)
|
|
(condition-case err
|
|
(funcall open ol nil)
|
|
(error (message "!!Reveal-show (funcall %s %s nil): %s !!"
|
|
open ol err)
|
|
;; Let's default to a meaningful behavior to avoid
|
|
;; getting stuck in an infinite loop.
|
|
(setq repeat nil)
|
|
(overlay-put ol 'invisible nil))))))))))
|
|
old-ols)
|
|
|
|
(defun reveal-close-old-overlays (old-ols)
|
|
(if (not (eq reveal-last-tick
|
|
(setq reveal-last-tick (buffer-modified-tick))))
|
|
;; The buffer was modified since last command: let's refrain from
|
|
;; closing any overlay because it tends to behave poorly when
|
|
;; inserting text at the end of an overlay (basically the overlay
|
|
;; should be rear-advance when it's open, but things like
|
|
;; outline-minor-mode make it non-rear-advance because it's
|
|
;; a better choice when it's closed).
|
|
nil
|
|
;; The last command was only a point motion or some such
|
|
;; non-buffer-modifying command. Let's close whatever can be closed.
|
|
(dolist (ol old-ols)
|
|
(if (and (overlay-start ol) ;Check it's still live.
|
|
(>= (point) (save-excursion
|
|
(goto-char (overlay-start ol))
|
|
(line-beginning-position 1)))
|
|
(<= (point) (save-excursion
|
|
(goto-char (overlay-end ol))
|
|
(line-beginning-position 2)))
|
|
;; If the application has moved the overlay to some other
|
|
;; buffer, we'd better reset the buffer to its
|
|
;; original state.
|
|
(eq (current-buffer) (overlay-buffer ol)))
|
|
;; Still near the overlay: keep it open.
|
|
nil
|
|
;; Really close it.
|
|
(let* ((inv (overlay-get ol 'reveal-invisible))
|
|
(open (or (overlay-get ol 'reveal-toggle-invisible)
|
|
(get inv 'reveal-toggle-invisible)
|
|
(overlay-get ol 'isearch-open-invisible-temporary))))
|
|
(if (and (overlay-start ol) ;Check it's still live.
|
|
open)
|
|
(condition-case err
|
|
(funcall open ol t)
|
|
(error (message "!!Reveal-hide (funcall %s %s t): %s !!"
|
|
open ol err)))
|
|
(overlay-put ol 'invisible inv))
|
|
;; Remove the overlay from the list of open spots.
|
|
(overlay-put ol 'reveal-invisible nil)
|
|
(setq reveal-open-spots
|
|
(delq (rassoc ol reveal-open-spots)
|
|
reveal-open-spots)))))))
|
|
|
|
(defvar reveal-mode-map
|
|
(let ((map (make-sparse-keymap)))
|
|
;; Override the default move-beginning-of-line and move-end-of-line
|
|
;; which skips valuable invisible text.
|
|
(define-key map [remap move-beginning-of-line] 'beginning-of-line)
|
|
(define-key map [remap move-end-of-line] 'end-of-line)
|
|
map))
|
|
|
|
;;;###autoload
|
|
(define-minor-mode reveal-mode
|
|
"Toggle Reveal mode on or off.
|
|
Reveal mode renders invisible text around point visible again.
|
|
|
|
Interactively, with no prefix argument, toggle the mode.
|
|
With universal prefix ARG (or if ARG is nil) turn mode on.
|
|
With zero or negative ARG turn mode off."
|
|
:group 'reveal
|
|
:lighter (global-reveal-mode nil " Reveal")
|
|
:keymap reveal-mode-map
|
|
(if reveal-mode
|
|
(progn
|
|
(set (make-local-variable 'search-invisible) t)
|
|
(add-hook 'post-command-hook 'reveal-post-command nil t))
|
|
(kill-local-variable 'search-invisible)
|
|
(remove-hook 'post-command-hook 'reveal-post-command t)))
|
|
|
|
;;;###autoload
|
|
(define-minor-mode global-reveal-mode
|
|
"Toggle Reveal mode in all buffers on or off.
|
|
Reveal mode renders invisible text around point visible again.
|
|
|
|
Interactively, with no prefix argument, toggle the mode.
|
|
With universal prefix ARG (or if ARG is nil) turn mode on.
|
|
With zero or negative ARG turn mode off."
|
|
:global t :group 'reveal
|
|
(setq-default reveal-mode global-reveal-mode)
|
|
(if global-reveal-mode
|
|
(progn
|
|
(setq search-invisible t)
|
|
(add-hook 'post-command-hook 'reveal-post-command))
|
|
(setq search-invisible 'open) ;FIXME
|
|
(remove-hook 'post-command-hook 'reveal-post-command)))
|
|
|
|
(provide 'reveal)
|
|
|
|
;; arch-tag: 96ba0242-2274-4ed7-8e10-26bc0707b4d8
|
|
;;; reveal.el ends here
|