374e6bcc40
Format all Nix files using the officially approved formatter,
making the CI check introduced in the previous commit succeed:
nix-build ci -A fmt.check
This is the next step of the of the [implementation](https://github.com/NixOS/nixfmt/issues/153)
of the accepted [RFC 166](https://github.com/NixOS/rfcs/pull/166).
This commit will lead to merge conflicts for a number of PRs,
up to an estimated ~1100 (~33%) among the PRs with activity in the past 2
months, but that should be lower than what it would be without the previous
[partial treewide format](https://github.com/NixOS/nixpkgs/pull/322537).
Merge conflicts caused by this commit can now automatically be resolved while rebasing using the
[auto-rebase script](8616af08d9/maintainers/scripts/auto-rebase).
If you run into any problems regarding any of this, please reach out to the
[formatting team](https://nixos.org/community/teams/formatting/) by
pinging @NixOS/nix-formatting.
59 lines
1.6 KiB
Nix
59 lines
1.6 KiB
Nix
{ stdenv, lib }:
|
|
|
|
let
|
|
inherit (lib)
|
|
findFirst
|
|
isString
|
|
optional
|
|
optionals
|
|
;
|
|
|
|
cmakeFlags' = optionals (stdenv.hostPlatform != stdenv.buildPlatform) (
|
|
[
|
|
"-DCMAKE_SYSTEM_NAME=${
|
|
findFirst isString "Generic" (
|
|
optional (!stdenv.hostPlatform.isRedox) stdenv.hostPlatform.uname.system
|
|
)
|
|
}"
|
|
]
|
|
++ optionals (stdenv.hostPlatform.uname.processor != null) [
|
|
"-DCMAKE_SYSTEM_PROCESSOR=${stdenv.hostPlatform.uname.processor}"
|
|
]
|
|
++ optionals (stdenv.hostPlatform.uname.release != null) [
|
|
"-DCMAKE_SYSTEM_VERSION=${stdenv.hostPlatform.uname.release}"
|
|
]
|
|
++ optionals (stdenv.hostPlatform.isDarwin) [
|
|
"-DCMAKE_OSX_ARCHITECTURES=${stdenv.hostPlatform.darwinArch}"
|
|
]
|
|
++ optionals (stdenv.buildPlatform.uname.system != null) [
|
|
"-DCMAKE_HOST_SYSTEM_NAME=${stdenv.buildPlatform.uname.system}"
|
|
]
|
|
++ optionals (stdenv.buildPlatform.uname.processor != null) [
|
|
"-DCMAKE_HOST_SYSTEM_PROCESSOR=${stdenv.buildPlatform.uname.processor}"
|
|
]
|
|
++ optionals (stdenv.buildPlatform.uname.release != null) [
|
|
"-DCMAKE_HOST_SYSTEM_VERSION=${stdenv.buildPlatform.uname.release}"
|
|
]
|
|
++ optionals (stdenv.buildPlatform.canExecute stdenv.hostPlatform) [
|
|
"-DCMAKE_CROSSCOMPILING_EMULATOR=env"
|
|
]
|
|
++ optionals (stdenv.hostPlatform.isNone) [
|
|
"-DCMAKE_TRY_COMPILE_TARGET_TYPE=STATIC_LIBRARY"
|
|
]
|
|
++ optionals stdenv.hostPlatform.isStatic [
|
|
"-DCMAKE_LINK_SEARCH_START_STATIC=ON"
|
|
]
|
|
);
|
|
|
|
makeCMakeFlags =
|
|
{
|
|
cmakeFlags ? [ ],
|
|
...
|
|
}:
|
|
cmakeFlags ++ cmakeFlags';
|
|
|
|
in
|
|
{
|
|
inherit makeCMakeFlags;
|
|
}
|