mirror of
https://git.savannah.gnu.org/git/emacs.git
synced 2025-02-07 20:54:32 +00:00
6bbbc38b34
This incorporates: 2017-09-16 manywarnings: port to GCC on 64-bit MS-Windows 2017-09-13 all: Replace many more http URLs by https URLs * build-aux/config.guess, build-aux/config.sub: * build-aux/gitlog-to-changelog, doc/misc/texinfo.tex: * lib/allocator.h, lib/count-leading-zeros.h: * lib/count-trailing-zeros.h, lib/dup2.c, lib/filevercmp.c: * lib/fstatat.c, lib/fsync.c, lib/ftoastr.c, lib/ftoastr.h: * lib/intprops.h, lib/signal.in.h, lib/stdio-impl.h, lib/stdio.in.h: * lib/unistd.in.h, lib/utimens.c, m4/alloca.m4, m4/extern-inline.m4: * m4/fstatat.m4, m4/gnulib-common.m4, m4/manywarnings.m4: * m4/std-gnu11.m4, m4/sys_types_h.m4, m4/vararrays.m4: Copy from Gnulib. * lib/gnulib.mk.in: Regenerate.
69 lines
1.9 KiB
Plaintext
69 lines
1.9 KiB
Plaintext
# Check for variable-length arrays.
|
|
|
|
# serial 5
|
|
|
|
# From Paul Eggert
|
|
|
|
# Copyright (C) 2001, 2009-2017 Free Software Foundation, Inc.
|
|
# This file is free software; the Free Software Foundation
|
|
# gives unlimited permission to copy and/or distribute it,
|
|
# with or without modifications, as long as this notice is preserved.
|
|
|
|
# This is a copy of AC_C_VARARRAYS from a recent development version
|
|
# of Autoconf. It replaces Autoconf's version, or for pre-2.61 autoconf
|
|
# it defines the macro that Autoconf lacks.
|
|
AC_DEFUN([AC_C_VARARRAYS],
|
|
[
|
|
AC_CACHE_CHECK([for variable-length arrays],
|
|
ac_cv_c_vararrays,
|
|
[AC_EGREP_CPP([defined],
|
|
[#ifdef __STDC_NO_VLA__
|
|
defined
|
|
#endif
|
|
],
|
|
[ac_cv_c_vararrays='no: __STDC_NO_VLA__ is defined'],
|
|
[AC_COMPILE_IFELSE(
|
|
[AC_LANG_PROGRAM(
|
|
[[/* Test for VLA support. This test is partly inspired
|
|
from examples in the C standard. Use at least two VLA
|
|
functions to detect the GCC 3.4.3 bug described in:
|
|
https://lists.gnu.org/archive/html/bug-gnulib/2014-08/msg00014.html
|
|
*/
|
|
#ifdef __STDC_NO_VLA__
|
|
syntax error;
|
|
#else
|
|
extern int n;
|
|
int B[100];
|
|
int fvla (int m, int C[m][m]);
|
|
|
|
int
|
|
simple (int count, int all[static count])
|
|
{
|
|
return all[count - 1];
|
|
}
|
|
|
|
int
|
|
fvla (int m, int C[m][m])
|
|
{
|
|
typedef int VLA[m][m];
|
|
VLA x;
|
|
int D[m];
|
|
static int (*q)[m] = &B;
|
|
int (*s)[n] = q;
|
|
return C && &x[0][0] == &D[0] && &D[0] == s[0];
|
|
}
|
|
#endif
|
|
]])],
|
|
[ac_cv_c_vararrays=yes],
|
|
[ac_cv_c_vararrays=no])])])
|
|
if test "$ac_cv_c_vararrays" = yes; then
|
|
dnl This is for compatibility with Autoconf 2.61-2.69.
|
|
AC_DEFINE([HAVE_C_VARARRAYS], 1,
|
|
[Define to 1 if C supports variable-length arrays.])
|
|
elif test "$ac_cv_c_vararrays" = no; then
|
|
AC_DEFINE([__STDC_NO_VLA__], 1,
|
|
[Define to 1 if C does not support variable-length arrays, and
|
|
if the compiler does not already define this.])
|
|
fi
|
|
])
|