a19cd4ffb1
This reverts commit 65a333600d5c88a98d674f637d092807cfc12253. This wasn't tested for correctness with something like fodwatch [0], and should not have been (self-)merged so quickly, especially without further review. It also resulted in the breakage of at least one package [1] (and that's the one we know of and was caught). A few packages that were updated in between this commit and this revert were not reverted back to using `rev`, but other than that, this is a 1:1 revert. [0]: https://codeberg.org/raphaelr/fodwatch [1]: https://github.com/NixOS/nixpkgs/pull/396904 / 758551e4587d75882aebc21a04bee960418f8ce9
52 lines
1.2 KiB
Nix
52 lines
1.2 KiB
Nix
{
|
|
lib,
|
|
stdenv,
|
|
fetchFromGitHub,
|
|
kernel,
|
|
}:
|
|
let
|
|
version = "1.0.17";
|
|
hash = "sha256-9/t+Mvfnq0KkPbe1mnrVy4mzNaK7vAgLuhUnOeEvBfI=";
|
|
in
|
|
stdenv.mkDerivation {
|
|
name = "system76-module-${version}-${kernel.version}";
|
|
|
|
passthru.moduleName = "system76";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "pop-os";
|
|
repo = "system76-dkms";
|
|
rev = version;
|
|
inherit hash;
|
|
};
|
|
|
|
hardeningDisable = [ "pic" ];
|
|
|
|
nativeBuildInputs = kernel.moduleBuildDependencies;
|
|
|
|
buildFlags = [
|
|
"KERNEL_DIR=${kernel.dev}/lib/modules/${kernel.modDirVersion}/build"
|
|
];
|
|
|
|
installPhase = ''
|
|
install -D system76.ko $out/lib/modules/${kernel.modDirVersion}/misc/system76.ko
|
|
mkdir -p $out/lib/udev/hwdb.d
|
|
mv lib/udev/hwdb.d/* $out/lib/udev/hwdb.d
|
|
'';
|
|
|
|
meta = {
|
|
maintainers = with lib.maintainers; [ ahoneybun ];
|
|
license = [ lib.licenses.gpl2Plus ];
|
|
platforms = [
|
|
"i686-linux"
|
|
"x86_64-linux"
|
|
];
|
|
description = "System76 DKMS driver";
|
|
homepage = "https://github.com/pop-os/system76-dkms";
|
|
longDescription = ''
|
|
The System76 DKMS driver. On newer System76 laptops, this driver controls
|
|
some of the hotkeys and allows for custom fan control.
|
|
'';
|
|
};
|
|
}
|