mirror of
https://git.savannah.gnu.org/git/emacs.git
synced 2025-01-21 18:23:59 +00:00
3b7b181bde
`string-search` is easier to understand, less error-prone, much faster, does not pollute the regexp cache, and does not mutate global state. Use it where applicable and obviously safe (erring on the conservative side). * admin/authors.el (authors-canonical-file-name) (authors-scan-change-log): * lisp/apropos.el (apropos-command) (apropos-documentation-property, apropos-symbols-internal): * lisp/arc-mode.el (archive-arc-summarize) (archive-zoo-summarize): * lisp/calc/calc-aent.el (math-read-factor): * lisp/calc/calc-ext.el (math-read-big-expr) (math-format-nice-expr, math-format-number-fancy): * lisp/calc/calc-forms.el (math-read-angle-brackets): * lisp/calc/calc-graph.el (calc-graph-set-range): * lisp/calc/calc-keypd.el (calc-keypad-press): * lisp/calc/calc-lang.el (tex, latex, math-read-big-rec): * lisp/calc/calc-prog.el (calc-fix-token-name) (calc-user-define-permanent, math-define-exp): * lisp/calc/calc.el (calc-record, calcDigit-key) (calc-count-lines): * lisp/calc/calcalg2.el (calc-solve-for, calc-poly-roots) (math-do-integral): * lisp/calc/calcalg3.el (calc-find-root, calc-find-minimum) (calc-get-fit-variables): * lisp/cedet/ede/speedbar.el (ede-tag-expand): * lisp/cedet/semantic/java.el (semantic-java-expand-tag): * lisp/cedet/semantic/sb.el (semantic-sb-show-extra) (semantic-sb-expand-group): * lisp/cedet/semantic/wisent/python.el (semantic-python-instance-variable-p): * lisp/cus-edit.el (get): * lisp/descr-text.el (describe-text-sexp): * lisp/dired-aux.el (dired-compress-file): * lisp/dired-x.el (dired-make-relative-symlink): * lisp/dired.el (dired-glob-regexp): * lisp/dos-fns.el (dos-convert-standard-filename, dos-8+3-filename): * lisp/edmacro.el (edmacro-format-keys): * lisp/emacs-lisp/eieio-opt.el (eieio-sb-expand): * lisp/emacs-lisp/eieio-speedbar.el (eieio-speedbar-object-expand): * lisp/emacs-lisp/lisp-mnt.el (lm-keywords-list): * lisp/emacs-lisp/warnings.el (display-warning): * lisp/emulation/viper-ex.el (viper-ex-read-file-name) (ex-print-display-lines): * lisp/env.el (read-envvar-name, setenv): * lisp/epa-mail.el (epa-mail-encrypt): * lisp/epg.el (epg--start): * lisp/erc/erc-backend.el (erc-parse-server-response): * lisp/erc/erc-dcc.el (erc-dcc-member): * lisp/erc/erc-speedbar.el (erc-speedbar-expand-server) (erc-speedbar-expand-channel, erc-speedbar-expand-user): * lisp/erc/erc.el (erc-send-input): * lisp/eshell/em-glob.el (eshell-glob-entries): * lisp/eshell/esh-proc.el (eshell-needs-pipe-p): * lisp/eshell/esh-util.el (eshell-convert): * lisp/eshell/esh-var.el (eshell-envvar-names): * lisp/faces.el (x-resolve-font-name): * lisp/ffap.el (ffap-file-at-point): * lisp/files.el (wildcard-to-regexp, shell-quote-wildcard-pattern): * lisp/forms.el (forms--update): * lisp/frameset.el (frameset-filter-unshelve-param): * lisp/gnus/gnus-art.el (article-decode-charset): * lisp/gnus/gnus-kill.el (gnus-kill-parse-rn-kill-file): * lisp/gnus/gnus-mlspl.el (gnus-group-split-fancy): * lisp/gnus/gnus-msg.el (gnus-summary-resend-message-insert-gcc) (gnus-inews-insert-gcc): * lisp/gnus/gnus-rfc1843.el (rfc1843-decode-article-body): * lisp/gnus/gnus-search.el (gnus-search-indexed-parse-output) (gnus-search--complete-key-data): * lisp/gnus/gnus-spec.el (gnus-parse-simple-format): * lisp/gnus/gnus-sum.el (gnus-summary-refer-article): * lisp/gnus/gnus-util.el (gnus-extract-address-components) (gnus-newsgroup-directory-form): * lisp/gnus/gnus-uu.el (gnus-uu-grab-view): * lisp/gnus/gnus.el (gnus-group-native-p, gnus-short-group-name): * lisp/gnus/message.el (message-check-news-header-syntax) (message-make-message-id, message-user-mail-address) (message-make-fqdn, message-get-reply-headers, message-followup): * lisp/gnus/mm-decode.el (mm-dissect-buffer): * lisp/gnus/nnheader.el (nnheader-insert): * lisp/gnus/nnimap.el (nnimap-process-quirk) (nnimap-imap-ranges-to-gnus-ranges): * lisp/gnus/nnmaildir.el (nnmaildir--ensure-suffix): * lisp/gnus/nnmairix.el (nnmairix-determine-original-group-from-path): * lisp/gnus/nnrss.el (nnrss-match-macro): * lisp/gnus/nntp.el (nntp-find-group-and-number): * lisp/help-fns.el (help--symbol-completion-table-affixation): * lisp/help.el (help-function-arglist): * lisp/hippie-exp.el (he-concat-directory-file-name): * lisp/htmlfontify.el (hfy-relstub): * lisp/ido.el (ido-make-prompt, ido-complete, ido-copy-current-word) (ido-exhibit): * lisp/image/image-converter.el (image-convert-p): * lisp/info-xref.el (info-xref-docstrings): * lisp/info.el (Info-toc-build, Info-follow-reference) (Info-backward-node, Info-finder-find-node) (Info-speedbar-expand-node): * lisp/international/mule-diag.el (print-fontset-element): * lisp/language/korea-util.el (default-korean-keyboard): * lisp/linum.el (linum-after-change): * lisp/mail/ietf-drums.el (ietf-drums-parse-address): * lisp/mail/mail-utils.el (mail-dont-reply-to): * lisp/mail/rfc2047.el (rfc2047-encode-1, rfc2047-decode-string): * lisp/mail/rfc2231.el (rfc2231-parse-string): * lisp/mail/rmailkwd.el (rmail-set-label): * lisp/mail/rmailsum.el (rmail-header-summary): * lisp/mail/smtpmail.el (smtpmail-maybe-append-domain) (smtpmail-user-mail-address): * lisp/mail/uce.el (uce-reply-to-uce): * lisp/man.el (Man-default-man-entry): * lisp/mh-e/mh-alias.el (mh-alias-gecos-name) (mh-alias-minibuffer-confirm-address): * lisp/mh-e/mh-comp.el (mh-forwarded-letter-subject): * lisp/mh-e/mh-speed.el (mh-speed-parse-flists-output): * lisp/mh-e/mh-utils.el (mh-collect-folder-names-filter) (mh-folder-completion-function): * lisp/minibuffer.el (completion--make-envvar-table) (completion-file-name-table, completion-flex-try-completion) (completion-flex-all-completions): * lisp/mpc.el (mpc--proc-quote-string, mpc-cmd-special-tag-p) (mpc-constraints-tag-lookup): * lisp/net/ange-ftp.el (ange-ftp-send-cmd) (ange-ftp-allow-child-lookup): * lisp/net/mailcap.el (mailcap-mime-types): * lisp/net/mairix.el (mairix-search-thread-this-article): * lisp/net/pop3.el (pop3-open-server): * lisp/net/soap-client.el (soap-decode-xs-complex-type): * lisp/net/socks.el (socks-filter): * lisp/nxml/nxml-outln.el (nxml-highlighted-qname): * lisp/nxml/rng-cmpct.el (rng-c-expand-name, rng-c-expand-datatype): * lisp/nxml/rng-uri.el (rng-uri-file-name-1): * lisp/obsolete/complete.el (partial-completion-mode) (PC-do-completion): * lisp/obsolete/longlines.el (longlines-encode-string): * lisp/obsolete/nnir.el (nnir-compose-result): * lisp/obsolete/terminal.el (te-quote-arg-for-sh): * lisp/obsolete/tpu-edt.el (tpu-check-search-case): * lisp/obsolete/url-ns.el (isPlainHostName): * lisp/pcmpl-unix.el (pcomplete/scp): * lisp/play/dunnet.el (dun-listify-string2, dun-get-path) (dun-unix-parse, dun-doassign, dun-cat, dun-batch-unix-interface): * lisp/progmodes/ebnf2ps.el: (ebnf-eps-header-footer-comment): * lisp/progmodes/gdb-mi.el (gdb-var-delete) (gdb-speedbar-expand-node, gdbmi-bnf-incomplete-record-result): * lisp/progmodes/gud.el (gud-find-expr): * lisp/progmodes/idlw-help.el (idlwave-do-context-help1): * lisp/progmodes/idlw-shell.el (idlwave-shell-mode) (idlwave-shell-filter-hidden-output, idlwave-shell-filter): * lisp/progmodes/idlwave.el (idlwave-skip-label-or-case) (idlwave-routine-info): * lisp/progmodes/octave.el (inferior-octave-completion-at-point): * lisp/progmodes/sh-script.el (sh-add-completer): * lisp/progmodes/sql.el (defun): * lisp/progmodes/xscheme.el (xscheme-process-filter): * lisp/replace.el (query-replace-compile-replacement) (map-query-replace-regexp): * lisp/shell.el (shell--command-completion-data) (shell-environment-variable-completion): * lisp/simple.el (display-message-or-buffer): * lisp/speedbar.el (speedbar-dired, speedbar-tag-file) (speedbar-tag-expand): * lisp/subr.el (split-string-and-unquote): * lisp/tar-mode.el (tar-extract): * lisp/term.el (term-command-hook, serial-read-name): * lisp/textmodes/bibtex.el (bibtex-print-help-message): * lisp/textmodes/ispell.el (ispell-lookup-words, ispell-filter) (ispell-parse-output, ispell-buffer-local-parsing): * lisp/textmodes/reftex-cite.el (reftex-do-citation): * lisp/textmodes/reftex-parse.el (reftex-notice-new): * lisp/textmodes/reftex-ref.el (reftex-show-entry): * lisp/textmodes/reftex.el (reftex-compile-variables): * lisp/textmodes/tex-mode.el (tex-send-command) (tex-start-tex, tex-append): * lisp/thingatpt.el (thing-at-point-url-at-point): * lisp/tmm.el (tmm-add-one-shortcut): * lisp/transient.el (transient-format-key): * lisp/url/url-auth.el (url-basic-auth) (url-digest-auth-directory-id-assoc): * lisp/url/url-news.el (url-news): * lisp/url/url-util.el (url-parse-query-string): * lisp/vc/vc-cvs.el (vc-cvs-parse-entry): * lisp/wid-browse.el (widget-browse-sexp): * lisp/woman.el (woman-parse-colon-path, woman-mini-help) (WoMan-getpage-in-background, woman-negative-vertical-space): * lisp/xml.el: * test/lisp/emacs-lisp/check-declare-tests.el (check-declare-tests-warn): * test/lisp/files-tests.el (files-tests-file-name-non-special-dired-compress-handler): * test/lisp/net/network-stream-tests.el (server-process-filter): * test/src/coding-tests.el (ert-test-unibyte-buffer-dos-eol-decode): Use `string-search` instead of `string-match` and `string-match-p`.
279 lines
9.0 KiB
EmacsLisp
279 lines
9.0 KiB
EmacsLisp
;;; epa-mail.el --- the EasyPG Assistant, minor-mode for mail composer -*- lexical-binding: t -*-
|
|
|
|
;; Copyright (C) 2006-2021 Free Software Foundation, Inc.
|
|
|
|
;; Author: Daiki Ueno <ueno@unixuser.org>
|
|
;; Keywords: PGP, GnuPG, mail, message
|
|
;; Package: epa
|
|
|
|
;; This file is part of GNU Emacs.
|
|
|
|
;; GNU Emacs is free software: you can redistribute it and/or modify
|
|
;; it under the terms of the GNU General Public License as published by
|
|
;; the Free Software Foundation, either version 3 of the License, or
|
|
;; (at your option) any later version.
|
|
|
|
;; GNU Emacs is distributed in the hope that it will be useful,
|
|
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
;; GNU General Public License for more details.
|
|
|
|
;; You should have received a copy of the GNU General Public License
|
|
;; along with GNU Emacs. If not, see <https://www.gnu.org/licenses/>.
|
|
|
|
;;; Code:
|
|
;;; Dependencies
|
|
|
|
(require 'epa)
|
|
(require 'mail-utils)
|
|
|
|
;;; Local Mode
|
|
|
|
(defvar epa-mail-mode-map
|
|
(let ((keymap (make-sparse-keymap)))
|
|
(define-key keymap "\C-c\C-ed" 'epa-mail-decrypt)
|
|
(define-key keymap "\C-c\C-ev" 'epa-mail-verify)
|
|
(define-key keymap "\C-c\C-es" 'epa-mail-sign)
|
|
(define-key keymap "\C-c\C-ee" 'epa-mail-encrypt)
|
|
(define-key keymap "\C-c\C-ei" 'epa-mail-import-keys)
|
|
(define-key keymap "\C-c\C-eo" 'epa-insert-keys)
|
|
(define-key keymap "\C-c\C-e\C-d" 'epa-mail-decrypt)
|
|
(define-key keymap "\C-c\C-e\C-v" 'epa-mail-verify)
|
|
(define-key keymap "\C-c\C-e\C-s" 'epa-mail-sign)
|
|
(define-key keymap "\C-c\C-e\C-e" 'epa-mail-encrypt)
|
|
(define-key keymap "\C-c\C-e\C-i" 'epa-mail-import-keys)
|
|
(define-key keymap "\C-c\C-e\C-o" 'epa-insert-keys)
|
|
keymap))
|
|
|
|
(defvar epa-mail-mode-hook nil)
|
|
(defvar epa-mail-mode-on-hook nil)
|
|
(defvar epa-mail-mode-off-hook nil)
|
|
|
|
(defcustom epa-mail-offer-skip t
|
|
"If non-nil, when a recipient has no key, ask whether to skip it.
|
|
Otherwise, signal an error."
|
|
:type 'boolean
|
|
:version "28.1"
|
|
:group 'epa-mail)
|
|
|
|
;;;###autoload
|
|
(define-minor-mode epa-mail-mode
|
|
"A minor-mode for composing encrypted/clearsigned mails."
|
|
:lighter " epa-mail")
|
|
|
|
;;; Utilities
|
|
|
|
(defun epa-mail--find-usable-key (keys usage)
|
|
"Find a usable key from KEYS for USAGE.
|
|
USAGE would be `sign' or `encrypt'."
|
|
(catch 'found
|
|
(while keys
|
|
(let ((pointer (epg-key-sub-key-list (car keys))))
|
|
(while pointer
|
|
(if (and (memq usage (epg-sub-key-capability (car pointer)))
|
|
(not (memq (epg-sub-key-validity (car pointer))
|
|
'(revoked expired))))
|
|
(throw 'found (car keys)))
|
|
(setq pointer (cdr pointer))))
|
|
(setq keys (cdr keys)))))
|
|
|
|
;;; Commands
|
|
|
|
;;;###autoload
|
|
(defun epa-mail-decrypt ()
|
|
"Decrypt OpenPGP armors in the current buffer.
|
|
The buffer is expected to contain a mail message."
|
|
(declare (interactive-only t))
|
|
(interactive)
|
|
(with-suppressed-warnings ((interactive-only epa-decrypt-armor-in-region))
|
|
(epa-decrypt-armor-in-region (point-min) (point-max))))
|
|
|
|
;;;###autoload
|
|
(defun epa-mail-verify ()
|
|
"Verify OpenPGP cleartext signed messages in the current buffer.
|
|
The buffer is expected to contain a mail message."
|
|
(declare (interactive-only t))
|
|
(interactive)
|
|
(with-suppressed-warnings ((interactive-only epa-verify-cleartext-in-region))
|
|
(epa-verify-cleartext-in-region (point-min) (point-max))))
|
|
|
|
;;;###autoload
|
|
(defun epa-mail-sign (start end signers mode)
|
|
"Sign the current buffer.
|
|
The buffer is expected to contain a mail message, and signing is
|
|
performed with your default key.
|
|
With prefix argument, asks you to select interactively the key to
|
|
use from your key ring."
|
|
(declare (interactive-only t))
|
|
(interactive
|
|
(save-excursion
|
|
(goto-char (point-min))
|
|
(rfc822-goto-eoh)
|
|
(unless (eobp)
|
|
(forward-line))
|
|
(setq epa-last-coding-system-specified
|
|
(or coding-system-for-write
|
|
(select-safe-coding-system (point) (point-max))))
|
|
(let ((verbose current-prefix-arg))
|
|
(list (point) (point-max)
|
|
(if verbose
|
|
(epa-select-keys (epg-make-context epa-protocol)
|
|
"Select keys for signing.
|
|
If no one is selected, default secret key is used. "
|
|
nil t))
|
|
(if verbose
|
|
(epa--read-signature-type)
|
|
'clear)))))
|
|
(let ((inhibit-read-only t))
|
|
(with-suppressed-warnings ((interactive-only epa-sign-region))
|
|
(epa-sign-region start end signers mode))))
|
|
|
|
(defun epa-mail-default-recipients ()
|
|
"Return the default list of encryption recipients for a mail buffer."
|
|
(let ((config (epg-find-configuration 'OpenPGP))
|
|
recipients-string real-recipients)
|
|
(save-excursion
|
|
(goto-char (point-min))
|
|
(save-restriction
|
|
(narrow-to-region (point)
|
|
(progn (rfc822-goto-eoh) (point)))
|
|
(setq recipients-string
|
|
(mapconcat #'identity
|
|
(nconc (mail-fetch-field "to" nil nil t)
|
|
(mail-fetch-field "cc" nil nil t)
|
|
(mail-fetch-field "bcc" nil nil t))
|
|
","))
|
|
(setq recipients-string
|
|
(mail-strip-quoted-names
|
|
(with-temp-buffer
|
|
(insert "to: " recipients-string "\n")
|
|
(expand-mail-aliases (point-min) (point-max))
|
|
(car (mail-fetch-field "to" nil nil t))))))
|
|
|
|
(setq real-recipients
|
|
(split-string recipients-string "," t "[ \t\n]*"))
|
|
|
|
;; Process all the recipients thru the list of GnuPG groups.
|
|
;; Expand GnuPG group names to what they stand for.
|
|
(setq real-recipients
|
|
(apply #'nconc
|
|
(mapcar
|
|
(lambda (recipient)
|
|
(or (epg-expand-group config recipient)
|
|
(list recipient)))
|
|
real-recipients)))
|
|
|
|
;; Process all the recipients thru the user's list
|
|
;; of encryption aliases.
|
|
(setq real-recipients
|
|
(apply #'nconc
|
|
(mapcar
|
|
(lambda (recipient)
|
|
(let ((tem (assoc (downcase recipient) epa-mail-aliases)))
|
|
(if tem (copy-sequence (cdr tem))
|
|
(list recipient))))
|
|
real-recipients)))
|
|
)))
|
|
|
|
;;;###autoload
|
|
(defun epa-mail-encrypt (&optional recipients signers)
|
|
"Encrypt the outgoing mail message in the current buffer.
|
|
Takes the recipients from the text in the header in the buffer
|
|
and translates them through `epa-mail-aliases'.
|
|
With prefix argument, asks you to select among them interactively
|
|
and also whether and how to sign.
|
|
|
|
Called from Lisp, the optional argument RECIPIENTS is a list
|
|
of recipient addresses, t to perform symmetric encryption,
|
|
or nil meaning use the defaults.
|
|
|
|
SIGNERS is a list of keys to sign the message with."
|
|
(interactive
|
|
(let ((verbose current-prefix-arg)
|
|
(context (epg-make-context epa-protocol)))
|
|
(list (if verbose
|
|
(or (epa-select-keys
|
|
context
|
|
"Select recipients for encryption.
|
|
If no one is selected, symmetric encryption will be performed. "
|
|
(epa-mail-default-recipients))
|
|
t))
|
|
(and verbose (y-or-n-p "Sign? ")
|
|
(epa-select-keys context
|
|
"Select keys for signing. ")))))
|
|
(let (start recipient-keys default-recipients)
|
|
(save-excursion
|
|
(setq recipient-keys
|
|
(cond ((eq recipients t)
|
|
nil)
|
|
(recipients recipients)
|
|
(t
|
|
(setq default-recipients
|
|
(epa-mail-default-recipients))
|
|
;; Convert recipients to keys.
|
|
(apply
|
|
'nconc
|
|
(mapcar
|
|
(lambda (recipient)
|
|
(let ((recipient-key
|
|
(epa-mail--find-usable-key
|
|
(epg-list-keys
|
|
(epg-make-context epa-protocol)
|
|
(if (string-search "@" recipient)
|
|
(concat "<" recipient ">")
|
|
recipient))
|
|
'encrypt)))
|
|
(unless (or recipient-key
|
|
(and epa-mail-offer-skip
|
|
(y-or-n-p
|
|
(format
|
|
"No public key for %s; skip it? "
|
|
recipient)))
|
|
)
|
|
(error "No public key for %s" recipient))
|
|
(if recipient-key (list recipient-key))))
|
|
default-recipients)))))
|
|
|
|
(goto-char (point-min))
|
|
(rfc822-goto-eoh)
|
|
(unless (eobp)
|
|
(forward-line))
|
|
(setq start (point))
|
|
|
|
(setq epa-last-coding-system-specified
|
|
(or coding-system-for-write
|
|
(select-safe-coding-system (point) (point-max)))))
|
|
|
|
;; Insert contents of requested attachments, if any.
|
|
(when (and (eq major-mode 'mail-mode) mail-encode-mml)
|
|
(mml-to-mime)
|
|
(setq mail-encode-mml nil))
|
|
|
|
;; Don't let some read-only text stop us from encrypting.
|
|
(let ((inhibit-read-only t))
|
|
(with-suppressed-warnings ((interactive-only epa-encrypt-region))
|
|
(epa-encrypt-region start (point-max)
|
|
recipient-keys signers signers)))))
|
|
|
|
;;;###autoload
|
|
(defun epa-mail-import-keys ()
|
|
"Import keys in the OpenPGP armor format in the current buffer.
|
|
The buffer is expected to contain a mail message."
|
|
(declare (interactive-only t))
|
|
(interactive)
|
|
(epa-import-armor-in-region (point-min) (point-max)))
|
|
|
|
;;; Global Mode
|
|
|
|
;;;###autoload
|
|
(define-minor-mode epa-global-mail-mode
|
|
"Minor mode to hook EasyPG into Mail mode."
|
|
:global t :init-value nil :group 'epa-mail :version "23.1"
|
|
(remove-hook 'mail-mode-hook 'epa-mail-mode)
|
|
(if epa-global-mail-mode
|
|
(add-hook 'mail-mode-hook 'epa-mail-mode)))
|
|
|
|
(provide 'epa-mail)
|
|
|
|
;;; epa-mail.el ends here
|