mirror of
https://git.savannah.gnu.org/git/emacs.git
synced 2024-12-27 10:54:40 +00:00
23f87bede0
Merge from emacs--gnus--5.10, gnus--rel--5.10 Patches applied: * miles@gnu.org--gnu-2004/emacs--gnus--5.10--base-0 tag of miles@gnu.org--gnu-2004/emacs--cvs-trunk--0--patch-464 * miles@gnu.org--gnu-2004/emacs--gnus--5.10--patch-1 Import from CVS branch gnus-5_10-branch * miles@gnu.org--gnu-2004/emacs--gnus--5.10--patch-2 Merge from lorentey@elte.hu--2004/emacs--multi-tty--0, emacs--cvs-trunk--0 * miles@gnu.org--gnu-2004/emacs--gnus--5.10--patch-3 Merge from gnus--rel--5.10 * miles@gnu.org--gnu-2004/emacs--gnus--5.10--patch-4 Merge from gnus--rel--5.10 * miles@gnu.org--gnu-2004/gnus--rel--5.10--patch-18 Update from CVS * miles@gnu.org--gnu-2004/gnus--rel--5.10--patch-19 Remove autoconf-generated files from archive * miles@gnu.org--gnu-2004/gnus--rel--5.10--patch-20 Update from CVS
116 lines
3.9 KiB
EmacsLisp
116 lines
3.9 KiB
EmacsLisp
;;; gnus-mh.el --- mh-e interface for Gnus
|
|
;; Copyright (C) 1994, 1995, 1996, 1997, 1998, 1999, 2000
|
|
;; Free Software Foundation, Inc.
|
|
|
|
;; Author: Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
|
|
;; Lars Magne Ingebrigtsen <larsi@gnus.org>
|
|
;; Keywords: news
|
|
|
|
;; This file is part of GNU Emacs.
|
|
|
|
;; GNU Emacs is free software; you can redistribute it and/or modify
|
|
;; it under the terms of the GNU General Public License as published by
|
|
;; the Free Software Foundation; either version 2, or (at your option)
|
|
;; any later version.
|
|
|
|
;; GNU Emacs is distributed in the hope that it will be useful,
|
|
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
;; GNU General Public License for more details.
|
|
|
|
;; You should have received a copy of the GNU General Public License
|
|
;; along with GNU Emacs; see the file COPYING. If not, write to the
|
|
;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
|
|
;; Boston, MA 02111-1307, USA.
|
|
|
|
;;; Commentary:
|
|
|
|
;;; Send mail using mh-e.
|
|
|
|
;; The following mh-e interface is all cooperative works of
|
|
;; tanaka@flab.fujitsu.CO.JP (TANAKA Hiroshi), kawabe@sra.CO.JP
|
|
;; (Yoshikatsu Kawabe), and shingu@casund.cpr.canon.co.jp (Toshiaki
|
|
;; SHINGU).
|
|
|
|
;;; Code:
|
|
|
|
(require 'gnus)
|
|
(require 'mh-e)
|
|
(require 'mh-comp)
|
|
(require 'gnus-msg)
|
|
(require 'gnus-sum)
|
|
|
|
(eval-when-compile
|
|
(defvar mh-lib-progs))
|
|
|
|
(defun gnus-summary-save-article-folder (&optional arg)
|
|
"Append the current article to an mh folder.
|
|
If N is a positive number, save the N next articles.
|
|
If N is a negative number, save the N previous articles.
|
|
If N is nil and any articles have been marked with the process mark,
|
|
save those articles instead."
|
|
(interactive "P")
|
|
(require 'gnus-art)
|
|
(let ((gnus-default-article-saver 'gnus-summary-save-in-folder))
|
|
(gnus-summary-save-article arg)))
|
|
|
|
(defun gnus-summary-save-in-folder (&optional folder)
|
|
"Save this article to MH folder (using `rcvstore' in MH library).
|
|
Optional argument FOLDER specifies folder name."
|
|
;; Thanks to yuki@flab.Fujitsu.JUNET and ohm@kaba.junet.
|
|
(mh-find-path)
|
|
(let ((folder
|
|
(cond ((and (eq folder 'default)
|
|
gnus-newsgroup-last-folder)
|
|
gnus-newsgroup-last-folder)
|
|
(folder folder)
|
|
(t (mh-prompt-for-folder
|
|
"Save article in"
|
|
(funcall gnus-folder-save-name gnus-newsgroup-name
|
|
gnus-current-headers gnus-newsgroup-last-folder)
|
|
t))))
|
|
(errbuf (gnus-get-buffer-create " *Gnus rcvstore*"))
|
|
;; Find the rcvstore program.
|
|
(exec-path (cond
|
|
((and (boundp 'mh-lib-progs) mh-lib-progs)
|
|
(cons mh-lib-progs exec-path))
|
|
(mh-lib (cons mh-lib exec-path))
|
|
(t exec-path))))
|
|
(with-current-buffer gnus-original-article-buffer
|
|
(save-restriction
|
|
(widen)
|
|
(unwind-protect
|
|
(call-process-region
|
|
(point-min) (point-max) "rcvstore" nil errbuf nil folder)
|
|
(set-buffer errbuf)
|
|
(if (zerop (buffer-size))
|
|
(message "Article saved in folder: %s" folder)
|
|
(message "%s" (buffer-string)))
|
|
(kill-buffer errbuf))))
|
|
(setq gnus-newsgroup-last-folder folder)))
|
|
|
|
(defun gnus-Folder-save-name (newsgroup headers &optional last-folder)
|
|
"Generate folder name from NEWSGROUP, HEADERS, and optional LAST-FOLDER.
|
|
If variable `gnus-use-long-file-name' is nil, it is +News.group.
|
|
Otherwise, it is like +news/group."
|
|
(or last-folder
|
|
(concat "+"
|
|
(if gnus-use-long-file-name
|
|
(gnus-capitalize-newsgroup newsgroup)
|
|
(gnus-newsgroup-directory-form newsgroup)))))
|
|
|
|
(defun gnus-folder-save-name (newsgroup headers &optional last-folder)
|
|
"Generate folder name from NEWSGROUP, HEADERS, and optional LAST-FOLDER.
|
|
If variable `gnus-use-long-file-name' is nil, it is +news.group.
|
|
Otherwise, it is like +news/group."
|
|
(or last-folder
|
|
(concat "+"
|
|
(if gnus-use-long-file-name
|
|
newsgroup
|
|
(gnus-newsgroup-directory-form newsgroup)))))
|
|
|
|
(provide 'gnus-mh)
|
|
|
|
;;; arch-tag: 2d5696d3-b363-48e5-8749-c256be56acca
|
|
;;; gnus-mh.el ends here
|