a19cd4ffb1
This reverts commit 65a333600d5c88a98d674f637d092807cfc12253. This wasn't tested for correctness with something like fodwatch [0], and should not have been (self-)merged so quickly, especially without further review. It also resulted in the breakage of at least one package [1] (and that's the one we know of and was caught). A few packages that were updated in between this commit and this revert were not reverted back to using `rev`, but other than that, this is a 1:1 revert. [0]: https://codeberg.org/raphaelr/fodwatch [1]: https://github.com/NixOS/nixpkgs/pull/396904 / 758551e4587d75882aebc21a04bee960418f8ce9
45 lines
1.1 KiB
Nix
45 lines
1.1 KiB
Nix
{
|
|
lib,
|
|
buildGoModule,
|
|
fetchFromGitHub,
|
|
fetchpatch2,
|
|
tetex,
|
|
makeWrapper,
|
|
}:
|
|
buildGoModule rec {
|
|
pname = "reporter";
|
|
version = "2.3.1";
|
|
|
|
src = fetchFromGitHub {
|
|
rev = "v${version}";
|
|
owner = "IzakMarais";
|
|
repo = "reporter";
|
|
hash = "sha256-lsraJwx56I2Gn8CePWUlQu1qdMp78P4xwPzLxetYUcw=";
|
|
};
|
|
|
|
nativeBuildInputs = [ makeWrapper ];
|
|
|
|
vendorHash = "sha256-QlNOx2jm1LVz066t9khppf//T5c9z3YUrSOr6qzbUzI=";
|
|
|
|
patches = [
|
|
(fetchpatch2 {
|
|
name = "use-go-mod-and-remove-vendor-dirs";
|
|
url = "https://github.com/IzakMarais/reporter/commit/e844b3f624e0da3a960f98cade427fe54f595504.patch";
|
|
hash = "sha256-CdI7/mkYG6t6H6ydGu7atwk18DpagdP7uzfrZVKKlhA=";
|
|
})
|
|
];
|
|
|
|
postInstall = ''
|
|
wrapProgram $out/bin/grafana-reporter \
|
|
--prefix PATH : ${lib.makeBinPath [ tetex ]}
|
|
'';
|
|
|
|
meta = {
|
|
description = "PDF report generator from a Grafana dashboard";
|
|
mainProgram = "grafana-reporter";
|
|
homepage = "https://github.com/IzakMarais/reporter";
|
|
license = lib.licenses.mit;
|
|
maintainers = [ lib.maintainers.disassembler ];
|
|
};
|
|
}
|