mirror of
https://git.savannah.gnu.org/git/emacs.git
synced 2024-12-20 10:23:57 +00:00
06e21633a4
* abbrev.el (abbrev-mode): * allout.el (allout-mode): * autoinsert.el (auto-insert-mode): * autoarg.el (autoarg-mode, autoarg-kp-mode): * autorevert.el (auto-revert-mode, auto-revert-tail-mode) (global-auto-revert-mode): * battery.el (display-battery-mode): * composite.el (global-auto-composition-mode) (auto-composition-mode): * delsel.el (delete-selection-mode): * desktop.el (desktop-save-mode): * dired-x.el (dired-omit-mode): * dirtrack.el (dirtrack-mode): * doc-view.el (doc-view-minor-mode): * double.el (double-mode): * electric.el (electric-indent-mode, electric-pair-mode): * emacs-lock.el (emacs-lock-mode): * epa-hook.el (auto-encryption-mode): * follow.el (follow-mode): * font-core.el (font-lock-mode): * frame.el (auto-raise-mode, auto-lower-mode, blink-cursor-mode): * help.el (temp-buffer-resize-mode): * hilit-chg.el (highlight-changes-mode) (highlight-changes-visible-mode): * hi-lock.el (hi-lock-mode): * hl-line.el (hl-line-mode, global-hl-line-mode): * icomplete.el (icomplete-mode): * ido.el (ido-everywhere): * image-file.el (auto-image-file-mode): * image-mode.el (image-minor-mode): * iswitchb.el (iswitchb-mode): * jka-cmpr-hook.el (auto-compression-mode): * linum.el (linum-mode): * longlines.el (longlines-mode): * master.el (master-mode): * mb-depth.el (minibuffer-depth-indicate-mode): * menu-bar.el (menu-bar-mode): * minibuf-eldef.el (minibuffer-electric-default-mode): * mouse-sel.el (mouse-sel-mode): * msb.el (msb-mode): * mwheel.el (mouse-wheel-mode): * outline.el (outline-minor-mode): * paren.el (show-paren-mode): * recentf.el (recentf-mode): * reveal.el (reveal-mode, global-reveal-mode): * rfn-eshadow.el (file-name-shadow-mode): * ruler-mode.el (ruler-mode): * savehist.el (savehist-mode): * scroll-all.el (scroll-all-mode): * scroll-bar.el (scroll-bar-mode): * server.el (server-mode): * shell.el (shell-dirtrack-mode): * simple.el (auto-fill-mode, transient-mark-mode) (visual-line-mode, overwrite-mode, binary-overwrite-mode) (line-number-mode, column-number-mode, size-indication-mode) (auto-save-mode, normal-erase-is-backspace-mode, visible-mode): * strokes.el (strokes-mode): * time.el (display-time-mode): * t-mouse.el (gpm-mouse-mode): * tool-bar.el (tool-bar-mode): * tooltip.el (tooltip-mode): * type-break.el (type-break-mode-line-message-mode) (type-break-query-mode): * view.el (view-mode): * whitespace.el (whitespace-mode, whitespace-newline-mode) (global-whitespace-mode, global-whitespace-newline-mode): * xt-mouse.el (xterm-mouse-mode): Doc fix. * emacs-lisp/easy-mmode.el (define-globalized-minor-mode): Fix autogenerated docstring.
122 lines
4.2 KiB
EmacsLisp
122 lines
4.2 KiB
EmacsLisp
;;; scroll-all.el --- scroll all buffers together minor mode
|
|
|
|
;; Copyright (C) 1997, 2001-2011 Free Software Foundation, Inc.
|
|
|
|
;; Author: Gary D. Foster <Gary.Foster@corp.sun.com>
|
|
;; Keywords: scroll crisp brief lock
|
|
|
|
;; This file is part of GNU Emacs.
|
|
|
|
;; GNU Emacs is free software: you can redistribute it and/or modify
|
|
;; it under the terms of the GNU General Public License as published by
|
|
;; the Free Software Foundation, either version 3 of the License, or
|
|
;; (at your option) any later version.
|
|
|
|
;; GNU Emacs is distributed in the hope that it will be useful,
|
|
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
;; GNU General Public License for more details.
|
|
|
|
;; You should have received a copy of the GNU General Public License
|
|
;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>.
|
|
|
|
;;; Commentary:
|
|
;; This mode allows multiple buffers to be 'locked' so that scrolling
|
|
;; up or down lines in any buffer causes all the buffers to mirror
|
|
;; the scrolling. It hooks into the post-command-hook to check for
|
|
;; potential scrolling commands and if we're locked, mirrors them in all
|
|
;; windows. This allows us to grab line-at-a-time scrolling as well as
|
|
;; screen-at-a-time scrolling, and doesn't remap any of the keyboard
|
|
;; commands to do it.
|
|
|
|
;; You can enable and disable this mode with the 'scroll-all-mode' command.
|
|
|
|
;; Suggestions/ideas from:
|
|
;; Rick Macdonald <rickm@vsl.com>
|
|
;; Anders Lindgren <andersl@csd.uu.se>
|
|
|
|
;;; Code:
|
|
|
|
(defun scroll-all-function-all (func arg)
|
|
"Apply function FUNC with argument ARG to all visible windows."
|
|
(let ((num-windows (count-windows))
|
|
(count 1))
|
|
(when (> num-windows 1)
|
|
(other-window 1)
|
|
(while (< count num-windows)
|
|
(condition-case nil
|
|
(funcall func arg)
|
|
;; Ignore beginning- or end-of-buffer error in other windows.
|
|
(error nil)
|
|
)
|
|
(other-window 1)
|
|
(setq count (1+ count))))))
|
|
|
|
(defun scroll-all-scroll-down-all (arg)
|
|
"Scroll down in all visible windows."
|
|
(interactive "p")
|
|
(scroll-all-function-all 'next-line arg))
|
|
|
|
(defun scroll-all-scroll-up-all (arg)
|
|
"Scroll up in all visible windows."
|
|
(interactive "p")
|
|
(scroll-all-function-all 'previous-line arg))
|
|
|
|
(defun scroll-all-page-down-all (arg)
|
|
"Page down in all visible windows."
|
|
(interactive "P")
|
|
(scroll-all-function-all 'scroll-up arg))
|
|
|
|
(defun scroll-all-page-up-all (arg)
|
|
"Page up in all visible windows."
|
|
(interactive "P")
|
|
(scroll-all-function-all 'scroll-down arg))
|
|
|
|
(defun scroll-all-beginning-of-buffer-all (arg)
|
|
"Go to the beginning of the buffer in all visible windows."
|
|
(interactive "P")
|
|
(scroll-all-function-all 'beginning-of-buffer arg))
|
|
|
|
(defun scroll-all-end-of-buffer-all (arg)
|
|
"Go to the end of the buffer in all visible windows."
|
|
(interactive "P")
|
|
(scroll-all-function-all 'end-of-buffer arg))
|
|
|
|
|
|
(defun scroll-all-check-to-scroll ()
|
|
"Check `this-command' to see if a scroll is to be done."
|
|
(cond ((eq this-command 'next-line)
|
|
(call-interactively 'scroll-all-scroll-down-all))
|
|
((eq this-command 'previous-line)
|
|
(call-interactively 'scroll-all-scroll-up-all))
|
|
((memq this-command '(scroll-up scroll-up-command))
|
|
(call-interactively 'scroll-all-page-down-all))
|
|
((memq this-command '(scroll-down scroll-down-command))
|
|
(call-interactively 'scroll-all-page-up-all))
|
|
((eq this-command 'beginning-of-buffer)
|
|
(call-interactively 'scroll-all-beginning-of-buffer-all))
|
|
((eq this-command 'end-of-buffer)
|
|
(call-interactively 'scroll-all-end-of-buffer-all))))
|
|
|
|
|
|
;;;###autoload
|
|
(define-minor-mode scroll-all-mode
|
|
"Toggle shared scrolling in same-frame windows (Scroll-All mode).
|
|
With a prefix argument ARG, enable Scroll-All mode if ARG is
|
|
positive, and disable it otherwise. If called from Lisp, enable
|
|
the mode if ARG is omitted or nil.
|
|
|
|
When Scroll-All mode is enabled, scrolling commands invoked in
|
|
one window apply to all visible windows in the same frame."
|
|
nil " *SL*" nil
|
|
:global t
|
|
:group 'windows
|
|
:group 'scrolling
|
|
(if scroll-all-mode
|
|
(add-hook 'post-command-hook 'scroll-all-check-to-scroll)
|
|
(remove-hook 'post-command-hook 'scroll-all-check-to-scroll)))
|
|
|
|
(provide 'scroll-all)
|
|
|
|
;;; scroll-all.el ends here
|