374e6bcc40
Format all Nix files using the officially approved formatter,
making the CI check introduced in the previous commit succeed:
nix-build ci -A fmt.check
This is the next step of the of the [implementation](https://github.com/NixOS/nixfmt/issues/153)
of the accepted [RFC 166](https://github.com/NixOS/rfcs/pull/166).
This commit will lead to merge conflicts for a number of PRs,
up to an estimated ~1100 (~33%) among the PRs with activity in the past 2
months, but that should be lower than what it would be without the previous
[partial treewide format](https://github.com/NixOS/nixpkgs/pull/322537).
Merge conflicts caused by this commit can now automatically be resolved while rebasing using the
[auto-rebase script](8616af08d9/maintainers/scripts/auto-rebase).
If you run into any problems regarding any of this, please reach out to the
[formatting team](https://nixos.org/community/teams/formatting/) by
pinging @NixOS/nix-formatting.
76 lines
1.6 KiB
Nix
76 lines
1.6 KiB
Nix
{
|
|
lib,
|
|
stdenv,
|
|
fetchFromGitHub,
|
|
ant,
|
|
jdk,
|
|
libffi,
|
|
pkg-config,
|
|
texinfo,
|
|
stripJavaArchivesHook,
|
|
}:
|
|
|
|
stdenv.mkDerivation (finalAttrs: {
|
|
pname = "jffi";
|
|
version = "1.3.13";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "jnr";
|
|
repo = "jffi";
|
|
rev = "jffi-${finalAttrs.version}";
|
|
hash = "sha256-aBQkkZyXZkaJc4sr/jHnIRaJYP116u4Jqsr9XXzfOBA=";
|
|
};
|
|
|
|
nativeBuildInputs = [
|
|
ant
|
|
jdk
|
|
pkg-config
|
|
texinfo
|
|
stripJavaArchivesHook
|
|
];
|
|
|
|
buildInputs = [ libffi ];
|
|
|
|
# The pkg-config script in the build.xml doesn't work propery
|
|
# set the lib path manually to work around this.
|
|
env.LIBFFI_LIBS = "${libffi}/lib/libffi${stdenv.hostPlatform.extensions.sharedLibrary}";
|
|
env.ANT_ARGS = "-Duse.system.libffi=1";
|
|
|
|
buildPhase = ''
|
|
runHook preBuild
|
|
ant jar
|
|
ant archive-platform-jar
|
|
runHook postBuild
|
|
'';
|
|
|
|
doCheck = true;
|
|
|
|
checkPhase = ''
|
|
runHook preCheck
|
|
ant test
|
|
runHook postCheck
|
|
'';
|
|
|
|
installPhase = ''
|
|
runHook preInstall
|
|
install -Dm644 dist/*.jar -t $out/share/java
|
|
runHook postInstall
|
|
'';
|
|
|
|
# nix can't detect libffi as a dependency inside the jar file, so we create
|
|
# a dummy file with the path to libffi, to make sure that nix knows about it
|
|
postFixup = ''
|
|
mkdir -p $out/nix-support
|
|
echo ${libffi} > $out/nix-support/depends
|
|
'';
|
|
|
|
meta = with lib; {
|
|
broken = stdenv.hostPlatform.isDarwin;
|
|
description = "Java Foreign Function Interface";
|
|
homepage = "https://github.com/jnr/jffi";
|
|
platforms = platforms.unix;
|
|
license = licenses.asl20;
|
|
maintainers = with maintainers; [ bachp ];
|
|
};
|
|
})
|