mirror of
https://git.savannah.gnu.org/git/emacs.git
synced 2024-11-25 07:28:20 +00:00
ecf08f0621
dc4e6b1329; Update copyright years in more files64b3777631; Run set-copyright from admin.el8e1c56ae46; Add 2024 to copyright years # Conflicts: # doc/misc/modus-themes.org # doc/misc/texinfo.tex # etc/NEWS # etc/refcards/ru-refcard.tex # etc/themes/modus-operandi-theme.el # etc/themes/modus-themes.el # etc/themes/modus-vivendi-theme.el # lib/alloca.in.h # lib/binary-io.h # lib/c-ctype.h # lib/c-strcasecmp.c # lib/c-strncasecmp.c # lib/careadlinkat.c # lib/cloexec.c # lib/close-stream.c # lib/diffseq.h # lib/dup2.c # lib/filemode.h # lib/fpending.c # lib/fpending.h # lib/fsusage.c # lib/getgroups.c # lib/getloadavg.c # lib/gettext.h # lib/gettime.c # lib/gettimeofday.c # lib/group-member.c # lib/malloc.c # lib/md5-stream.c # lib/md5.c # lib/md5.h # lib/memmem.c # lib/memrchr.c # lib/nanosleep.c # lib/save-cwd.h # lib/sha1.c # lib/sig2str.c # lib/stdlib.in.h # lib/strtoimax.c # lib/strtol.c # lib/strtoll.c # lib/time_r.c # lib/xalloc-oversized.h # lisp/auth-source-pass.el # lisp/emacs-lisp/lisp-mnt.el # lisp/emacs-lisp/timer.el # lisp/info-look.el # lisp/jit-lock.el # lisp/loadhist.el # lisp/mail/rmail.el # lisp/net/ntlm.el # lisp/net/webjump.el # lisp/progmodes/asm-mode.el # lisp/progmodes/project.el # lisp/progmodes/sh-script.el # lisp/textmodes/flyspell.el # lisp/textmodes/reftex-toc.el # lisp/textmodes/reftex.el # lisp/textmodes/tex-mode.el # lisp/url/url-gw.el # m4/alloca.m4 # m4/clock_time.m4 # m4/d-type.m4 # m4/dirent_h.m4 # m4/dup2.m4 # m4/euidaccess.m4 # m4/fchmodat.m4 # m4/filemode.m4 # m4/fsusage.m4 # m4/getgroups.m4 # m4/getloadavg.m4 # m4/getrandom.m4 # m4/gettime.m4 # m4/gettimeofday.m4 # m4/gnulib-common.m4 # m4/group-member.m4 # m4/inttypes.m4 # m4/malloc.m4 # m4/manywarnings.m4 # m4/mempcpy.m4 # m4/memrchr.m4 # m4/mkostemp.m4 # m4/mktime.m4 # m4/nproc.m4 # m4/nstrftime.m4 # m4/pathmax.m4 # m4/pipe2.m4 # m4/pselect.m4 # m4/pthread_sigmask.m4 # m4/readlink.m4 # m4/realloc.m4 # m4/sig2str.m4 # m4/ssize_t.m4 # m4/stat-time.m4 # m4/stddef_h.m4 # m4/stdint.m4 # m4/stdio_h.m4 # m4/stdlib_h.m4 # m4/stpcpy.m4 # m4/strnlen.m4 # m4/strtoimax.m4 # m4/strtoll.m4 # m4/time_h.m4 # m4/timegm.m4 # m4/timer_time.m4 # m4/timespec.m4 # m4/unistd_h.m4 # m4/warnings.m4 # nt/configure.bat # nt/preprep.c # test/lisp/register-tests.el
534 lines
17 KiB
EmacsLisp
534 lines
17 KiB
EmacsLisp
;;; cvs-status.el --- major mode for browsing `cvs status' output -*- lexical-binding: t -*-
|
|
|
|
;; Copyright (C) 1999-2024 Free Software Foundation, Inc.
|
|
|
|
;; Author: Stefan Monnier <monnier@iro.umontreal.ca>
|
|
;; Keywords: pcl-cvs cvs status tree vc tools
|
|
|
|
;; This file is part of GNU Emacs.
|
|
|
|
;; GNU Emacs is free software: you can redistribute it and/or modify
|
|
;; it under the terms of the GNU General Public License as published by
|
|
;; the Free Software Foundation, either version 3 of the License, or
|
|
;; (at your option) any later version.
|
|
|
|
;; GNU Emacs is distributed in the hope that it will be useful,
|
|
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
;; GNU General Public License for more details.
|
|
|
|
;; You should have received a copy of the GNU General Public License
|
|
;; along with GNU Emacs. If not, see <https://www.gnu.org/licenses/>.
|
|
|
|
;;; Commentary:
|
|
|
|
;; Todo:
|
|
|
|
;; - Somehow allow cvs-status-tree to work on-the-fly
|
|
|
|
;;; Code:
|
|
|
|
(require 'cl-lib)
|
|
(require 'pcvs)
|
|
|
|
;;;
|
|
|
|
(defvar-keymap cvs-status-mode-map
|
|
:parent cvs-mode-map
|
|
"n" #'next-line
|
|
"p" #'previous-line
|
|
"N" #'cvs-status-next
|
|
"P" #'cvs-status-prev
|
|
"M-n" #'cvs-status-next
|
|
"M-p" #'cvs-status-prev
|
|
"t" #'cvs-status-cvstrees
|
|
"T" #'cvs-status-trees
|
|
">" #'cvs-mode-checkout)
|
|
|
|
;;(easy-menu-define cvs-status-menu cvs-status-mode-map
|
|
;; "Menu for `cvs-status-mode'."
|
|
;; '("CVS-Status"
|
|
;; ["Show Tag Trees" cvs-status-tree t]
|
|
;; ))
|
|
|
|
(defvar cvs-status-mode-hook nil
|
|
"Hook run at the end of `cvs-status-mode'.")
|
|
|
|
(defconst cvs-status-tags-leader-re "^ Existing Tags:$")
|
|
(defconst cvs-status-entry-leader-re
|
|
"^File:\\s-+\\(?:no file \\)?\\(.*\\S-\\)\\s-+Status: \\(.+\\)$")
|
|
(defconst cvs-status-dir-re "^cvs[.ex]* [a-z]+: Examining \\(.+\\)$")
|
|
(defconst cvs-status-rev-re "[0-9][.0-9]*\\.[.0-9]*[0-9]")
|
|
(defconst cvs-status-tag-re "[ \t]\\([a-zA-Z][^ \t\n.]*\\)")
|
|
|
|
(defconst cvs-status-font-lock-keywords
|
|
`((,cvs-status-entry-leader-re
|
|
(1 'cvs-filename)
|
|
(2 'cvs-need-action))
|
|
(,cvs-status-tags-leader-re
|
|
(,cvs-status-rev-re
|
|
(save-excursion (re-search-forward "^\n" nil 'move) (point))
|
|
(progn (re-search-backward cvs-status-tags-leader-re nil t)
|
|
(forward-line 1))
|
|
(0 font-lock-comment-face))
|
|
(,cvs-status-tag-re
|
|
(save-excursion (re-search-forward "^\n" nil 'move) (point))
|
|
(progn (re-search-backward cvs-status-tags-leader-re nil t)
|
|
(forward-line 1))
|
|
(1 font-lock-function-name-face)))))
|
|
(defconst cvs-status-font-lock-defaults
|
|
'(cvs-status-font-lock-keywords t nil nil nil (font-lock-multiline . t)))
|
|
|
|
(defvar cvs-minor-wrap-function)
|
|
(defvar cvs-force-command)
|
|
(defvar cvs-minor-current-files)
|
|
(defvar cvs-secondary-branch-prefix)
|
|
(defvar cvs-branch-prefix)
|
|
(defvar cvs-tag-print-rev)
|
|
|
|
(put 'cvs-status-mode 'mode-class 'special)
|
|
;;;###autoload
|
|
(define-derived-mode cvs-status-mode fundamental-mode "CVS-Status"
|
|
"Mode used for cvs status output."
|
|
(setq-local font-lock-defaults cvs-status-font-lock-defaults)
|
|
(setq-local cvs-minor-wrap-function #'cvs-status-minor-wrap))
|
|
|
|
;; Define cvs-status-next and cvs-status-prev
|
|
(easy-mmode-define-navigation cvs-status cvs-status-entry-leader-re "entry")
|
|
|
|
(defun cvs-status-current-file ()
|
|
(save-excursion
|
|
(forward-line 1)
|
|
(or (re-search-backward cvs-status-entry-leader-re nil t)
|
|
(re-search-forward cvs-status-entry-leader-re))
|
|
(let* ((file (match-string 1))
|
|
(cvsdir (and (re-search-backward cvs-status-dir-re nil t)
|
|
(match-string 1)))
|
|
(pcldir (and (if (boundp 'cvs-pcl-cvs-dirchange-re)
|
|
(re-search-backward cvs-pcl-cvs-dirchange-re nil t))
|
|
(match-string 1)))
|
|
(dir ""))
|
|
(let ((default-directory ""))
|
|
(when pcldir (setq dir (expand-file-name pcldir dir)))
|
|
(when cvsdir (setq dir (expand-file-name cvsdir dir)))
|
|
(expand-file-name file dir)))))
|
|
|
|
(defun cvs-status-current-tag ()
|
|
(save-excursion
|
|
(let ((pt (point))
|
|
(col (current-column))
|
|
(start (progn (re-search-backward cvs-status-tags-leader-re nil t) (point)))
|
|
(end (progn (re-search-forward "^$" nil t) (point))))
|
|
(when (and (< start pt) (> end pt))
|
|
(goto-char pt)
|
|
(end-of-line)
|
|
(let ((tag nil) (dist pt) (end (point)))
|
|
(beginning-of-line)
|
|
(while (re-search-forward cvs-status-tag-re end t)
|
|
(let* ((cole (current-column))
|
|
(colb (save-excursion
|
|
(goto-char (match-beginning 1)) (current-column)))
|
|
(ndist (min (abs (- cole col)) (abs (- colb col)))))
|
|
(when (< ndist dist)
|
|
(setq dist ndist)
|
|
(setq tag (match-string 1)))))
|
|
tag)))))
|
|
|
|
(defun cvs-status-minor-wrap (buf f)
|
|
(let ((data (with-current-buffer buf
|
|
(cons
|
|
(cons (cvs-status-current-file)
|
|
(cvs-status-current-tag))
|
|
(when mark-active
|
|
(save-excursion
|
|
(goto-char (mark))
|
|
(cons (cvs-status-current-file)
|
|
(cvs-status-current-tag))))))))
|
|
(let ((cvs-branch-prefix (cdar data))
|
|
(cvs-secondary-branch-prefix (and (cdar data) (cddr data)))
|
|
(cvs-minor-current-files
|
|
(cons (caar data)
|
|
(when (and (cadr data) (not (equal (caar data) (cadr data))))
|
|
(list (cadr data)))))
|
|
;; FIXME: I need to force because the fileinfos are UNKNOWN
|
|
(cvs-force-command "/F"))
|
|
(funcall f))))
|
|
|
|
;;
|
|
;; Tagelt, tag element
|
|
;;
|
|
|
|
(cl-defstruct (cvs-tag
|
|
(:constructor nil)
|
|
(:constructor cvs-tag-make
|
|
(vlist &optional name type))
|
|
(:conc-name cvs-tag->))
|
|
vlist
|
|
name
|
|
type)
|
|
|
|
(defsubst cvs-status-vl-to-str (vl) (mapconcat #'number-to-string vl "."))
|
|
|
|
(defun cvs-tag->string (tag)
|
|
(if (stringp tag) tag
|
|
(let ((name (cvs-tag->name tag))
|
|
(vl (cvs-tag->vlist tag)))
|
|
(if (null name) (cvs-status-vl-to-str vl)
|
|
(let ((rev (if vl (concat " (" (cvs-status-vl-to-str vl) ")") "")))
|
|
(if (consp name) (mapcar (lambda (name) (concat name rev)) name)
|
|
(concat name rev)))))))
|
|
|
|
(defun cvs-tag-compare-1 (vl1 vl2)
|
|
(cond
|
|
((and (null vl1) (null vl2)) 'equal)
|
|
((null vl1) 'more2)
|
|
((null vl2) 'more1)
|
|
(t (let ((v1 (car vl1))
|
|
(v2 (car vl2)))
|
|
(cond
|
|
((> v1 v2) 'more1)
|
|
((< v1 v2) 'more2)
|
|
(t (cvs-tag-compare-1 (cdr vl1) (cdr vl2))))))))
|
|
|
|
(defsubst cvs-tag-compare (tag1 tag2)
|
|
(cvs-tag-compare-1 (cvs-tag->vlist tag1) (cvs-tag->vlist tag2)))
|
|
|
|
(defun cvs-tag-merge (tag1 tag2)
|
|
"Merge TAG1 and TAG2 into one."
|
|
(let ((type1 (cvs-tag->type tag1))
|
|
(type2 (cvs-tag->type tag2))
|
|
(name1 (cvs-tag->name tag1))
|
|
(name2 (cvs-tag->name tag2)))
|
|
(unless (equal (cvs-tag->vlist tag1) (cvs-tag->vlist tag2))
|
|
(setf (cvs-tag->vlist tag1) nil))
|
|
(if type1
|
|
(unless (or (not type2) (equal type1 type2))
|
|
(setf (cvs-tag->type tag1) nil))
|
|
(setf (cvs-tag->type tag1) type2))
|
|
(if name1
|
|
(setf (cvs-tag->name tag1) (cvs-append name1 name2))
|
|
(setf (cvs-tag->name tag1) name2))
|
|
tag1))
|
|
|
|
(defun cvs-tree-print (tags printer column)
|
|
"Print the tree of TAGS where each tag's string is given by PRINTER.
|
|
PRINTER should accept both a tag (in which case it should return a string)
|
|
or a string (in which case it should simply return its argument).
|
|
A tag cannot be a CONS. The return value can also be a list of strings,
|
|
if several nodes where merged into one.
|
|
The tree will be printed no closer than column COLUMN."
|
|
|
|
(let* ((eol (save-excursion (end-of-line) (current-column)))
|
|
(column (max (+ eol 2) column)))
|
|
(if (null tags) column
|
|
(let* ((rev (cvs-car tags))
|
|
(name (funcall printer (cvs-car rev)))
|
|
(rest (append (cvs-cdr name) (cvs-cdr tags)))
|
|
(prefix
|
|
(save-excursion
|
|
(or (= (forward-line 1) 0) (insert "\n"))
|
|
(cvs-tree-print rest printer column))))
|
|
(cl-assert (>= prefix column))
|
|
(move-to-column prefix t)
|
|
(cl-assert (eolp))
|
|
(insert (cvs-car name))
|
|
(dolist (br (cvs-cdr rev))
|
|
(let* ((column (current-column))
|
|
(brrev (funcall printer (cvs-car br)))
|
|
(brlength (length (cvs-car brrev)))
|
|
(brfill (concat (make-string (/ brlength 2) ? ) "|"))
|
|
(prefix
|
|
(save-excursion
|
|
(insert " -- ")
|
|
(cvs-tree-print (cvs-append brrev brfill (cvs-cdr br))
|
|
printer (current-column)))))
|
|
(delete-region (save-excursion (move-to-column prefix) (point))
|
|
(point))
|
|
(insert " " (make-string (- prefix column 2) ?-) " ")
|
|
(end-of-line)))
|
|
prefix))))
|
|
|
|
(defun cvs-tree-merge (tree1 tree2)
|
|
"Merge tags trees TREE1 and TREE2 into one.
|
|
BEWARE: because of stability issues, this is not a symmetric operation."
|
|
(cl-assert (and (listp tree1) (listp tree2)))
|
|
(cond
|
|
((null tree1) tree2)
|
|
((null tree2) tree1)
|
|
(t
|
|
(let* ((rev1 (car tree1))
|
|
(tag1 (cvs-car rev1))
|
|
(vl1 (cvs-tag->vlist tag1))
|
|
(l1 (length vl1))
|
|
(rev2 (car tree2))
|
|
(tag2 (cvs-car rev2))
|
|
(vl2 (cvs-tag->vlist tag2))
|
|
(l2 (length vl2)))
|
|
(cond
|
|
((= l1 l2)
|
|
(pcase (cvs-tag-compare tag1 tag2)
|
|
('more1 (cons rev2 (cvs-tree-merge tree1 (cdr tree2))))
|
|
('more2 (cons rev1 (cvs-tree-merge (cdr tree1) tree2)))
|
|
('equal
|
|
(cons (cons (cvs-tag-merge tag1 tag2)
|
|
(cvs-tree-merge (cvs-cdr rev1) (cvs-cdr rev2)))
|
|
(cvs-tree-merge (cdr tree1) (cdr tree2))))))
|
|
((> l1 l2)
|
|
(cvs-tree-merge
|
|
(list (cons (cvs-tag-make (butlast vl1)) tree1)) tree2))
|
|
((< l1 l2)
|
|
(cvs-tree-merge
|
|
tree1 (list (cons (cvs-tag-make (butlast vl2)) tree2)))))))))
|
|
|
|
(defun cvs-tag-make-tag (tag)
|
|
(let ((vl (mapcar #'string-to-number (split-string (nth 2 tag) "\\."))))
|
|
(cvs-tag-make vl (nth 0 tag) (intern (nth 1 tag)))))
|
|
|
|
(defun cvs-tags->tree (tags)
|
|
"Make a tree out of a list of TAGS."
|
|
(let ((tags
|
|
(mapcar
|
|
(lambda (tag)
|
|
(let ((tag (cvs-tag-make-tag tag)))
|
|
(list (if (not (eq (cvs-tag->type tag) 'branch)) tag
|
|
(list (cvs-tag-make (butlast (cvs-tag->vlist tag)))
|
|
tag)))))
|
|
tags)))
|
|
(while (cdr tags)
|
|
(let (tl)
|
|
(while tags
|
|
(push (cvs-tree-merge (pop tags) (pop tags)) tl))
|
|
(setq tags (nreverse tl))))
|
|
(car tags)))
|
|
|
|
(defun cvs-status-get-tags ()
|
|
"Look for a list of tags, read them in and delete them.
|
|
Return nil if there was an empty list of tags and t if there wasn't
|
|
even a list. Else, return the list of tags where each element of
|
|
the list is a three-string list TAG, KIND, REV."
|
|
(let ((tags nil))
|
|
(if (not (re-search-forward cvs-status-tags-leader-re nil t)) t
|
|
(forward-char 1)
|
|
(let ((pt (point))
|
|
(lastrev nil)
|
|
(case-fold-search t))
|
|
(or
|
|
(looking-at "\\s-+no\\s-+tags")
|
|
|
|
(progn ; normal listing
|
|
(while (looking-at "^[ \t]+\\([^ \t\n]+\\)[ \t]+(\\([a-z]+\\): \\(.+\\))$")
|
|
(push (list (match-string 1) (match-string 2) (match-string 3)) tags)
|
|
(forward-line 1))
|
|
(unless (looking-at "^$") (setq tags nil) (goto-char pt))
|
|
tags)
|
|
|
|
(progn ; cvstree-style listing
|
|
(while (or (looking-at "^ .+\\(.\\) \\([0-9.]+\\): \\([^\n\t .0-9][^\n\t ]*\\)?$")
|
|
(and lastrev
|
|
(looking-at "^ .+\\(\\) \\(8\\)? \\([^\n\t .0-9][^\n\t ]*\\)$")))
|
|
(setq lastrev (or (match-string 2) lastrev))
|
|
(push (list (match-string 3)
|
|
(if (equal (match-string 1) " ") "branch" "revision")
|
|
lastrev) tags)
|
|
(forward-line 1))
|
|
(unless (looking-at "^$") (setq tags nil) (goto-char pt))
|
|
(setq tags (nreverse tags)))
|
|
|
|
(progn ; new tree style listing
|
|
(let* ((re-lead "[ \t]*\\(-+\\)?\\(|\n?[ \t]+\\)*")
|
|
(re3 (concat re-lead "\\(\\.\\)?\\(" cvs-status-rev-re "\\)"))
|
|
(re2 (concat re-lead cvs-status-tag-re "\\(\\)"))
|
|
(re1 (concat re-lead cvs-status-tag-re
|
|
" (\\(" cvs-status-rev-re "\\))")))
|
|
(while (or (looking-at re1) (looking-at re2) (looking-at re3))
|
|
(push (list (match-string 3)
|
|
(if (match-string 1) "branch" "revision")
|
|
(match-string 4)) tags)
|
|
(goto-char (match-end 0))
|
|
(when (eolp) (forward-char 1))))
|
|
(unless (looking-at "^$") (setq tags nil) (goto-char pt))
|
|
(setq tags (nreverse tags))))
|
|
|
|
(delete-region pt (point)))
|
|
tags)))
|
|
|
|
;; (defun cvs-refontify (beg end)
|
|
;; (when font-lock-mode
|
|
;; (font-lock-fontify-region (1- beg) (1+ end))))
|
|
|
|
(defun cvs-status-trees ()
|
|
"Look for a lists of tags, and replace them with trees."
|
|
(interactive)
|
|
(save-excursion
|
|
(goto-char (point-min))
|
|
(let ((inhibit-read-only t)
|
|
(tags nil))
|
|
(while (listp (setq tags (cvs-status-get-tags)))
|
|
;;(let ((pt (save-excursion (forward-line -1) (point))))
|
|
(save-restriction
|
|
(narrow-to-region (point) (point))
|
|
;;(newline)
|
|
(combine-after-change-calls
|
|
(cvs-tree-print (cvs-tags->tree tags) 'cvs-tag->string 3)))
|
|
;;(cvs-refontify pt (point))
|
|
;;(sit-for 0)
|
|
;;)
|
|
))))
|
|
|
|
;;;;
|
|
;;;; CVSTree-style trees
|
|
;;;;
|
|
|
|
(defvar cvs-tree-use-jisx0208 nil) ;Old compat var.
|
|
(defvar cvs-tree-use-charset
|
|
(cond
|
|
(cvs-tree-use-jisx0208 'jisx0208)
|
|
((char-displayable-p ?━) 'unicode)
|
|
((char-displayable-p (make-char 'japanese-jisx0208 40 44)) 'jisx0208))
|
|
"Non-nil if we should use the graphical glyphs from `japanese-jisx0208'.
|
|
Otherwise, default to ASCII chars like +, - and |.")
|
|
|
|
(defconst cvs-tree-char-space
|
|
(pcase cvs-tree-use-charset
|
|
('jisx0208 (make-char 'japanese-jisx0208 33 33))
|
|
('unicode " ")
|
|
(_ " ")))
|
|
(defconst cvs-tree-char-hbar
|
|
(pcase cvs-tree-use-charset
|
|
('jisx0208 (make-char 'japanese-jisx0208 40 44))
|
|
('unicode "━")
|
|
(_ "--")))
|
|
(defconst cvs-tree-char-vbar
|
|
(pcase cvs-tree-use-charset
|
|
('jisx0208 (make-char 'japanese-jisx0208 40 45))
|
|
('unicode "┃")
|
|
(_ "| ")))
|
|
(defconst cvs-tree-char-branch
|
|
(pcase cvs-tree-use-charset
|
|
('jisx0208 (make-char 'japanese-jisx0208 40 50))
|
|
('unicode "┣")
|
|
(_ "+-")))
|
|
(defconst cvs-tree-char-eob ;end of branch
|
|
(pcase cvs-tree-use-charset
|
|
('jisx0208 (make-char 'japanese-jisx0208 40 49))
|
|
('unicode "┗")
|
|
(_ "`-")))
|
|
(defconst cvs-tree-char-bob ;beginning of branch
|
|
(pcase cvs-tree-use-charset
|
|
('jisx0208 (make-char 'japanese-jisx0208 40 51))
|
|
('unicode "┳")
|
|
(_ "+-")))
|
|
|
|
(defun cvs-tag-lessp (tag1 tag2)
|
|
(eq (cvs-tag-compare tag1 tag2) 'more2))
|
|
|
|
(defvar cvs-tree-nomerge nil)
|
|
|
|
(defun cvs-status-cvstrees (&optional arg)
|
|
"Look for a list of tags, and replace it with a tree.
|
|
Optional prefix ARG chooses between two representations."
|
|
(interactive "P")
|
|
(when (and cvs-tree-use-charset
|
|
(not enable-multibyte-characters))
|
|
;; We need to convert the buffer from unibyte to multibyte
|
|
;; since we'll use multibyte chars for the tree.
|
|
(let ((modified (buffer-modified-p))
|
|
(inhibit-read-only t)
|
|
(inhibit-modification-hooks t))
|
|
(unwind-protect
|
|
(progn
|
|
(decode-coding-region (point-min) (point-max) 'undecided)
|
|
(set-buffer-multibyte t))
|
|
(restore-buffer-modified-p modified))))
|
|
(save-excursion
|
|
(goto-char (point-min))
|
|
(let ((inhibit-read-only t)
|
|
(tags nil)
|
|
(cvs-tree-nomerge (if arg (not cvs-tree-nomerge) cvs-tree-nomerge)))
|
|
(while (listp (setq tags (cvs-status-get-tags)))
|
|
(let ((tags (mapcar #'cvs-tag-make-tag tags))
|
|
;;(pt (save-excursion (forward-line -1) (point)))
|
|
)
|
|
(setq tags (sort tags #'cvs-tag-lessp))
|
|
(let* ((first (car tags))
|
|
(prev (if (cvs-tag-p first)
|
|
(list (car (cvs-tag->vlist first))) nil)))
|
|
(combine-after-change-calls
|
|
(cvs-tree-tags-insert tags prev))
|
|
;;(cvs-refontify pt (point))
|
|
;;(sit-for 0)
|
|
))))))
|
|
|
|
(defun cvs-tree-tags-insert (tags prev)
|
|
(when tags
|
|
(let* ((tag (car tags))
|
|
(vlist (cvs-tag->vlist tag))
|
|
(nprev ;"next prev"
|
|
(let* ((next (cvs-car (cadr tags)))
|
|
(nprev (if (and cvs-tree-nomerge next
|
|
(equal vlist (cvs-tag->vlist next)))
|
|
prev vlist)))
|
|
(cl-mapcar (lambda (v _p) v) nprev prev)))
|
|
(after (save-excursion
|
|
(newline)
|
|
(cvs-tree-tags-insert (cdr tags) nprev)))
|
|
(pe t) ;"prev equal"
|
|
(nas nil)) ;"next afters" to be returned
|
|
(insert " ")
|
|
(cl-do* ((vs vlist (cdr vs))
|
|
(ps prev (cdr ps))
|
|
(as after (cdr as)))
|
|
((and (null as) (null vs) (null ps))
|
|
(let ((revname (cvs-status-vl-to-str vlist)))
|
|
(if (cl-every #'identity (cl-mapcar #'equal prev vlist))
|
|
(insert (make-string (+ 4 (length revname)) ? )
|
|
(or (cvs-tag->name tag) ""))
|
|
(insert " " revname ": " (or (cvs-tag->name tag) "")))))
|
|
(let* ((eq (and pe (equal (car ps) (car vs))))
|
|
(next-eq (equal (cadr ps) (cadr vs))))
|
|
(let* ((na+char
|
|
(if (car as)
|
|
(if eq
|
|
(if next-eq (cons t cvs-tree-char-vbar)
|
|
(cons t cvs-tree-char-branch))
|
|
(cons nil cvs-tree-char-bob))
|
|
(if eq
|
|
(if next-eq (cons nil cvs-tree-char-space)
|
|
(cons t cvs-tree-char-eob))
|
|
(cons nil (if (and (eq (cvs-tag->type tag) 'branch)
|
|
(cl-every #'null as))
|
|
cvs-tree-char-space
|
|
cvs-tree-char-hbar))))))
|
|
(insert (cdr na+char))
|
|
(push (car na+char) nas))
|
|
(setq pe eq)))
|
|
(nreverse nas))))
|
|
|
|
;;;;
|
|
;;;; Merged trees from different files
|
|
;;;;
|
|
|
|
;; (defun cvs-tree-fuzzy-merge-1 (trees tree prev)
|
|
;; )
|
|
|
|
;; (defun cvs-tree-fuzzy-merge (trees tree)
|
|
;; "Do the impossible: merge TREE into TREES."
|
|
;; ())
|
|
|
|
;; (defun cvs-tree ()
|
|
;; "Get tags from the status output and merge them all into a big tree."
|
|
;; (save-excursion
|
|
;; (goto-char (point-min))
|
|
;; (let ((inhibit-read-only t)
|
|
;; (trees (make-vector 31 0)) tree)
|
|
;; (while (listp (setq tree (cvs-tags->tree (cvs-status-get-tags))))
|
|
;; (cvs-tree-fuzzy-merge trees tree))
|
|
;; (erase-buffer)
|
|
;; (let ((cvs-tag-print-rev nil))
|
|
;; (cvs-tree-print tree 'cvs-tag->string 3)))))
|
|
|
|
|
|
(provide 'cvs-status)
|
|
|
|
;;; cvs-status.el ends here
|