a19cd4ffb1
This reverts commit 65a333600d5c88a98d674f637d092807cfc12253. This wasn't tested for correctness with something like fodwatch [0], and should not have been (self-)merged so quickly, especially without further review. It also resulted in the breakage of at least one package [1] (and that's the one we know of and was caught). A few packages that were updated in between this commit and this revert were not reverted back to using `rev`, but other than that, this is a 1:1 revert. [0]: https://codeberg.org/raphaelr/fodwatch [1]: https://github.com/NixOS/nixpkgs/pull/396904 / 758551e4587d75882aebc21a04bee960418f8ce9
76 lines
1.3 KiB
Nix
76 lines
1.3 KiB
Nix
{
|
|
lib,
|
|
stdenv,
|
|
fetchFromGitHub,
|
|
runCommand,
|
|
asciidoctor,
|
|
coreutils,
|
|
gawk,
|
|
glibc,
|
|
util-linux,
|
|
bash,
|
|
makeBinaryWrapper,
|
|
doas-sudo-shim,
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "doas-sudo-shim";
|
|
version = "0.1.2";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "jirutka";
|
|
repo = "doas-sudo-shim";
|
|
rev = "v${version}";
|
|
sha256 = "sha256-jgakKxglJi4LcxXsSE4mEdY/44kPxVb/jF7CgX7dllA=";
|
|
};
|
|
|
|
nativeBuildInputs = [
|
|
asciidoctor
|
|
makeBinaryWrapper
|
|
];
|
|
buildInputs = [
|
|
bash
|
|
coreutils
|
|
gawk
|
|
glibc
|
|
util-linux
|
|
];
|
|
|
|
dontConfigure = true;
|
|
dontBuild = true;
|
|
|
|
installFlags = [
|
|
"DESTDIR=$(out)"
|
|
"PREFIX=\"\""
|
|
];
|
|
|
|
postInstall = ''
|
|
wrapProgram $out/bin/sudo \
|
|
--prefix PATH : ${
|
|
lib.makeBinPath [
|
|
bash
|
|
coreutils
|
|
gawk
|
|
glibc
|
|
util-linux
|
|
]
|
|
}
|
|
'';
|
|
|
|
passthru.tests = {
|
|
helpTest = runCommand "${pname}-helpTest" { } ''
|
|
${doas-sudo-shim}/bin/sudo -h > $out
|
|
grep -q "Execute a command as another user using doas(1)" $out
|
|
'';
|
|
};
|
|
|
|
meta = with lib; {
|
|
description = "Shim for the sudo command that utilizes doas";
|
|
homepage = "https://github.com/jirutka/doas-sudo-shim";
|
|
license = licenses.isc;
|
|
mainProgram = "sudo";
|
|
maintainers = with maintainers; [ dsuetin ];
|
|
platforms = platforms.linux;
|
|
};
|
|
}
|