{
  config,
  lib,
  pkgs,
  ...
}:
{
  imports = [ ];

  config = lib.mkMerge [
    { }
    (lib.mkIf (!config.me.buildingIso) {
      nix.settings.system-features = lib.mkForce [
        "gccarch-alderlake"
        "gccarch-x86-64-v3"
        "benchmark"
        "big-parallel"
        "kvm"
        "nixos-test"
      ];

      # nixpkgs.hostPlatform = {
      #   gcc.arch = "alderlake";
      #   gcc.tune = "alderlake";
      #   system = "x86_64-linux";

      # };

      nixpkgs.overlays = [
        (
          self: super:
          let
            optimizeWithFlags =
              pkg: flags:
              pkg.overrideAttrs (old: {
                NIX_CFLAGS_COMPILE = [ (old.NIX_CFLAGS_COMPILE or "") ] ++ flags;
              });
            addConfig =
              additionalConfig: pkg:
              pkg.override (oldconfig: {
                structuredExtraConfig = pkg.structuredExtraConfig // additionalConfig;
              });
          in
          {
            linux_alderlake =
              addConfig
                {
                  # Full preemption
                  PREEMPT = lib.mkOverride 60 lib.kernel.yes;
                  PREEMPT_VOLUNTARY = lib.mkOverride 60 lib.kernel.no;

                  # Google's BBRv3 TCP congestion Control
                  TCP_CONG_BBR = lib.kernel.yes;
                  DEFAULT_BBR = lib.kernel.yes;

                  # Preemptive Full Tickless Kernel at 300Hz
                  HZ = lib.kernel.freeform "300";
                  HZ_300 = lib.kernel.yes;
                  HZ_1000 = lib.kernel.no;
                }
                (
                  optimizeWithFlags super.linux_6_12 [
                    "-march=alderlake"
                    "-mtune=alderlake"
                  ]
                );
          }
        )
      ];

      boot.kernelPackages = pkgs.linuxPackagesFor pkgs.linux_alderlake;
    })
    (lib.mkIf (config.me.buildingIso) {
      boot.kernelPackages = pkgs.linuxPackagesFor pkgs.linux_6_12;
      boot.supportedFilesystems = [ "zfs" ];
    })
  ];
}