lerna: init at 8.1.9

* Include lerna_6 and lerna_8 variants

pkgs/development/node-packages/aliases.nix

@@ -135,6 +135,7 @@ mapAliases {
   inherit (pkgs) kaput-cli; # added 2024-12-03
   karma = pkgs.karma-runner; # added 2023-07-29
   leetcode-cli = self.vsc-leetcode-cli; # added 2023-08-31
+  inherit (pkgs) lerna; # added 2025-02-12
   less = pkgs.lessc; # added 2024-06-15
   less-plugin-clean-css = pkgs.lessc.plugins.clean-css; # added 2024-06-15
   inherit (pkgs) lv_font_conv; # added 2024-06-28

pkgs/development/node-packages/node-packages.json

@@ -111,7 +111,6 @@
 , "katex"
 , "keyoxide"
 , "lcov-result-merger"
-, "lerna"
 , "live-server"
 , "livedown"
 , "localtunnel"

pkgs/development/tools/lerna/default.nix

@@ -0,0 +1,37 @@
+{
+  lib,
+  callPackage,
+}:
+
+let
+  inherit (lib) mapAttrs' nameValuePair;
+
+  variants = {
+    "6" = {
+      version = "6.6.2";
+      hash = "sha256-B+o6SwVTrotHNYJW6CUXU/rJLK2VeGHvZYQZqbhYWjg=";
+      npmDepsHash = "sha256-yR3MUcmAVj0/+lLQk5+hmyGFnyqhzw1xjVsu7ciYccs=";
+      packageLockFile = ./package-lock.v6.json;
+    };
+    "8" = {
+      version = "8.1.9";
+      hash = "sha256-Rs6utL5dsL2h+rpOwjbtwEyU5pRdaAWHexfOm18o6BA=";
+      npmDepsHash = "sha256-o3mLG0mBDIdkjusCKTSoradYlD8r4xdMyHH2HtOG9KQ=";
+      packageLockFile = ./package-lock.v8.json;
+    };
+  };
+
+  callLerna =
+    variant:
+    callPackage ./generic.nix {
+      inherit (variant)
+        version
+        hash
+        npmDepsHash
+        packageLockFile
+        ;
+    };
+
+  mkLerna = versionSuffix: variant: nameValuePair "lerna_${versionSuffix}" (callLerna variant);
+in
+mapAttrs' mkLerna variants

pkgs/development/tools/lerna/generic.nix

@@ -0,0 +1,34 @@
+{
+  lib,
+  buildNpmPackage,
+  fetchurl,
+  version,
+  hash,
+  npmDepsHash,
+  packageLockFile,
+}:
+
+buildNpmPackage rec {
+  pname = "lerna";
+  inherit version;
+
+  src = fetchurl {
+    url = "https://registry.npmjs.org/lerna/-/lerna-${version}.tgz";
+    inherit hash;
+  };
+
+  postPatch = ''
+    ln -s ${packageLockFile} package-lock.json
+  '';
+
+  inherit npmDepsHash;
+  dontNpmBuild = true;
+
+  meta = {
+    description = "Lerna is a fast, modern build system for managing and publishing multiple JavaScript/TypeScript packages from the same repository";
+    homepage = "https://lerna.js.org/";
+    changelog = "https://github.com/lerna/lerna/blob/v${version}/CHANGELOG.md";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ ThaoTranLePhuong ];
+  };
+}

pkgs/top-level/all-packages.nix

@@ -4074,6 +4074,10 @@ with pkgs;
 
   leanblueprint = with python3Packages; toPythonApplication leanblueprint;
 
+  inherit (callPackage ../development/tools/lerna { })
+    lerna_6 lerna_8;
+  lerna = lerna_8;
+
   lethe = callPackage ../tools/security/lethe {
     inherit (darwin.apple_sdk.frameworks) Security;
   };