a19cd4ffb1
This reverts commit 65a333600d5c88a98d674f637d092807cfc12253. This wasn't tested for correctness with something like fodwatch [0], and should not have been (self-)merged so quickly, especially without further review. It also resulted in the breakage of at least one package [1] (and that's the one we know of and was caught). A few packages that were updated in between this commit and this revert were not reverted back to using `rev`, but other than that, this is a 1:1 revert. [0]: https://codeberg.org/raphaelr/fodwatch [1]: https://github.com/NixOS/nixpkgs/pull/396904 / 758551e4587d75882aebc21a04bee960418f8ce9
63 lines
1.3 KiB
Nix
63 lines
1.3 KiB
Nix
{
|
|
buildGoModule,
|
|
bzip2,
|
|
callPackage,
|
|
fetchFromGitHub,
|
|
lib,
|
|
libunarr,
|
|
mupdf-headless,
|
|
nix-update-script,
|
|
versionCheckHook,
|
|
zlib,
|
|
}:
|
|
|
|
buildGoModule rec {
|
|
pname = "cbconvert";
|
|
version = "1.1.0";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "gen2brain";
|
|
repo = "cbconvert";
|
|
rev = "v${version}";
|
|
hash = "sha256-C2Eox6fpKS0fPB7KFgBn62HKbWYacSVMJK0CkT6+FBU=";
|
|
};
|
|
|
|
vendorHash = "sha256-uV8aIUKy9HQdZvR3k8CTTrHsh9TyBw21gFTdjR1XJlg=";
|
|
modRoot = "cmd/cbconvert";
|
|
|
|
# The extlib tag forces the github.com/gen2brain/go-unarr module to use external libraries instead of bundled ones.
|
|
tags = [ "extlib" ];
|
|
|
|
ldflags = [
|
|
"-s"
|
|
"-w"
|
|
"-X main.appVersion=${version}"
|
|
];
|
|
|
|
buildInputs = [
|
|
bzip2
|
|
libunarr
|
|
mupdf-headless
|
|
zlib
|
|
];
|
|
|
|
doInstallCheck = true;
|
|
nativeInstallCheckInputs = [ versionCheckHook ];
|
|
versionCheckProgramArg = "version";
|
|
|
|
passthru = {
|
|
gui = callPackage ./gui.nix { };
|
|
updateScript = nix-update-script { };
|
|
};
|
|
|
|
meta = {
|
|
description = "Comic Book converter";
|
|
homepage = "https://github.com/gen2brain/cbconvert";
|
|
changelog = "https://github.com/gen2brain/cbconvert/releases/tag/v${version}";
|
|
license = with lib.licenses; [ gpl3Only ];
|
|
platforms = lib.platforms.linux;
|
|
maintainers = with lib.maintainers; [ jwillikers ];
|
|
mainProgram = "cbconvert";
|
|
};
|
|
}
|