a19cd4ffb1
This reverts commit 65a333600d5c88a98d674f637d092807cfc12253. This wasn't tested for correctness with something like fodwatch [0], and should not have been (self-)merged so quickly, especially without further review. It also resulted in the breakage of at least one package [1] (and that's the one we know of and was caught). A few packages that were updated in between this commit and this revert were not reverted back to using `rev`, but other than that, this is a 1:1 revert. [0]: https://codeberg.org/raphaelr/fodwatch [1]: https://github.com/NixOS/nixpkgs/pull/396904 / 758551e4587d75882aebc21a04bee960418f8ce9
61 lines
1.3 KiB
Nix
61 lines
1.3 KiB
Nix
{
|
|
lib,
|
|
buildGoModule,
|
|
fetchFromGitHub,
|
|
gitMinimal,
|
|
ghq,
|
|
}:
|
|
|
|
buildGoModule rec {
|
|
pname = "gst";
|
|
version = "5.0.5";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "uetchy";
|
|
repo = "gst";
|
|
rev = "v${version}";
|
|
hash = "sha256-NhbGHTYucfqCloVirkaDlAtQfhWP2cw4I+t/ysvvkR0=";
|
|
};
|
|
|
|
vendorHash = "sha256-kGPg6NyhVfVOn0BFQY83/VYdpUjOqaf5I4bev0uhvUw=";
|
|
|
|
doCheck = false;
|
|
|
|
nativeBuildInputs = [
|
|
gitMinimal
|
|
ghq
|
|
];
|
|
|
|
ldflags = [
|
|
"-s"
|
|
"-w"
|
|
"-X=main.Version=${version}"
|
|
];
|
|
|
|
doInstallCheck = true;
|
|
installCheckPhase = ''
|
|
if [[ "$("$out/bin/${pname}" --version)" == "${pname} version ${version}" ]]; then
|
|
export HOME=$(mktemp -d)
|
|
git config --global user.name "Test User"
|
|
git config --global user.email "test@example.com"
|
|
git config --global init.defaultBranch "main"
|
|
git config --global ghq.user "user"
|
|
ghq create test > /dev/null 2>&1
|
|
touch $HOME/ghq/github.com/user/test/SmokeTest
|
|
$out/bin/${pname} list | grep SmokeTest > /dev/null
|
|
echo '${pname} smoke check passed'
|
|
else
|
|
echo '${pname} smoke check failed'
|
|
return 1
|
|
fi
|
|
'';
|
|
|
|
meta = {
|
|
description = "Supercharge your ghq workflow";
|
|
homepage = "https://github.com/uetchy/gst";
|
|
maintainers = with lib.maintainers; [ _0x4A6F ];
|
|
license = lib.licenses.asl20;
|
|
mainProgram = "gst";
|
|
};
|
|
}
|