From 8c6d63ee38d833d9c977bcf0d37ebee2bdb3d117 Mon Sep 17 00:00:00 2001
From: ccicnce113424 <ccicnce113424@gmail.com>
Date: Thu, 26 Jun 2025 05:40:00 +0800
Subject: [PATCH 1/2] maintainers: add ccicnce113424

---
 maintainers/maintainer-list.nix | 7 +++++++
 1 file changed, 7 insertions(+)

diff --git a/maintainers/maintainer-list.nix b/maintainers/maintainer-list.nix
index 940d7a59b496..d77b63b652db 100644
--- a/maintainers/maintainer-list.nix
+++ b/maintainers/maintainer-list.nix
@@ -4293,6 +4293,13 @@
     githubId = 44584960;
     name = "Denis Khalmatov";
   };
+  ccicnce113424 = {
+    email = "ccicnce113424@gmail.com";
+    matrix = "@ccicnce113424:matrix.org";
+    github = "ccicnce113424";
+    githubId = 30774232;
+    name = "ccicnce113424";
+  };
   cdepillabout = {
     email = "cdep.illabout@gmail.com";
     matrix = "@cdepillabout:matrix.org";

From 6bff9c905f17ed12ee237e557c404b9c5f039d0d Mon Sep 17 00:00:00 2001
From: ccicnce113424 <ccicnce113424@gmail.com>
Date: Thu, 26 Jun 2025 06:06:23 +0800
Subject: [PATCH 2/2] splayer: init at 3.0.0-beta.1

---
 pkgs/by-name/sp/splayer/package.nix | 108 ++++++++++++++++++++++++++++
 1 file changed, 108 insertions(+)
 create mode 100644 pkgs/by-name/sp/splayer/package.nix

diff --git a/pkgs/by-name/sp/splayer/package.nix b/pkgs/by-name/sp/splayer/package.nix
new file mode 100644
index 000000000000..5f1c45c4f2db
--- /dev/null
+++ b/pkgs/by-name/sp/splayer/package.nix
@@ -0,0 +1,108 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  pnpm_10,
+  nodejs,
+  electron,
+  makeWrapper,
+  copyDesktopItems,
+  makeDesktopItem,
+  nix-update-script,
+}:
+stdenv.mkDerivation (final: {
+  pname = "splayer";
+  version = "3.0.0-beta.1";
+
+  src = fetchFromGitHub {
+    owner = "imsyy";
+    repo = "SPlayer";
+    tag = "v${final.version}";
+    fetchSubmodules = false;
+    hash = "sha256-Sw5L474gowpOVkIc3CHWVEzknMgJvBmtNXRCxzwY8BA=";
+  };
+
+  pnpm = pnpm_10;
+
+  pnpmDeps = final.pnpm.fetchDeps {
+    inherit (final) pname version src;
+    hash = "sha256-mC1iJtkZpTd2Vte5DLI3ntZ7vSO5Gka2qOk7ihQd3Gs=";
+  };
+
+  nativeBuildInputs = [
+    final.pnpm.configHook
+    nodejs
+    makeWrapper
+    copyDesktopItems
+  ];
+
+  env.ELECTRON_SKIP_BINARY_DOWNLOAD = "1";
+
+  postConfigure = ''
+    cp .env.example .env
+  '';
+
+  buildPhase = ''
+    runHook preBuild
+
+    pnpm build
+
+    npm exec electron-builder -- \
+        --dir \
+        --config electron-builder.yml \
+        -c.electronDist=${electron.dist} \
+        -c.electronVersion=${electron.version}
+
+    runHook postBuild
+  '';
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p "$out/share/splayer"
+    cp -Pr --no-preserve=ownership dist/*-unpacked/{locales,resources{,.pak}} $out/share/splayer
+
+    _icon_sizes=(16x16 32x32 96x96 192x192 256x256 512x512)
+    for _icons in "''${_icon_sizes[@]}";do
+      install -D public/icons/favicon-$_icons.png $out/share/icons/hicolor/$_icons/apps/splayer.png
+    done
+
+    makeWrapper '${lib.getExe electron}' "$out/bin/splayer" \
+      --add-flags $out/share/splayer/resources/app.asar \
+      --add-flags "\''${NIXOS_OZONE_WL:+\''${WAYLAND_DISPLAY:+--ozone-platform-hint=auto --enable-features=WaylandWindowDecorations --enable-wayland-ime=true --wayland-text-input-version=3}}" \
+      --set-default ELECTRON_FORCE_IS_PACKAGED 1 \
+      --set-default ELECTRON_IS_DEV 0 \
+      --inherit-argv0
+
+    runHook postInstall
+  '';
+
+  desktopItems = [
+    (makeDesktopItem {
+      name = "splayer";
+      desktopName = "SPlayer";
+      exec = "splayer %U";
+      terminal = false;
+      type = "Application";
+      icon = "splayer";
+      startupWMClass = "SPlayer";
+      comment = "A minimalist music player";
+      categories = [
+        "AudioVideo"
+        "Audio"
+        "Music"
+      ];
+    })
+  ];
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "Simple Netease Cloud Music player";
+    homepage = "https://github.com/imsyy/SPlayer";
+    license = lib.licenses.agpl3Only;
+    maintainers = with lib.maintainers; [ ccicnce113424 ];
+    mainProgram = "splayer";
+    platforms = lib.platforms.linux;
+  };
+})