Merge #319176: libtheora: adopt; modernize

...into staging

pkgs/by-name/li/libtheora/package.nix

@@ -0,0 +1,69 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  fetchpatch,
+  autoreconfHook,
+  libogg,
+  libvorbis,
+  pkg-config,
+  testers,
+  validatePkgConfig,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "libtheora";
+  version = "1.1.1";
+
+  src = fetchurl {
+    url = "https://downloads.xiph.org/releases/theora/libtheora-${finalAttrs.version}.tar.gz";
+    hash = "sha256-QJUpVsR4EZKNHnkizaO8H0J+t1aAw8NySckelJBUkWs=";
+  };
+
+  patches = [
+    # fix error in autoconf scripts
+    (fetchpatch {
+      url = "https://github.com/xiph/theora/commit/28cc6dbd9b2a141df94f60993256a5fca368fa54.diff";
+      hash = "sha256-M/UULkiklvEay7LyOuCamxWCSvt37QSMzHOsAAnOWJo=";
+    })
+  ] ++ lib.optionals stdenv.hostPlatform.isMinGW [ ./mingw-remove-export.patch ];
+
+  configureFlags = [ "--disable-examples" ];
+
+  outputs = [
+    "out"
+    "dev"
+    "devdoc"
+  ];
+  outputDoc = "devdoc";
+
+  nativeBuildInputs = [
+    autoreconfHook
+    pkg-config
+    validatePkgConfig
+  ];
+
+  propagatedBuildInputs = [
+    libogg
+    libvorbis
+  ];
+
+  passthru = {
+    tests.pkg-config = testers.hasPkgConfigModules {
+      package = finalAttrs.finalPackage;
+      moduleNames = [
+        "theora"
+        "theoradec"
+        "theoraenc"
+      ];
+    };
+  };
+
+  meta = {
+    description = "Library for Theora, a free and open video compression format";
+    homepage = "https://www.theora.org/";
+    license = lib.licenses.bsd3;
+    maintainers = with lib.maintainers; [ getchoo ];
+    platforms = lib.platforms.unix ++ lib.platforms.windows;
+  };
+})

pkgs/development/libraries/libtheora/default.nix

@@ -1,37 +0,0 @@
-{ lib, stdenv, fetchurl, libogg, libvorbis, pkg-config, autoreconfHook, fetchpatch }:
-
-stdenv.mkDerivation rec {
-  pname = "libtheora";
-  version = "1.1.1";
-
-  src = fetchurl {
-    url = "https://downloads.xiph.org/releases/theora/${pname}-${version}.tar.gz";
-    sha256 = "0swiaj8987n995rc7hw0asvpwhhzpjiws8kr3s6r44bqqib2k5a0";
-  };
-
-  patches = [
-    # fix error in autoconf scripts
-    (fetchpatch {
-      url = "https://github.com/xiph/theora/commit/28cc6dbd9b2a141df94f60993256a5fca368fa54.diff";
-      sha256 = "16jqrq4h1b3krj609vbpzd5845cvkbh3mwmjrcdg35m490p19x9k";
-    })
-  ] ++ lib.optionals stdenv.hostPlatform.isMinGW [
-    ./mingw-remove-export.patch
-  ];
-
-  configureFlags = [ "--disable-examples" ];
-
-  outputs = [ "out" "dev" "devdoc" ];
-  outputDoc = "devdoc";
-
-  nativeBuildInputs = [ pkg-config autoreconfHook ];
-  propagatedBuildInputs = [ libogg libvorbis ];
-
-  meta = with lib; {
-    homepage = "https://www.theora.org/";
-    description = "Library for Theora, a free and open video compression format";
-    license = licenses.bsd3;
-    maintainers = [ ];
-    platforms = platforms.unix ++ platforms.windows;
-  };
-}

pkgs/top-level/all-packages.nix

@@ -22304,8 +22304,6 @@ with pkgs;
 
   libthai = callPackage ../development/libraries/libthai { };
 
-  libtheora = callPackage ../development/libraries/libtheora { };
-
   libthreadar = callPackage ../development/libraries/libthreadar { };
 
   libticables2 = callPackage ../development/libraries/libticables2 { };