mirror of
https://git.savannah.gnu.org/git/emacs.git
synced 2024-11-29 07:58:28 +00:00
ecf08f0621
dc4e6b1329; Update copyright years in more files64b3777631; Run set-copyright from admin.el8e1c56ae46; Add 2024 to copyright years # Conflicts: # doc/misc/modus-themes.org # doc/misc/texinfo.tex # etc/NEWS # etc/refcards/ru-refcard.tex # etc/themes/modus-operandi-theme.el # etc/themes/modus-themes.el # etc/themes/modus-vivendi-theme.el # lib/alloca.in.h # lib/binary-io.h # lib/c-ctype.h # lib/c-strcasecmp.c # lib/c-strncasecmp.c # lib/careadlinkat.c # lib/cloexec.c # lib/close-stream.c # lib/diffseq.h # lib/dup2.c # lib/filemode.h # lib/fpending.c # lib/fpending.h # lib/fsusage.c # lib/getgroups.c # lib/getloadavg.c # lib/gettext.h # lib/gettime.c # lib/gettimeofday.c # lib/group-member.c # lib/malloc.c # lib/md5-stream.c # lib/md5.c # lib/md5.h # lib/memmem.c # lib/memrchr.c # lib/nanosleep.c # lib/save-cwd.h # lib/sha1.c # lib/sig2str.c # lib/stdlib.in.h # lib/strtoimax.c # lib/strtol.c # lib/strtoll.c # lib/time_r.c # lib/xalloc-oversized.h # lisp/auth-source-pass.el # lisp/emacs-lisp/lisp-mnt.el # lisp/emacs-lisp/timer.el # lisp/info-look.el # lisp/jit-lock.el # lisp/loadhist.el # lisp/mail/rmail.el # lisp/net/ntlm.el # lisp/net/webjump.el # lisp/progmodes/asm-mode.el # lisp/progmodes/project.el # lisp/progmodes/sh-script.el # lisp/textmodes/flyspell.el # lisp/textmodes/reftex-toc.el # lisp/textmodes/reftex.el # lisp/textmodes/tex-mode.el # lisp/url/url-gw.el # m4/alloca.m4 # m4/clock_time.m4 # m4/d-type.m4 # m4/dirent_h.m4 # m4/dup2.m4 # m4/euidaccess.m4 # m4/fchmodat.m4 # m4/filemode.m4 # m4/fsusage.m4 # m4/getgroups.m4 # m4/getloadavg.m4 # m4/getrandom.m4 # m4/gettime.m4 # m4/gettimeofday.m4 # m4/gnulib-common.m4 # m4/group-member.m4 # m4/inttypes.m4 # m4/malloc.m4 # m4/manywarnings.m4 # m4/mempcpy.m4 # m4/memrchr.m4 # m4/mkostemp.m4 # m4/mktime.m4 # m4/nproc.m4 # m4/nstrftime.m4 # m4/pathmax.m4 # m4/pipe2.m4 # m4/pselect.m4 # m4/pthread_sigmask.m4 # m4/readlink.m4 # m4/realloc.m4 # m4/sig2str.m4 # m4/ssize_t.m4 # m4/stat-time.m4 # m4/stddef_h.m4 # m4/stdint.m4 # m4/stdio_h.m4 # m4/stdlib_h.m4 # m4/stpcpy.m4 # m4/strnlen.m4 # m4/strtoimax.m4 # m4/strtoll.m4 # m4/time_h.m4 # m4/timegm.m4 # m4/timer_time.m4 # m4/timespec.m4 # m4/unistd_h.m4 # m4/warnings.m4 # nt/configure.bat # nt/preprep.c # test/lisp/register-tests.el
55 lines
1.7 KiB
Plaintext
55 lines
1.7 KiB
Plaintext
dnl Check whether limits.h has needed features.
|
|
|
|
dnl Copyright 2016-2024 Free Software Foundation, Inc.
|
|
dnl This file is free software; the Free Software Foundation
|
|
dnl gives unlimited permission to copy and/or distribute it,
|
|
dnl with or without modifications, as long as this notice is preserved.
|
|
|
|
dnl From Paul Eggert.
|
|
|
|
AC_DEFUN_ONCE([gl_LIMITS_H],
|
|
[
|
|
gl_CHECK_NEXT_HEADERS([limits.h])
|
|
|
|
AC_CACHE_CHECK([whether limits.h has WORD_BIT, BOOL_WIDTH etc.],
|
|
[gl_cv_header_limits_width],
|
|
[AC_COMPILE_IFELSE(
|
|
[AC_LANG_PROGRAM(
|
|
[[#ifndef __STDC_WANT_IEC_60559_BFP_EXT__
|
|
#define __STDC_WANT_IEC_60559_BFP_EXT__ 1
|
|
#endif
|
|
#include <limits.h>
|
|
long long llm = LLONG_MAX;
|
|
int wb = WORD_BIT;
|
|
int ullw = ULLONG_WIDTH;
|
|
int bw = BOOL_WIDTH;
|
|
int bm = BOOL_MAX;
|
|
int mblm = MB_LEN_MAX;
|
|
]])],
|
|
[gl_cv_header_limits_width=yes],
|
|
[gl_cv_header_limits_width=no])])
|
|
GL_GENERATE_LIMITS_H=true
|
|
AS_IF([test "$gl_cv_header_limits_width" = yes],
|
|
[AC_CACHE_CHECK([whether limits.h has SSIZE_MAX],
|
|
[gl_cv_header_limits_ssize_max],
|
|
[AC_COMPILE_IFELSE(
|
|
[AC_LANG_SOURCE(
|
|
[[#include <limits.h>
|
|
#ifndef SSIZE_MAX
|
|
#error "SSIZE_MAX is not defined"
|
|
#endif
|
|
]])],
|
|
[gl_cv_header_limits_ssize_max=yes],
|
|
[gl_cv_header_limits_ssize_max=no])])
|
|
if test "$gl_cv_header_limits_ssize_max" = yes; then
|
|
GL_GENERATE_LIMITS_H=false
|
|
fi])
|
|
])
|
|
|
|
dnl Unconditionally enables the replacement of <limits.h>.
|
|
AC_DEFUN([gl_REPLACE_LIMITS_H],
|
|
[
|
|
AC_REQUIRE([gl_LIMITS_H])
|
|
GL_GENERATE_LIMITS_H=true
|
|
])
|