openfreebuds: init at 0.17.1 (#428681)

pkgs/by-name/op/openfreebuds/package.nix

@@ -0,0 +1,70 @@
+{
+  fetchFromGitHub,
+  lib,
+  nix-update-script,
+  python3Packages,
+  qt6,
+  qt6Packages,
+}:
+python3Packages.buildPythonApplication rec {
+  name = "openfreebuds";
+  version = "0.17.1";
+
+  src = fetchFromGitHub {
+    owner = "melianmiko";
+    repo = "OpenFreebuds";
+    tag = "v${version}";
+    hash = "sha256-y89BTKk14P/2kkYo63i9HgAdenzCVVnNArDsTmo4bPU=";
+  };
+
+  pyproject = true;
+
+  pythonRelaxDeps = [ "psutil" ];
+
+  build-system = with python3Packages; [
+    pdm-backend
+    pyqt6
+  ];
+
+  nativeBuildInputs = [
+    qt6Packages.wrapQtAppsHook
+    qt6Packages.qttools
+  ];
+
+  buildInputs = [ qt6.qtbase ];
+
+  dependencies = with python3Packages; [
+    aiocmd
+    aiohttp
+    dbus-next
+    pillow
+    psutil
+    pynput
+    pyqt6
+    qasync
+  ];
+
+  preBuild = ''
+    find openfreebuds_qt/designer -name "*.ui" | while read ui_file; do
+      py_file="''${ui_file%.ui}.py"
+      pyuic6 "$ui_file" -o "$py_file"
+    done
+
+    lrelease openfreebuds_qt/assets/i18n/*.ts
+  '';
+
+  preFixup = ''
+    makeWrapperArgs+=("''${qtWrapperArgs[@]}")
+  '';
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    changelog = "https://github.com/melianmiko/OpenFreebuds/blob/${src.rev}/CHANGELOG.md";
+    description = "Open source app for HUAWEI FreeBuds (Linux + Windows)";
+    homepage = "https://github.com/melianmiko/OpenFreebuds";
+    license = lib.licenses.gpl3Only;
+    maintainers = [ lib.maintainers.znaniye ];
+    platforms = lib.platforms.linux;
+  };
+}

pkgs/development/python-modules/aiocmd/default.nix

@@ -0,0 +1,35 @@
+{
+  buildPythonPackage,
+  fetchFromGitHub,
+  lib,
+  prompt-toolkit,
+  setuptools,
+}:
+buildPythonPackage rec {
+  name = "aiocmd";
+  version = "0.1.5";
+  src = fetchFromGitHub {
+    owner = "KimiNewt";
+    repo = "aiocmd";
+    tag = "v${version}";
+    hash = "sha256-C8dpeMTaoOMgfNP19JUYKUf+Vyw36Ry6dHkhaSm/QNk=";
+  };
+
+  pyproject = true;
+
+  build-system = [ setuptools ];
+
+  dependencies = [ prompt-toolkit ];
+
+  doCheck = false;
+
+  pythonImportsCheck = [ "aiocmd" ];
+
+  meta = {
+    description = "Asyncio-based automatic CLI creation tool using prompt-toolkit";
+    homepage = "https://github.com/KimiNewt/aiocmd";
+    license = lib.licenses.mit;
+    maintainers = [ lib.maintainers.znaniye ];
+    platforms = lib.platforms.linux;
+  };
+}

pkgs/top-level/all-packages.nix

@@ -16489,6 +16489,10 @@ with pkgs;
     flutter = flutter324;
   };
 
+  openfreebuds = callPackage ../by-name/op/openfreebuds/package.nix {
+    python3Packages = python3Full.pkgs;
+  };
+
   davis = callPackage ../by-name/da/davis/package.nix {
     php = php83; # https://github.com/tchapi/davis/issues/195
   };

pkgs/top-level/python-packages.nix

@@ -226,6 +226,8 @@ self: super: with self; {
 
   aiocache = callPackage ../development/python-modules/aiocache { };
 
+  aiocmd = callPackage ../development/python-modules/aiocmd { };
+
   aiocoap = callPackage ../development/python-modules/aiocoap { };
 
   aiocomelit = callPackage ../development/python-modules/aiocomelit { };