mirror of
https://git.savannah.gnu.org/git/emacs.git
synced 2025-02-04 20:27:45 +00:00
f9ff60e0d7
* doc/lispref/searching.texi (Regexp Special): Mention char classes earlier, in a more-logical place. Advise sticking to ASCII letters and digits in ranges. Reword negative advice to make it clearer that it’s negative. * lisp/files.el (make-auto-save-file-name): * lisp/gnus/message.el (message-mailer-swallows-blank-line): * lisp/gnus/nndoc.el (nndoc-lanl-gov-announce-type-p) (nndoc-generate-lanl-gov-head): * lisp/org/org-eshell.el (org-eshell-open): * lisp/org/org.el (org-deadline-time-hour-regexp) (org-scheduled-time-hour-regexp): * lisp/progmodes/bat-mode.el (bat-font-lock-keywords): * lisp/progmodes/bug-reference.el (bug-reference-bug-regexp): * lisp/textmodes/less-css-mode.el (less-css-font-lock-keywords): * lisp/vc/vc-cvs.el (vc-cvs-valid-symbolic-tag-name-p): * lisp/vc/vc-svn.el (vc-svn-valid-symbolic-tag-name-p): Avoid attempts to chain ranges, as this can be confusing. For example, instead of [0-9-_.], use [0-9_.-].
67 lines
2.2 KiB
EmacsLisp
67 lines
2.2 KiB
EmacsLisp
;;; org-eshell.el - Support for Links to Working Directories in Eshell -*- lexical-binding: t; -*-
|
|
|
|
;; Copyright (C) 2011-2019 Free Software Foundation, Inc.
|
|
|
|
;; Author: Konrad Hinsen <konrad.hinsen AT fastmail.net>
|
|
|
|
;; This file is part of GNU Emacs.
|
|
|
|
;; GNU Emacs is free software: you can redistribute it and/or modify
|
|
;; it under the terms of the GNU General Public License as published by
|
|
;; the Free Software Foundation, either version 3 of the License, or
|
|
;; (at your option) any later version.
|
|
|
|
;; GNU Emacs is distributed in the hope that it will be useful,
|
|
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
;; GNU General Public License for more details.
|
|
|
|
;; You should have received a copy of the GNU General Public License
|
|
;; along with GNU Emacs. If not, see <https://www.gnu.org/licenses/>.
|
|
|
|
;;; Commentary:
|
|
|
|
;;; Code:
|
|
|
|
(require 'org)
|
|
(require 'eshell)
|
|
(require 'esh-mode)
|
|
|
|
(org-link-set-parameters "eshell"
|
|
:follow #'org-eshell-open
|
|
:store #'org-eshell-store-link)
|
|
|
|
(defun org-eshell-open (link)
|
|
"Switch to am eshell buffer and execute a command line.
|
|
The link can be just a command line (executed in the default
|
|
eshell buffer) or a command line prefixed by a buffer name
|
|
followed by a colon."
|
|
(let* ((buffer-and-command
|
|
(if (string-match "\\([A-Za-z0-9+*-]+\\):\\(.*\\)" link)
|
|
(list (match-string 1 link)
|
|
(match-string 2 link))
|
|
(list eshell-buffer-name link)))
|
|
(eshell-buffer-name (car buffer-and-command))
|
|
(command (cadr buffer-and-command)))
|
|
(if (get-buffer eshell-buffer-name)
|
|
(pop-to-buffer-same-window eshell-buffer-name)
|
|
(eshell))
|
|
(goto-char (point-max))
|
|
(eshell-kill-input)
|
|
(insert command)
|
|
(eshell-send-input)))
|
|
|
|
(defun org-eshell-store-link ()
|
|
"Store a link that, when opened, switches back to the current eshell buffer
|
|
and the current working directory."
|
|
(when (eq major-mode 'eshell-mode)
|
|
(let* ((command (concat "cd " dired-directory))
|
|
(link (concat (buffer-name) ":" command)))
|
|
(org-store-link-props
|
|
:link (concat "eshell:" link)
|
|
:description command))))
|
|
|
|
(provide 'org-eshell)
|
|
|
|
;;; org-eshell.el ends here
|