diff --git a/pkgs/by-name/gn/gnunet-messenger-cli/package.nix b/pkgs/by-name/gn/gnunet-messenger-cli/package.nix
new file mode 100644
index 000000000000..9db6de9f2a34
--- /dev/null
+++ b/pkgs/by-name/gn/gnunet-messenger-cli/package.nix
@@ -0,0 +1,56 @@
+{
+  lib,
+  stdenv,
+  fetchgit,
+  meson,
+  ninja,
+  pkg-config,
+  gnunet,
+  libsodium,
+  libgcrypt,
+  libgnunetchat,
+  ncurses,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "gnunet-messenger-cli";
+  version = "0.3.1";
+
+  src = fetchgit {
+    url = "https://git.gnunet.org/messenger-cli.git";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-8Iby3IZXEZJ1dqVV62xDzXx/qq7JKhVtn6ZLb697ZSw=";
+  };
+
+  env.INSTALL_DIR = (placeholder "out") + "/";
+
+  strictDeps = true;
+
+  nativeBuildInputs = [
+    meson
+    ninja
+    pkg-config
+  ];
+
+  buildInputs = [
+    gnunet
+    libgcrypt
+    libgnunetchat
+    libsodium
+    ncurses
+  ];
+
+  preInstall = "mkdir -p $out/bin";
+
+  preFixup = "mv $out/bin/messenger-cli $out/bin/gnunet-messenger-cli";
+
+  meta = {
+    description = "Decentralized, privacy-preserving networking framework for secure peer-to-peer communication";
+    homepage = "https://git.gnunet.org/messenger-cli.git";
+    license = lib.licenses.gpl3Plus;
+    platforms = lib.platforms.all;
+    teams = with lib.teams; [ ngi ];
+    maintainers = [ lib.maintainers.ethancedwards8 ];
+    mainProgram = "gnunet-messenger-cli";
+  };
+})
diff --git a/pkgs/by-name/li/libgnunetchat/package.nix b/pkgs/by-name/li/libgnunetchat/package.nix
new file mode 100644
index 000000000000..f5803786bb60
--- /dev/null
+++ b/pkgs/by-name/li/libgnunetchat/package.nix
@@ -0,0 +1,59 @@
+{
+  lib,
+  stdenv,
+  fetchgit,
+  meson,
+  ninja,
+  pkg-config,
+  validatePkgConfig,
+  testers,
+  check,
+  gnunet,
+  libsodium,
+  libgcrypt,
+  libextractor,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  name = "libgnunetchat";
+  version = "0.5.3";
+
+  src = fetchgit {
+    url = "https://git.gnunet.org/libgnunetchat.git";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-DhXPYa8ya9cEbwa4btQTrpjfoTGhzBInWXXH4gmDAQw=";
+  };
+
+  strictDeps = true;
+
+  nativeBuildInputs = [
+    meson
+    ninja
+    pkg-config
+    validatePkgConfig
+  ];
+
+  buildInputs = [
+    check
+    gnunet
+    libextractor
+    libgcrypt
+    libsodium
+  ];
+
+  env.INSTALL_DIR = (placeholder "out") + "/";
+
+  prePatch = "mkdir -p $out/lib";
+
+  passthru.tests.pkg-config = testers.testMetaPkgConfig finalAttrs.finalPackage;
+
+  meta = {
+    pkgConfigModules = [ "gnunetchat" ];
+    description = "Library for secure, decentralized chat using GNUnet network services";
+    homepage = "https://git.gnunet.org/libgnunetchat.git";
+    license = lib.licenses.gpl3Plus;
+    platforms = lib.platforms.all;
+    teams = with lib.teams; [ ngi ];
+    maintainers = [ lib.maintainers.ethancedwards8 ];
+  };
+})