mirror of
https://git.savannah.gnu.org/git/emacs.git
synced 2024-11-30 08:09:04 +00:00
f9caea8233
It's not safe to call qsort or qsort_r, since they have undefined behavior if the user-specified predicate is not a total order. Also, watch out for garbage-collection while sorting vectors. * admin/merge-gnulib (GNULIB_MODULES): Add vla. * configure.ac (qsort_r): Remove, as we no longer use qsort-like functions. * lib/gnulib.mk, m4/gnulib-comp.m4: Regenerate. * lib/vla.h, m4/vararrays.m4: New files, copied from gnulib. * lib/stdlib.in.h, m4/stdlib_h.m4: Sync from gnulib, incorporating: 2014-08-29 qsort_r: new module, for GNU-style qsort_r The previous two files' changes are boilerplate generated by admin/merge-gnulib, and should not affect Emacs. * src/fns.c: Include <vla.h>. (sort_vector_predicate) [!HAVE_QSORT_R]: Remove. (sort_vector_compare): Remove, replacing with .... (inorder, merge_vectors, sort_vector_inplace, sort_vector_copy): ... these new functions. (sort_vector): Rewrite to use the new functions. GCPRO locals, since the predicate can invoke the GC. Since it's in-place return void; caller changed. (merge): Use 'inorder', for clarity. Fixes: debbugs:18361
69 lines
1.9 KiB
Plaintext
69 lines
1.9 KiB
Plaintext
# Check for variable-length arrays.
|
|
|
|
# serial 5
|
|
|
|
# From Paul Eggert
|
|
|
|
# Copyright (C) 2001, 2009-2014 Free Software Foundation, Inc.
|
|
# This file is free software; the Free Software Foundation
|
|
# gives unlimited permission to copy and/or distribute it,
|
|
# with or without modifications, as long as this notice is preserved.
|
|
|
|
# This is a copy of AC_C_VARARRAYS from a recent development version
|
|
# of Autoconf. It replaces Autoconf's version, or for pre-2.61 autoconf
|
|
# it defines the macro that Autoconf lacks.
|
|
AC_DEFUN([AC_C_VARARRAYS],
|
|
[
|
|
AC_CACHE_CHECK([for variable-length arrays],
|
|
ac_cv_c_vararrays,
|
|
[AC_EGREP_CPP([defined],
|
|
[#ifdef __STDC_NO_VLA__
|
|
defined
|
|
#endif
|
|
],
|
|
[ac_cv_c_vararrays='no: __STDC_NO_VLA__ is defined'],
|
|
[AC_COMPILE_IFELSE(
|
|
[AC_LANG_PROGRAM(
|
|
[[/* Test for VLA support. This test is partly inspired
|
|
from examples in the C standard. Use at least two VLA
|
|
functions to detect the GCC 3.4.3 bug described in:
|
|
http://lists.gnu.org/archive/html/bug-gnulib/2014-08/msg00014.html
|
|
*/
|
|
#ifdef __STDC_NO_VLA__
|
|
syntax error;
|
|
#else
|
|
extern int n;
|
|
int B[100];
|
|
int fvla (int m, int C[m][m]);
|
|
|
|
int
|
|
simple (int count, int all[static count])
|
|
{
|
|
return all[count - 1];
|
|
}
|
|
|
|
int
|
|
fvla (int m, int C[m][m])
|
|
{
|
|
typedef int VLA[m][m];
|
|
VLA x;
|
|
int D[m];
|
|
static int (*q)[m] = &B;
|
|
int (*s)[n] = q;
|
|
return C && &x[0][0] == &D[0] && &D[0] == s[0];
|
|
}
|
|
#endif
|
|
]])],
|
|
[ac_cv_c_vararrays=yes],
|
|
[ac_cv_c_vararrays=no])])])
|
|
if test "$ac_cv_c_vararrays" = yes; then
|
|
dnl This is for compatibility with Autoconf 2.61-2.69.
|
|
AC_DEFINE([HAVE_C_VARARRAYS], 1,
|
|
[Define to 1 if C supports variable-length arrays.])
|
|
elif test "$ac_cv_c_vararrays" = no; then
|
|
AC_DEFINE([__STDC_NO_VLA__], 1,
|
|
[Define to 1 if C does not support variable-length arrays, and
|
|
if the compiler does not already define this.])
|
|
fi
|
|
])
|