4f0dadbf38
After final improvements to the official formatter implementation,
this commit now performs the first treewide reformat of Nix files using it.
This is part of the implementation of RFC 166.
Only "inactive" files are reformatted, meaning only files that
aren't being touched by any PR with activity in the past 2 months.
This is to avoid conflicts for PRs that might soon be merged.
Later we can do a full treewide reformat to get the rest,
which should not cause as many conflicts.
A CI check has already been running for some time to ensure that new and
already-formatted files are formatted, so the files being reformatted here
should also stay formatted.
This commit was automatically created and can be verified using
nix-build a08b3a4d19.tar.gz \
--argstr baseRev b32a0943687d2a5094a6d92f25a4b6e16a76b5b7
result/bin/apply-formatting $NIXPKGS_PATH
75 lines
2.2 KiB
Nix
75 lines
2.2 KiB
Nix
{
|
|
config,
|
|
lib,
|
|
pkgs,
|
|
...
|
|
}:
|
|
let
|
|
cfg = config.services.pantalaimon-headless;
|
|
|
|
iniFmt = pkgs.formats.ini { };
|
|
|
|
mkConfigFile =
|
|
name: instanceConfig:
|
|
iniFmt.generate "pantalaimon.conf" {
|
|
Default = {
|
|
LogLevel = instanceConfig.logLevel;
|
|
Notifications = false;
|
|
};
|
|
|
|
${name} = (
|
|
lib.recursiveUpdate {
|
|
Homeserver = instanceConfig.homeserver;
|
|
ListenAddress = instanceConfig.listenAddress;
|
|
ListenPort = instanceConfig.listenPort;
|
|
SSL = instanceConfig.ssl;
|
|
|
|
# Set some settings to prevent user interaction for headless operation
|
|
IgnoreVerification = true;
|
|
UseKeyring = false;
|
|
} instanceConfig.extraSettings
|
|
);
|
|
};
|
|
|
|
mkPantalaimonService =
|
|
name: instanceConfig:
|
|
lib.nameValuePair "pantalaimon-${name}" {
|
|
description = "pantalaimon instance ${name} - E2EE aware proxy daemon for matrix clients";
|
|
wants = [ "network-online.target" ];
|
|
after = [ "network-online.target" ];
|
|
wantedBy = [ "multi-user.target" ];
|
|
|
|
serviceConfig = {
|
|
ExecStart = ''${pkgs.pantalaimon-headless}/bin/pantalaimon --config ${mkConfigFile name instanceConfig} --data-path ${instanceConfig.dataPath}'';
|
|
Restart = "on-failure";
|
|
DynamicUser = true;
|
|
NoNewPrivileges = true;
|
|
PrivateDevices = true;
|
|
PrivateTmp = true;
|
|
ProtectHome = true;
|
|
ProtectSystem = "strict";
|
|
StateDirectory = "pantalaimon-${name}";
|
|
};
|
|
};
|
|
in
|
|
{
|
|
options.services.pantalaimon-headless.instances = lib.mkOption {
|
|
default = { };
|
|
type = lib.types.attrsOf (lib.types.submodule (import ./pantalaimon-options.nix));
|
|
description = ''
|
|
Declarative instance config.
|
|
|
|
Note: to use pantalaimon interactively, e.g. for a Matrix client which does not
|
|
support End-to-end encryption (like `fractal`), refer to the home-manager module.
|
|
'';
|
|
};
|
|
|
|
config = lib.mkIf (config.services.pantalaimon-headless.instances != { }) {
|
|
systemd.services = lib.mapAttrs' mkPantalaimonService config.services.pantalaimon-headless.instances;
|
|
};
|
|
|
|
meta = {
|
|
maintainers = with lib.maintainers; [ jojosch ];
|
|
};
|
|
}
|