a19cd4ffb1
This reverts commit 65a333600d5c88a98d674f637d092807cfc12253. This wasn't tested for correctness with something like fodwatch [0], and should not have been (self-)merged so quickly, especially without further review. It also resulted in the breakage of at least one package [1] (and that's the one we know of and was caught). A few packages that were updated in between this commit and this revert were not reverted back to using `rev`, but other than that, this is a 1:1 revert. [0]: https://codeberg.org/raphaelr/fodwatch [1]: https://github.com/NixOS/nixpkgs/pull/396904 / 758551e4587d75882aebc21a04bee960418f8ce9
65 lines
1.9 KiB
Nix
65 lines
1.9 KiB
Nix
{
|
|
lib,
|
|
buildPythonPackage,
|
|
fetchFromGitHub,
|
|
setuptools,
|
|
cython,
|
|
tree-sitter,
|
|
pytestCheckHook,
|
|
python,
|
|
}:
|
|
|
|
buildPythonPackage rec {
|
|
pname = "tree-sitter-languages";
|
|
version = "1.10.2";
|
|
pyproject = true;
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "grantjenks";
|
|
repo = "py-tree-sitter-languages";
|
|
rev = "v${version}";
|
|
hash = "sha256-wKU2c8QRBKFVFqg+DAeH5+cwm5jpDLmPZG3YBUsh/lM=";
|
|
# Use git, to also fetch tree-sitter repositories that upstream puts their
|
|
# hashes in the repository as well, in repos.txt.
|
|
forceFetchGit = true;
|
|
postFetch = ''
|
|
cd $out
|
|
substitute build.py get-repos.py \
|
|
--replace-fail "from tree_sitter import Language" "" \
|
|
--replace-fail 'print(f"{sys.argv[0]}: Building", languages_filename)' "exit(0)"
|
|
${python.pythonOnBuildForHost.interpreter} get-repos.py
|
|
rm -rf vendor/*/.git
|
|
'';
|
|
};
|
|
|
|
build-system = [
|
|
setuptools
|
|
cython
|
|
];
|
|
dependencies = [ tree-sitter ];
|
|
# Generate languages.so file (build won't fail without this, but tests will).
|
|
preBuild = ''
|
|
${python.pythonOnBuildForHost.interpreter} build.py
|
|
'';
|
|
nativeCheckInputs = [ pytestCheckHook ];
|
|
# Without cd $out, tests fail to import the compiled cython extensions.
|
|
# Without copying the ./tests/ directory to $out, pytest won't detect the
|
|
# tests and run them. See also:
|
|
# https://github.com/NixOS/nixpkgs/issues/255262
|
|
preCheck = ''
|
|
cp -r tests $out/${python.sitePackages}/tree_sitter_languages
|
|
cd $out
|
|
'';
|
|
|
|
pythonImportsCheck = [ "tree_sitter_languages" ];
|
|
|
|
meta = with lib; {
|
|
description = "Binary Python wheels for all tree sitter languages";
|
|
homepage = "https://github.com/grantjenks/py-tree-sitter-languages";
|
|
license = licenses.asl20;
|
|
maintainers = with maintainers; [ doronbehar ];
|
|
# https://github.com/grantjenks/py-tree-sitter-languages/issues/67
|
|
broken = versionAtLeast tree-sitter.version "0.22";
|
|
};
|
|
}
|