mirror of
https://git.savannah.gnu.org/git/emacs.git
synced 2024-11-24 07:20:37 +00:00
64d1b9fd8a
This incorporates: 2019-12-23 mktime, nstrftime: tweak division performance 2019-12-22 count-leading-zeros: assume 'long long' 2019-12-22 count-one-bits: assume 'long long' 2019-12-22 count-trailing-zeros: assume 'long long' 2019-12-12 inttypes-incomplete: assume 'long long' 2019-12-22 malloca: assume 'long long' 2019-12-22 stdint: assume 'long long' 2019-12-22 strtoll, strtoimax, strtoumax: assume 'long long' 2019-12-22 prefer lib_SOURCES to unconditional AC_LIBOBJ 2019-12-19 nstrftime: avoid a shadowing warning 2019-12-18 improve port of AC_C_RESTRICT to Oracle C++ 2019-12-12 stdalign: port to xlclang 16.01 2019-12-11 stddef, unistd: fix compilation error in C++ mode on MSVC 2019-12-08 fix compilation errors in C++ mode on Haiku 2019-12-08 fix compilation errors in 32-bit C++ mode on HP-UX 11/ia64 2019-12-08 fix compilation error in C++ mode on OpenBSD * build-aux/config.guess, doc/misc/texinfo.tex: * lib/count-leading-zeros.h, lib/count-one-bits.h: * lib/count-trailing-zeros.h, lib/inttypes.in.h, lib/malloca.h: * lib/mktime.c, lib/nstrftime.c, lib/signal.in.h, lib/stdalign.in.h: * lib/stddef.in.h, lib/stdint.in.h, lib/stdio.in.h, lib/stdlib.in.h: * lib/strtoimax.c, lib/unistd.in.h, m4/gnulib-common.m4: * m4/inttypes.m4, m4/largefile.m4, m4/malloca.m4, m4/strtoimax.m4: * m4/strtoll.m4: Copy from Gnulib. Also, change copyright notices in some other Gnulib-copied files to exactly match Gnulib, as Gnulib updated them in a trivially different way. * lib/gnulib.mk.in, m4/gnulib-comp.m4: Regenerate.
110 lines
4.0 KiB
Plaintext
110 lines
4.0 KiB
Plaintext
# serial 23
|
|
|
|
dnl From Jim Meyering.
|
|
dnl A wrapper around AC_FUNC_GETGROUPS.
|
|
|
|
# Copyright (C) 1996-1997, 1999-2004, 2008-2020 Free Software Foundation, Inc.
|
|
#
|
|
# This file is free software; the Free Software Foundation
|
|
# gives unlimited permission to copy and/or distribute it,
|
|
# with or without modifications, as long as this notice is preserved.
|
|
|
|
# This is taken from the following Autoconf patch:
|
|
# https://git.savannah.gnu.org/gitweb/?p=autoconf.git;a=commitdiff;h=7fbb553727ed7e0e689a17594b58559ecf3ea6e9
|
|
AC_DEFUN([AC_FUNC_GETGROUPS],
|
|
[
|
|
AC_REQUIRE([AC_TYPE_GETGROUPS])dnl
|
|
AC_REQUIRE([AC_TYPE_SIZE_T])dnl
|
|
AC_REQUIRE([AC_CANONICAL_HOST])dnl for cross-compiles
|
|
AC_CHECK_FUNC([getgroups])
|
|
|
|
# If we don't yet have getgroups, see if it's in -lbsd.
|
|
# This is reported to be necessary on an ITOS 3000WS running SEIUX 3.1.
|
|
ac_save_LIBS=$LIBS
|
|
if test $ac_cv_func_getgroups = no; then
|
|
AC_CHECK_LIB(bsd, getgroups, [GETGROUPS_LIB=-lbsd])
|
|
fi
|
|
|
|
# Run the program to test the functionality of the system-supplied
|
|
# getgroups function only if there is such a function.
|
|
if test $ac_cv_func_getgroups = yes; then
|
|
AC_CACHE_CHECK([for working getgroups], [ac_cv_func_getgroups_works],
|
|
[AC_RUN_IFELSE(
|
|
[AC_LANG_PROGRAM(
|
|
[AC_INCLUDES_DEFAULT],
|
|
[[/* On NeXTstep 3.2, getgroups (0, 0) always fails. */
|
|
return getgroups (0, 0) == -1;]])
|
|
],
|
|
[ac_cv_func_getgroups_works=yes],
|
|
[ac_cv_func_getgroups_works=no],
|
|
[case "$host_os" in # ((
|
|
# Guess yes on glibc systems.
|
|
*-gnu* | gnu*) ac_cv_func_getgroups_works="guessing yes" ;;
|
|
# Guess yes on musl systems.
|
|
*-musl*) ac_cv_func_getgroups_works="guessing yes" ;;
|
|
# If we don't know, obey --enable-cross-guesses.
|
|
*) ac_cv_func_getgroups_works="$gl_cross_guess_normal" ;;
|
|
esac
|
|
])
|
|
])
|
|
else
|
|
ac_cv_func_getgroups_works=no
|
|
fi
|
|
case "$ac_cv_func_getgroups_works" in
|
|
*yes)
|
|
AC_DEFINE([HAVE_GETGROUPS], [1],
|
|
[Define to 1 if your system has a working `getgroups' function.])
|
|
;;
|
|
esac
|
|
LIBS=$ac_save_LIBS
|
|
])# AC_FUNC_GETGROUPS
|
|
|
|
AC_DEFUN([gl_FUNC_GETGROUPS],
|
|
[
|
|
AC_REQUIRE([AC_TYPE_GETGROUPS])
|
|
AC_REQUIRE([gl_UNISTD_H_DEFAULTS])
|
|
AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
|
|
|
|
AC_FUNC_GETGROUPS
|
|
if test $ac_cv_func_getgroups != yes; then
|
|
HAVE_GETGROUPS=0
|
|
else
|
|
if test "$ac_cv_type_getgroups" != gid_t \
|
|
|| { case "$ac_cv_func_getgroups_works" in
|
|
*yes) false;;
|
|
*) true;;
|
|
esac
|
|
}; then
|
|
REPLACE_GETGROUPS=1
|
|
AC_DEFINE([GETGROUPS_ZERO_BUG], [1], [Define this to 1 if
|
|
getgroups(0,NULL) does not return the number of groups.])
|
|
else
|
|
dnl Detect FreeBSD bug; POSIX requires getgroups(-1,ptr) to fail.
|
|
AC_CACHE_CHECK([whether getgroups handles negative values],
|
|
[gl_cv_func_getgroups_works],
|
|
[AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
|
|
[[int size = getgroups (0, 0);
|
|
gid_t *list = malloc (size * sizeof *list);
|
|
int result = getgroups (-1, list) != -1;
|
|
free (list);
|
|
return result;]])],
|
|
[gl_cv_func_getgroups_works=yes],
|
|
[gl_cv_func_getgroups_works=no],
|
|
[case "$host_os" in
|
|
# Guess yes on glibc systems.
|
|
*-gnu* | gnu*) gl_cv_func_getgroups_works="guessing yes" ;;
|
|
# Guess yes on musl systems.
|
|
*-musl*) gl_cv_func_getgroups_works="guessing yes" ;;
|
|
# If we don't know, obey --enable-cross-guesses.
|
|
*) gl_cv_func_getgroups_works="$gl_cross_guess_normal" ;;
|
|
esac
|
|
])])
|
|
case "$gl_cv_func_getgroups_works" in
|
|
*yes) ;;
|
|
*) REPLACE_GETGROUPS=1 ;;
|
|
esac
|
|
fi
|
|
fi
|
|
test -n "$GETGROUPS_LIB" && LIBS="$GETGROUPS_LIB $LIBS"
|
|
])
|