374e6bcc40
Format all Nix files using the officially approved formatter,
making the CI check introduced in the previous commit succeed:
nix-build ci -A fmt.check
This is the next step of the of the [implementation](https://github.com/NixOS/nixfmt/issues/153)
of the accepted [RFC 166](https://github.com/NixOS/rfcs/pull/166).
This commit will lead to merge conflicts for a number of PRs,
up to an estimated ~1100 (~33%) among the PRs with activity in the past 2
months, but that should be lower than what it would be without the previous
[partial treewide format](https://github.com/NixOS/nixpkgs/pull/322537).
Merge conflicts caused by this commit can now automatically be resolved while rebasing using the
[auto-rebase script](8616af08d9/maintainers/scripts/auto-rebase).
If you run into any problems regarding any of this, please reach out to the
[formatting team](https://nixos.org/community/teams/formatting/) by
pinging @NixOS/nix-formatting.
78 lines
1.9 KiB
Nix
78 lines
1.9 KiB
Nix
{
|
|
lib,
|
|
buildDotnetModule,
|
|
dotnetCorePackages,
|
|
fetchFromGitHub,
|
|
pkg-config,
|
|
blueprint-compiler,
|
|
glib,
|
|
gtk4,
|
|
libadwaita,
|
|
wrapGAppsHook4,
|
|
appstream-glib,
|
|
desktop-file-utils,
|
|
cava,
|
|
libGL,
|
|
}:
|
|
|
|
buildDotnetModule rec {
|
|
pname = "cavalier";
|
|
version = "2024.1.0";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "NickvisionApps";
|
|
repo = "Cavalier";
|
|
tag = version;
|
|
hash = "sha256-SFhEKtYrlnkbLMnxU4Uf4jnFsw0MJHstgZgLLnGC2d8=";
|
|
};
|
|
|
|
dotnet-sdk = dotnetCorePackages.sdk_8_0;
|
|
dotnet-runtime = dotnetCorePackages.runtime_8_0;
|
|
|
|
projectFile = "NickvisionCavalier.GNOME/NickvisionCavalier.GNOME.csproj";
|
|
nugetDeps = ./deps.json;
|
|
executables = "NickvisionCavalier.GNOME";
|
|
|
|
nativeBuildInputs = [
|
|
pkg-config
|
|
blueprint-compiler
|
|
wrapGAppsHook4
|
|
appstream-glib
|
|
desktop-file-utils
|
|
];
|
|
|
|
buildInputs = [
|
|
glib
|
|
gtk4
|
|
libadwaita
|
|
];
|
|
|
|
runtimeDeps = [
|
|
glib
|
|
gtk4
|
|
libadwaita
|
|
libGL
|
|
];
|
|
|
|
postInstall = ''
|
|
substituteInPlace NickvisionCavalier.Shared/Linux/org.nickvision.cavalier.desktop.in \
|
|
--replace-fail '@EXEC@' "NickvisionCavalier.GNOME"
|
|
install -Dm444 NickvisionCavalier.Shared/Linux/org.nickvision.cavalier.desktop.in -T $out/share/applications/org.nickvision.cavalier.desktop
|
|
install -Dm444 NickvisionCavalier.Shared/Resources/org.nickvision.cavalier.svg -t $out/share/icons/hicolor/scalable/apps/
|
|
install -Dm444 NickvisionCavalier.Shared/Resources/org.nickvision.cavalier-symbolic.svg -t $out/share/icons/hicolor/symbolic/apps/
|
|
'';
|
|
|
|
makeWrapperArgs = [ "--prefix PATH : ${lib.makeBinPath [ cava ]}" ];
|
|
|
|
passthru.updateScript = ./update.sh;
|
|
|
|
meta = {
|
|
description = "Visualize audio with CAVA";
|
|
homepage = "https://github.com/NickvisionApps/Cavalier";
|
|
mainProgram = "NickvisionCavalier.GNOME";
|
|
license = lib.licenses.mit;
|
|
platforms = lib.platforms.linux;
|
|
maintainers = with lib.maintainers; [ zendo ];
|
|
};
|
|
}
|