{
  description = "webhook-bridge development environment";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    rust-overlay = {
      url = "github:oxalica/rust-overlay";
      inputs = {
        nixpkgs.follows = "nixpkgs";
      };
    };
  };

  outputs =
    {
      self,
      nixpkgs,
      rust-overlay,
    }:
    let
      forAllSystems =
        func:
        builtins.listToAttrs (
          map (system: {
            name = system;
            value = func system;
          }) nixpkgs.lib.systems.flakeExposed
        );
    in
    {
      devShells = forAllSystems (
        system:
        let
          overlays = [ (import rust-overlay) ];
          pkgs = import nixpkgs {
            inherit system overlays;
          };
          rustToolchain = pkgs.pkgsBuildHost.rust-bin.fromRustupToolchainFile ./rust-toolchain.toml;
        in
        {
          default = pkgs.mkShell {
            nativeBuildInputs = [
              pkgs.pkg-config
              rustToolchain
              pkgs.openssl
            ];
            buildInputs = with pkgs; [
              # sqlx-cli # For sqlx CLI to manage migrations
              # sqlite # To access the database (sqlite is bundled into the together_alone binary but this is for manually accessing the db).
            ];
          };
        }
      );
      packages = forAllSystems (
        system:
        let
          overlays = [ (import rust-overlay) ];
          pkgs = import nixpkgs {
            inherit system overlays;
          };
          rustToolchain = pkgs.pkgsBuildHost.rust-bin.fromRustupToolchainFile ./rust-toolchain.toml;
        in
        rec {
          app = pkgs.rustPlatform.buildRustPackage {
            pname = "webhook-bridge";
            version = "0.0.0";
            src = ./.;

            # If you have a Cargo.lock file, use this:
            cargoLock.lockFile = ./Cargo.lock;

            nativeBuildInputs = [
              pkgs.pkg-config
            ];
            buildInputs = [
              pkgs.openssl
            ];
          };
          docker_env = pkgs.buildEnv {
            name = "webhook-bridge";
            paths = with pkgs; [
              app
              bash
              uutils-coreutils-noprefix
              # toybox # Smaller than uutils-coreutils?
            ];
          };
          default = app;
        }
      );
    };
}