From e168f650dbaef030e73d29a1103e710266431826 Mon Sep 17 00:00:00 2001
From: Defelo <mail@defelo.de>
Date: Sat, 15 Feb 2025 15:43:30 +0100
Subject: [PATCH] koto: init at 0.15.2

---
 pkgs/by-name/ko/koto/package.nix | 44 ++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)
 create mode 100644 pkgs/by-name/ko/koto/package.nix

diff --git a/pkgs/by-name/ko/koto/package.nix b/pkgs/by-name/ko/koto/package.nix
new file mode 100644
index 000000000000..2708409d2dec
--- /dev/null
+++ b/pkgs/by-name/ko/koto/package.nix
@@ -0,0 +1,44 @@
+{
+  lib,
+  rustPlatform,
+  fetchFromGitHub,
+  yq,
+  versionCheckHook,
+  nix-update-script,
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "koto";
+  version = "0.15.2";
+
+  src = fetchFromGitHub {
+    owner = "koto-lang";
+    repo = "koto";
+    tag = "v${version}";
+    hash = "sha256-T8SjNeoTANAcT+uAdgzBRMK0LbC038cpKFoCFHgsp8k=";
+  };
+
+  useFetchCargoVendor = true;
+  cargoHash = "sha256-kIjDY27ot1dN3L8TKaBEQWDzo7+QIFvhdmi1YN9TofI=";
+
+  postPatch = ''
+    ${lib.getExe' yq "tomlq"} -ti 'del(.bench)' crates/koto/Cargo.toml
+  '';
+
+  cargoBuildFlags = [ "--package=koto_cli" ];
+
+  nativeInstallCheckInputs = [ versionCheckHook ];
+  versionCheckProgramArg = "--version";
+  doInstallCheck = true;
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "Simple, expressive, embeddable programming language";
+    homepage = "https://github.com/koto-lang/koto";
+    changelog = "https://github.com/koto-lang/koto/blob/${src.rev}/CHANGELOG.md";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ defelo ];
+    mainProgram = "koto";
+  };
+}