mirror of
https://git.savannah.gnu.org/git/emacs.git
synced 2024-12-29 11:02:01 +00:00
79f15092b9
This incorporates:
2018-05-21 crypto: omit stream ops Emacs doesn’t need
2018-05-13 truncate: Fix compilation error on Android
2018-05-13 imaxdiv: Fix compilation error on Android
2018-05-13 Support selective inclusion of recent mingw.org headers
2018-05-13 Add cross-compilation guesses for Linux systems sans glibc
2018-05-13 stdioext: Fix compilation errors with newer Android headers
2018-05-07 af_alg: Pacify --enable-gcc-warnings
2018-05-06 af_alg: Fix bug with streams that are not at position 0
2018-05-06 Followup to 'af_alg: New module'
2018-05-05 crypto/{md5,sha1,sha256,sha512}: simplify
2018-05-05 af_alg: New module
2018-05-05 af_alg: Improve function signature
2018-04-28 md5sum: Use AF_ALG when available
2018-04-28 sha512sum: Use AF_ALG when available
2018-04-28 sha256sum: Use AF_ALG when available
2018-04-28 sha1sum: Use AF_ALG when available
2018-05-05 all: Replace more http URLs by https URLs
2018-05-03 maint: port more modules to GCC 8
2018-05-03 Simplify code; drop support for Borland C++ on Windows
* admin/merge-gnulib (GNULIB_MODULES): Use crypto/md5-buffer
rather than crypto/md5, since Emacs doesn’t use the stream
operations that in recent Gnulib pull in other stuff Emacs doesn’t
need. Similarly for crypto/sha1-buffer, crypto/sha256-buffer,
crypto/sha512-buffer.
* build-aux/config.guess, build-aux/config.sub, lib/dosname.h:
* lib/dup2.c, lib/errno.in.h, lib/euidaccess.c, lib/fcntl.c:
* lib/fcntl.in.h, lib/fpending.c, lib/fsync.c, lib/getdtablesize.c:
* lib/getopt.c, lib/gettimeofday.c, lib/inttypes.in.h, lib/md5.c:
* lib/md5.h, lib/open.c, lib/pipe2.c, lib/putenv.c, lib/sha1.c:
* lib/sha1.h, lib/sha256.c, lib/sha256.h, lib/sha512.c:
* lib/sha512.h, lib/stat-time.h, lib/stdio-impl.h, lib/stdio.in.h:
* lib/stdlib.in.h, lib/sys_stat.in.h, lib/sys_types.in.h:
* lib/timespec.h, lib/unistd.in.h, lib/utimens.c, m4/c-strtod.m4:
* m4/gnulib-common.m4, m4/inttypes.m4, m4/lstat.m4, m4/nocrash.m4:
* m4/pselect.m4, m4/readlink.m4, m4/stdio_h.m4, m4/symlink.m4:
* m4/unistd_h.m4, m4/utimens.m4:
Copy from Gnulib.
* lib/gnulib.mk.in, m4/gnulib-comp.m4: Regenerate.
77 lines
2.4 KiB
Plaintext
77 lines
2.4 KiB
Plaintext
# c-strtod.m4 serial 16
|
|
|
|
# Copyright (C) 2004-2006, 2009-2018 Free Software Foundation, Inc.
|
|
# This file is free software; the Free Software Foundation
|
|
# gives unlimited permission to copy and/or distribute it,
|
|
# with or without modifications, as long as this notice is preserved.
|
|
|
|
# Written by Paul Eggert.
|
|
|
|
AC_DEFUN([gl_C99_STRTOLD],
|
|
[
|
|
AC_CACHE_CHECK([whether strtold conforms to C99],
|
|
[gl_cv_func_c99_strtold],
|
|
[AC_LINK_IFELSE(
|
|
[AC_LANG_PROGRAM(
|
|
[[/* On HP-UX before 11.23, strtold returns a struct instead of
|
|
long double. Reject implementations like that, by requiring
|
|
compatibility with the C99 prototype. */
|
|
#include <stdlib.h>
|
|
static long double (*p) (char const *, char **) = strtold;
|
|
static long double
|
|
test (char const *nptr, char **endptr)
|
|
{
|
|
long double r;
|
|
r = strtold (nptr, endptr);
|
|
return r;
|
|
}]],
|
|
[[return test ("1.0", NULL) != 1 || p ("1.0", NULL) != 1;]])],
|
|
[gl_cv_func_c99_strtold=yes],
|
|
[gl_cv_func_c99_strtold=no])])
|
|
if test $gl_cv_func_c99_strtold = yes; then
|
|
AC_DEFINE([HAVE_C99_STRTOLD], [1], [Define to 1 if strtold conforms to C99.])
|
|
fi
|
|
])
|
|
|
|
dnl Prerequisites of lib/c-strtod.c.
|
|
AC_DEFUN([gl_C_STRTOD],
|
|
[
|
|
AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
|
|
|
|
AC_CHECK_HEADERS_ONCE([xlocale.h])
|
|
dnl We can't use AC_CHECK_FUNC here, because strtod_l() is defined as a
|
|
dnl static inline function when compiling for Android 7.1 or older.
|
|
AC_CACHE_CHECK([for strtod_l], [gl_cv_func_strtod_l],
|
|
[AC_LINK_IFELSE(
|
|
[AC_LANG_PROGRAM(
|
|
[[#include <stdlib.h>
|
|
#include <locale.h>
|
|
#if HAVE_XLOCALE_H
|
|
# include <xlocale.h>
|
|
#endif
|
|
locale_t loc;
|
|
]],
|
|
[[char *end;
|
|
return strtod_l("0",&end,loc) < 0.0;
|
|
]])
|
|
],
|
|
[gl_cv_func_strtod_l=yes],
|
|
[gl_cv_func_strtod_l=no])
|
|
])
|
|
if test $gl_cv_func_strtod_l = yes; then
|
|
HAVE_STRTOD_L=1
|
|
else
|
|
HAVE_STRTOD_L=0
|
|
fi
|
|
AC_DEFINE_UNQUOTED([HAVE_STRTOD_L], [$HAVE_STRTOD_L],
|
|
[Define to 1 if the system has the 'strtod_l' function.])
|
|
])
|
|
|
|
dnl Prerequisites of lib/c-strtold.c.
|
|
AC_DEFUN([gl_C_STRTOLD],
|
|
[
|
|
AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
|
|
AC_REQUIRE([gl_C99_STRTOLD])
|
|
AC_CHECK_FUNCS([strtold_l])
|
|
])
|