tailwindcss_4: init at 4.0.6 (#382426)

maintainers/maintainer-list.nix

@@ -574,6 +574,11 @@
     githubId = 2071575;
     name = "Adam C. Stephens";
   };
+  adamjhf = {
+    github = "adamjhf";
+    githubId = 50264672;
+    name = "Adam Freeth";
+  };
   adamt = {
     email = "mail@adamtulinius.dk";
     github = "adamtulinius";

pkgs/by-name/ta/tailwindcss_4/package.nix

@@ -0,0 +1,78 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  versionCheckHook,
+  autoPatchelfHook,
+  makeWrapper,
+  tailwindcss_4,
+}:
+let
+  version = "4.0.6";
+  inherit (stdenv.hostPlatform) system;
+  throwSystem = throw "tailwindcss has not been packaged for ${system} yet.";
+
+  plat =
+    {
+      aarch64-darwin = "macos-arm64";
+      aarch64-linux = "linux-arm64";
+      x86_64-darwin = "macos-x64";
+      x86_64-linux = "linux-x64";
+    }
+    .${system} or throwSystem;
+
+  hash =
+    {
+      aarch64-darwin = "sha256-FopnfuGYBjjQkfPHdIWacpom9WsAVRwHPQ/14waWR7s=";
+      aarch64-linux = "sha256-y+9d53skmoSZPhbtk9vUkhKNzIE1A868Lnkw7Cot/PU=";
+      x86_64-darwin = "sha256-rFjaDtPjJO9W6G//7Uu5CJE+pB0sqLrMByC5pv4FA4E=";
+      x86_64-linux = "sha256-14EMXenpvPsKlnu5kebNu3MmfWwa7UYfAgEkh5EwVRM=";
+    }
+    .${system} or throwSystem;
+in
+stdenv.mkDerivation {
+  inherit version;
+  pname = "tailwindcss_4";
+
+  src = fetchurl {
+    url =
+      "https://github.com/tailwindlabs/tailwindcss/releases/download/v${version}/tailwindcss-" + plat;
+    inherit hash;
+  };
+
+  nativeBuildInputs = lib.optional stdenv.hostPlatform.isLinux autoPatchelfHook;
+  buildInputs = [ makeWrapper ];
+
+  dontUnpack = true;
+  dontBuild = true;
+  dontStrip = true;
+
+  installPhase = ''
+    mkdir -p $out/bin
+    install -m755 $src $out/bin/tailwindcss
+  '';
+
+  # libstdc++.so.6 for @parcel/watcher
+  postFixup = ''
+    wrapProgram $out/bin/tailwindcss --prefix LD_LIBRARY_PATH : ${
+      lib.makeLibraryPath [ stdenv.cc.cc.lib ]
+    }
+  '';
+
+  nativeInstallCheckInputs = [ versionCheckHook ];
+  doInstallCheck = true;
+  versionCheckProgram = "${placeholder "out"}/bin/tailwindcss";
+  versionCheckProgramArg = "--help";
+
+  passthru.updateScript = ./update.sh;
+
+  meta = {
+    description = "Command-line tool for the CSS framework with composable CSS classes, standalone v4 CLI";
+    homepage = "https://tailwindcss.com/blog/tailwindcss-v4";
+    license = lib.licenses.mit;
+    sourceProvenance = [ lib.sourceTypes.binaryNativeCode ];
+    maintainers = [ lib.maintainers.adamjhf ];
+    mainProgram = "tailwindcss";
+    platforms = lib.platforms.darwin ++ lib.platforms.linux;
+  };
+}

pkgs/by-name/ta/tailwindcss_4/update.sh

@@ -0,0 +1,30 @@
+#!/usr/bin/env nix-shell
+#!nix-shell -i bash -p curl gnused jq nix-prefetch
+set -eou pipefail
+
+ROOT="$(dirname "$(readlink -f "$0")")"
+
+CURRENT_VERSION=$(nix-instantiate --eval --strict --json -A tailwindcss.version . | jq -r .)
+LATEST_VERSION=$(curl --fail --silent https://api.github.com/repos/tailwindlabs/tailwindcss/releases/latest | jq --raw-output .tag_name | sed 's/v//')
+sed -i "s/version = \".*\"/version = \"${LATEST_VERSION}\"/" "$ROOT/default.nix"
+
+if [ "$CURRENT_VERSION" = "$LATEST_VERSION" ]; then
+    echo "tailwindcss already at latest version $CURRENT_VERSION, exiting"
+    exit 0
+fi
+
+function updatePlatform() {
+    NIXPLAT=$1
+    TAILWINDPLAT=$2
+    echo "Updating tailwindcss for $NIXPLAT"
+
+    URL="https://github.com/tailwindlabs/tailwindcss/releases/download/v${LATEST_VERSION}/tailwindcss-${TAILWINDPLAT}"
+    HASH=$(nix hash to-sri --type sha256 "$(nix-prefetch-url --type sha256 "$URL")")
+
+    sed -i "s,$NIXPLAT = \"sha256.*\",$NIXPLAT = \"${HASH}\"," "$ROOT/default.nix"
+}
+
+updatePlatform aarch64-darwin macos-arm64
+updatePlatform aarch64-linux linux-arm64
+updatePlatform x86_64-darwin macos-x64
+updatePlatform x86_64-linux linux-x64