a19cd4ffb1
This reverts commit 65a333600d5c88a98d674f637d092807cfc12253. This wasn't tested for correctness with something like fodwatch [0], and should not have been (self-)merged so quickly, especially without further review. It also resulted in the breakage of at least one package [1] (and that's the one we know of and was caught). A few packages that were updated in between this commit and this revert were not reverted back to using `rev`, but other than that, this is a 1:1 revert. [0]: https://codeberg.org/raphaelr/fodwatch [1]: https://github.com/NixOS/nixpkgs/pull/396904 / 758551e4587d75882aebc21a04bee960418f8ce9
54 lines
1.4 KiB
Nix
54 lines
1.4 KiB
Nix
{
|
|
lib,
|
|
stdenv,
|
|
fetchFromGitHub,
|
|
autoreconfHook,
|
|
glib,
|
|
libev,
|
|
libevent,
|
|
pkg-config,
|
|
glibSupport ? true,
|
|
libevSupport ? true,
|
|
libeventSupport ? true,
|
|
}:
|
|
|
|
let
|
|
inherit (lib) optional;
|
|
in
|
|
stdenv.mkDerivation (finalAttrs: {
|
|
pname = "libverto";
|
|
version = "0.3.2";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "latchset";
|
|
repo = "libverto";
|
|
rev = finalAttrs.version;
|
|
hash = "sha256-csoJ0WdKyrza8kBSMKoaItKvcbijI6Wl8nWCbywPScQ=";
|
|
};
|
|
|
|
nativeBuildInputs = [
|
|
autoreconfHook
|
|
pkg-config
|
|
];
|
|
|
|
buildInputs =
|
|
optional glibSupport glib ++ optional libevSupport libev ++ optional libeventSupport libevent;
|
|
|
|
meta = with lib; {
|
|
homepage = "https://github.com/latchset/libverto";
|
|
description = "Asynchronous event loop abstraction library";
|
|
longDescription = ''
|
|
Libverto exists to solve an important problem: many applications and
|
|
libraries are unable to write asynchronous code because they are unable to
|
|
pick an event loop. This is particularly true of libraries who want to be
|
|
useful to many applications who use loops that do not integrate with one
|
|
another or which use home-grown loops. libverto provides a loop-neutral
|
|
async api which allows the library to expose asynchronous interfaces and
|
|
offload the choice of the main loop to the application.
|
|
'';
|
|
license = licenses.mit;
|
|
maintainers = with maintainers; [ ];
|
|
platforms = platforms.unix;
|
|
};
|
|
})
|