mirror of
https://git.savannah.gnu.org/git/emacs.git
synced 2024-11-23 07:19:15 +00:00
27e6afeb6f
This incorporates: 2015-04-24 file-has-acl: new module, split from acl 2015-04-24 manywarnings: add GCC 5.1 warnings 2015-04-21 lstat: fix cross-compilation 'ln -s' problem 2015-04-15 qacl: Simplify HP-UX acl_nontrivial check 2015-04-15 acl: On Linux, check for acls without libacl 2015-04-14 tempname: avoid unused parameter warnings (trivial) * lib/acl-internal.c: New file, from gnulib. * lib/file-has-acl.c: Remove; no longer imported from gnulib. * lib/acl-internal.h, lib/gnulib.mk, lib/qcopy-acl.c, lib/tempname.c: * m4/acl.m4, m4/gnulib-comp.m4, m4/lstat.m4, m4/manywarnings.m4: Update from gnulib.
72 lines
2.4 KiB
Plaintext
72 lines
2.4 KiB
Plaintext
# serial 27
|
|
|
|
# Copyright (C) 1997-2001, 2003-2015 Free Software Foundation, Inc.
|
|
#
|
|
# This file is free software; the Free Software Foundation
|
|
# gives unlimited permission to copy and/or distribute it,
|
|
# with or without modifications, as long as this notice is preserved.
|
|
|
|
dnl From Jim Meyering.
|
|
|
|
AC_DEFUN([gl_FUNC_LSTAT],
|
|
[
|
|
AC_REQUIRE([gl_SYS_STAT_H_DEFAULTS])
|
|
dnl If lstat does not exist, the replacement <sys/stat.h> does
|
|
dnl "#define lstat stat", and lstat.c is a no-op.
|
|
AC_CHECK_FUNCS_ONCE([lstat])
|
|
if test $ac_cv_func_lstat = yes; then
|
|
AC_REQUIRE([gl_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK])
|
|
case "$gl_cv_func_lstat_dereferences_slashed_symlink" in
|
|
*no)
|
|
REPLACE_LSTAT=1
|
|
;;
|
|
esac
|
|
else
|
|
HAVE_LSTAT=0
|
|
fi
|
|
])
|
|
|
|
# Prerequisites of lib/lstat.c.
|
|
AC_DEFUN([gl_PREREQ_LSTAT], [:])
|
|
|
|
AC_DEFUN([gl_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK],
|
|
[
|
|
dnl We don't use AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK any more, because it
|
|
dnl is no longer maintained in Autoconf and because it invokes AC_LIBOBJ.
|
|
AC_CACHE_CHECK([whether lstat correctly handles trailing slash],
|
|
[gl_cv_func_lstat_dereferences_slashed_symlink],
|
|
[rm -f conftest.sym conftest.file
|
|
echo >conftest.file
|
|
AC_RUN_IFELSE(
|
|
[AC_LANG_PROGRAM(
|
|
[AC_INCLUDES_DEFAULT],
|
|
[[struct stat sbuf;
|
|
if (symlink ("conftest.file", "conftest.sym") != 0)
|
|
return 1;
|
|
/* Linux will dereference the symlink and fail, as required by
|
|
POSIX. That is better in the sense that it means we will not
|
|
have to compile and use the lstat wrapper. */
|
|
return lstat ("conftest.sym/", &sbuf) == 0;
|
|
]])],
|
|
[gl_cv_func_lstat_dereferences_slashed_symlink=yes],
|
|
[gl_cv_func_lstat_dereferences_slashed_symlink=no],
|
|
[case "$host_os" in
|
|
*-gnu*)
|
|
# Guess yes on glibc systems.
|
|
gl_cv_func_lstat_dereferences_slashed_symlink="guessing yes" ;;
|
|
*)
|
|
# If we don't know, assume the worst.
|
|
gl_cv_func_lstat_dereferences_slashed_symlink="guessing no" ;;
|
|
esac
|
|
])
|
|
rm -f conftest.sym conftest.file
|
|
])
|
|
case "$gl_cv_func_lstat_dereferences_slashed_symlink" in
|
|
*yes)
|
|
AC_DEFINE_UNQUOTED([LSTAT_FOLLOWS_SLASHED_SYMLINK], [1],
|
|
[Define to 1 if 'lstat' dereferences a symlink specified
|
|
with a trailing slash.])
|
|
;;
|
|
esac
|
|
])
|