mirror of
https://git.savannah.gnu.org/git/emacs.git
synced 2024-11-24 07:20:37 +00:00
9eff9fe3e8
* Makefile.in (AUTOCONF_INPUTS): New macro.
($(srcdir)/configure, $(srcdir)/src/stamp-h.in): Depend on it,
so that these files also depend on m4/getopt.m4.
* configure.in: Configure getopt by including m4/getopt.m4,
and configuring a getopt replacement if necessary.
* make-dist: Add m4 subdirectory. Unlink lib-src/getopt.h.
* m4/getopt.m4: New file.
* lib-src/Makefile.in (mostlyclean): Remove getopt.h, getopt.h-t.
(GETOPT_H): New macro, from gnulib.
(getopt.h): New rule, from gnulib.
(GETOPTOBJS): Now autoconfigured.
(GETOPTDEPS): getopt.h is now autoconfigured.
(getopt.o, getopt1.o): Depend on $(GETOPT_H), not ${srcdir}/getopt.h.
(getopt.o): Depend on ${srcdir}/gettext.h.
(movemail.o): Depend on $(GETOPT_H).
* lib-src/getopt.c, lib-src/getopt1.c: Sync from gnulib.
* lib-src/getopt_.h, lib-src/getopt_int.h, lib-src/gettext.h:
New files, from gnulib.
* lib-src/getopt.h: Removed (now is getopt_.h).
* nt/inc/gettext.h: Remove; no longer needed now that
lib-src/gettext.h exists.
* src/s/cygwin.h (C_SWITCH_SYSTEM): Remove, since gettext.h is
now part of lib-src.
79 lines
2.4 KiB
Plaintext
79 lines
2.4 KiB
Plaintext
# getopt.m4 serial 10
|
|
dnl Copyright (C) 2002, 2003, 2004, 2005 Free Software Foundation, Inc.
|
|
dnl This file is free software; the Free Software Foundation
|
|
dnl gives unlimited permission to copy and/or distribute it,
|
|
dnl with or without modifications, as long as this notice is preserved.
|
|
|
|
# The getopt module assume you want GNU getopt, with getopt_long etc,
|
|
# rather than vanilla POSIX getopt. This means your your code should
|
|
# always include <getopt.h> for the getopt prototypes.
|
|
|
|
AC_DEFUN([gl_GETOPT_SUBSTITUTE],
|
|
[
|
|
AC_LIBOBJ([getopt])
|
|
AC_LIBOBJ([getopt1])
|
|
gl_GETOPT_SUBSTITUTE_HEADER
|
|
gl_PREREQ_GETOPT
|
|
])
|
|
|
|
AC_DEFUN([gl_GETOPT_SUBSTITUTE_HEADER],
|
|
[
|
|
GETOPT_H=getopt.h
|
|
AC_DEFINE([__GETOPT_PREFIX], [[rpl_]],
|
|
[Define to rpl_ if the getopt replacement functions and variables
|
|
should be used.])
|
|
AC_SUBST([GETOPT_H])
|
|
])
|
|
|
|
AC_DEFUN([gl_GETOPT_CHECK_HEADERS],
|
|
[
|
|
GETOPT_H=
|
|
AC_CHECK_HEADERS([getopt.h], [], [GETOPT_H=getopt.h])
|
|
if test -z "$GETOPT_H"; then
|
|
AC_CHECK_FUNCS([getopt_long_only], [], [GETOPT_H=getopt.h])
|
|
fi
|
|
|
|
dnl BSD getopt_long uses an incompatible method to reset option processing,
|
|
dnl and (as of 2004-10-15) mishandles optional option-arguments.
|
|
if test -z "$GETOPT_H"; then
|
|
AC_CHECK_DECL([optreset], [GETOPT_H=getopt.h], [], [#include <getopt.h>])
|
|
fi
|
|
|
|
dnl Solaris 10 getopt doesn't handle `+' as a leading character in an
|
|
dnl option string (as of 2005-05-05).
|
|
if test -z "$GETOPT_H"; then
|
|
AC_CACHE_CHECK([for working GNU getopt function], [gl_cv_func_gnu_getopt],
|
|
[AC_RUN_IFELSE(
|
|
[AC_LANG_PROGRAM([#include <getopt.h>],
|
|
[[
|
|
char *myargv[3];
|
|
myargv[0] = "conftest";
|
|
myargv[1] = "-+";
|
|
myargv[2] = 0;
|
|
return getopt (2, myargv, "+a") != '?';
|
|
]])],
|
|
[gl_cv_func_gnu_getopt=yes],
|
|
[gl_cv_func_gnu_getopt=no],
|
|
[dnl cross compiling - pessimistically guess based on decls
|
|
dnl Solaris 10 getopt doesn't handle `+' as a leading character in an
|
|
dnl option string (as of 2005-05-05).
|
|
AC_CHECK_DECL([getopt_clip],
|
|
[gl_cv_func_gnu_getopt=no], [gl_cv_func_gnu_getopt=yes],
|
|
[#include <getopt.h>])])])
|
|
if test "$gl_cv_func_gnu_getopt" = "no"; then
|
|
GETOPT_H=getopt.h
|
|
fi
|
|
fi
|
|
])
|
|
|
|
AC_DEFUN([gl_GETOPT_IFELSE],
|
|
[
|
|
AC_REQUIRE([gl_GETOPT_CHECK_HEADERS])
|
|
AS_IF([test -n "$GETOPT_H"], [$1], [$2])
|
|
])
|
|
|
|
AC_DEFUN([gl_GETOPT], [gl_GETOPT_IFELSE([gl_GETOPT_SUBSTITUTE])])
|
|
|
|
# Prerequisites of lib/getopt*.
|
|
AC_DEFUN([gl_PREREQ_GETOPT], [:])
|