mirror of
https://git.savannah.gnu.org/git/emacs/org-mode.git
synced 2024-12-03 08:30:03 +00:00
e81a094383
* lisp/org-compat.el (org-assert-version): New macro comparing Org version at compile time and laod time. Add `org-assert-version' call to all files: * lisp/org-macs.el: * lisp/org-crypt.el: * lisp/org-ctags.el: * lisp/org-cycle.el: * lisp/org-datetree.el: * lisp/org-duration.el: * lisp/org-element.el (avl-tree): * lisp/org-entities.el: * lisp/org-faces.el: * lisp/org-feed.el: * lisp/org-fold-core.el: * lisp/org-fold.el: * lisp/org-footnote.el: * lisp/org-goto.el: * lisp/org-habit.el: * lisp/org-id.el: * lisp/org-indent.el: * lisp/org-inlinetask.el: * lisp/org-keys.el: * lisp/org-lint.el: * lisp/org-list.el: * lisp/org-macro.el: * lisp/org-mobile.el: * lisp/org-mouse.el: * lisp/org-num.el: * lisp/org-pcomplete.el: * lisp/org-persist.el: * lisp/org-plot.el: * lisp/org-protocol.el: * lisp/org-refile.el: * lisp/org-src.el: * lisp/org-table.el: * lisp/org-tempo.el: * lisp/org-timer.el: * lisp/org.el: * lisp/ox-ascii.el: * lisp/ox-beamer.el: * lisp/ox-html.el: * lisp/ox-icalendar.el: * lisp/ox-koma-letter.el: * lisp/ox-latex.el: * lisp/ox-man.el: * lisp/ox-md.el: * lisp/ox-odt.el: * lisp/ox-org.el: * lisp/ox-publish.el: * lisp/ox-texinfo.el: * lisp/ox.el:
121 lines
4.2 KiB
EmacsLisp
121 lines
4.2 KiB
EmacsLisp
;;; ol-rmail.el --- Links to Rmail Messages -*- lexical-binding: t; -*-
|
|
|
|
;; Copyright (C) 2004-2022 Free Software Foundation, Inc.
|
|
|
|
;; Author: Carsten Dominik <carsten.dominik@gmail.com>
|
|
;; Keywords: outlines, hypermedia, calendar, wp
|
|
;; URL: https://orgmode.org
|
|
;;
|
|
;; This file is part of GNU Emacs.
|
|
;;
|
|
;; GNU Emacs is free software: you can redistribute it and/or modify
|
|
;; it under the terms of the GNU General Public License as published by
|
|
;; the Free Software Foundation, either version 3 of the License, or
|
|
;; (at your option) any later version.
|
|
|
|
;; GNU Emacs is distributed in the hope that it will be useful,
|
|
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
;; GNU General Public License for more details.
|
|
|
|
;; You should have received a copy of the GNU General Public License
|
|
;; along with GNU Emacs. If not, see <https://www.gnu.org/licenses/>.
|
|
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
|
|
;;
|
|
;;; Commentary:
|
|
|
|
;; This file implements links to Rmail messages from within Org mode.
|
|
;; Org mode loads this module by default - if this is not what you
|
|
;; want, configure the variable `org-modules'.
|
|
|
|
;;; Code:
|
|
|
|
(require 'org-macs)
|
|
(org-assert-version)
|
|
|
|
(require 'ol)
|
|
|
|
;; Declare external functions and variables
|
|
(declare-function rmail-show-message "rmail" (&optional n no-summary))
|
|
(declare-function rmail-what-message "rmail" (&optional pos))
|
|
(declare-function rmail-toggle-header "rmail" (&optional arg))
|
|
(declare-function rmail "rmail" (&optional file-name-arg))
|
|
(declare-function rmail-widen "rmail" ())
|
|
(defvar rmail-current-message) ; From rmail.el
|
|
(defvar rmail-header-style) ; From rmail.el
|
|
(defvar rmail-file-name) ; From rmail.el
|
|
|
|
;; Install the link type
|
|
(org-link-set-parameters "rmail"
|
|
:follow #'org-rmail-open
|
|
:store #'org-rmail-store-link)
|
|
|
|
;; Implementation
|
|
(defun org-rmail-store-link ()
|
|
"Store a link to an Rmail folder or message."
|
|
(when (or (eq major-mode 'rmail-mode)
|
|
(eq major-mode 'rmail-summary-mode))
|
|
(save-window-excursion
|
|
(save-restriction
|
|
(when (eq major-mode 'rmail-summary-mode)
|
|
(rmail-show-message rmail-current-message))
|
|
(when (fboundp 'rmail-narrow-to-non-pruned-header)
|
|
(rmail-narrow-to-non-pruned-header))
|
|
(when (eq rmail-header-style 'normal)
|
|
(rmail-toggle-header -1))
|
|
(let* ((folder buffer-file-name)
|
|
(message-id (mail-fetch-field "message-id"))
|
|
(from (mail-fetch-field "from"))
|
|
(to (mail-fetch-field "to"))
|
|
(subject (mail-fetch-field "subject"))
|
|
(date (mail-fetch-field "date"))
|
|
desc link)
|
|
(org-link-store-props
|
|
:type "rmail" :from from :to to :date date
|
|
:subject subject :message-id message-id)
|
|
(setq message-id (org-unbracket-string "<" ">" message-id))
|
|
(setq desc (org-link-email-description))
|
|
(setq link (concat "rmail:" folder "#" message-id))
|
|
(org-link-add-props :link link :description desc)
|
|
(rmail-show-message rmail-current-message)
|
|
link)))))
|
|
|
|
(defun org-rmail-open (path _)
|
|
"Follow an Rmail message link to the specified PATH."
|
|
(let (folder article)
|
|
(if (not (string-match "\\`\\([^#]+\\)\\(#\\(.*\\)\\)?" path))
|
|
(error "Error in Rmail link"))
|
|
(setq folder (match-string 1 path)
|
|
article (match-string 3 path))
|
|
(org-rmail-follow-link folder article)))
|
|
|
|
(defun org-rmail-follow-link (folder article)
|
|
"Follow an Rmail link to FOLDER and ARTICLE."
|
|
(require 'rmail)
|
|
(cond ((null article) (setq article ""))
|
|
((stringp article)
|
|
(setq article (org-link-add-angle-brackets article)))
|
|
(t (user-error "Wrong RMAIL link format")))
|
|
(let (message-number)
|
|
(save-excursion
|
|
(save-window-excursion
|
|
(rmail (if (string= folder "RMAIL") rmail-file-name folder))
|
|
(setq message-number
|
|
(save-restriction
|
|
(rmail-widen)
|
|
(goto-char (point-max))
|
|
(if (re-search-backward
|
|
(concat "^Message-ID:\\s-+" (regexp-quote article))
|
|
nil t)
|
|
(rmail-what-message))))))
|
|
(if message-number
|
|
(progn
|
|
(rmail (if (string= folder "RMAIL") rmail-file-name folder))
|
|
(rmail-show-message message-number)
|
|
message-number)
|
|
(error "Message not found"))))
|
|
|
|
(provide 'ol-rmail)
|
|
|
|
;;; ol-rmail.el ends here
|