a19cd4ffb1
This reverts commit 65a333600d5c88a98d674f637d092807cfc12253. This wasn't tested for correctness with something like fodwatch [0], and should not have been (self-)merged so quickly, especially without further review. It also resulted in the breakage of at least one package [1] (and that's the one we know of and was caught). A few packages that were updated in between this commit and this revert were not reverted back to using `rev`, but other than that, this is a 1:1 revert. [0]: https://codeberg.org/raphaelr/fodwatch [1]: https://github.com/NixOS/nixpkgs/pull/396904 / 758551e4587d75882aebc21a04bee960418f8ce9
78 lines
1.4 KiB
Nix
78 lines
1.4 KiB
Nix
{
|
|
bats,
|
|
bash,
|
|
fetchFromGitHub,
|
|
lib,
|
|
resholve,
|
|
coreutils,
|
|
getopt,
|
|
}:
|
|
let
|
|
version = "0.0.1";
|
|
in
|
|
resholve.mkDerivation {
|
|
pname = "locate-dominating-file";
|
|
inherit version;
|
|
src = fetchFromGitHub {
|
|
owner = "roman";
|
|
repo = "locate-dominating-file";
|
|
rev = "v${version}";
|
|
hash = "sha256-gwh6fAw7BV7VFIkQN02QIhK47uxpYheMk64UeLyp2IY=";
|
|
};
|
|
|
|
postPatch = ''
|
|
for file in $(find src tests -type f); do
|
|
patchShebangs "$file"
|
|
done
|
|
'';
|
|
|
|
buildInputs = [
|
|
getopt
|
|
coreutils
|
|
];
|
|
|
|
checkInputs = [
|
|
(bats.withLibraries (p: [
|
|
p.bats-support
|
|
p.bats-assert
|
|
]))
|
|
];
|
|
|
|
doCheck = true;
|
|
|
|
checkPhase = ''
|
|
runHook preCheck
|
|
|
|
bats -t tests
|
|
|
|
runHook postCheck
|
|
'';
|
|
|
|
installPhase = ''
|
|
runHook preInstall
|
|
|
|
mkdir -p $out/bin
|
|
cp src/locate-dominating-file.sh $out/bin/locate-dominating-file
|
|
|
|
runHook postInstall
|
|
'';
|
|
|
|
solutions.default = {
|
|
scripts = [ "bin/locate-dominating-file" ];
|
|
interpreter = "${bash}/bin/bash";
|
|
inputs = [
|
|
coreutils
|
|
getopt
|
|
];
|
|
};
|
|
|
|
meta = with lib; {
|
|
homepage = "https://github.com/roman/locate-dominating-file";
|
|
description = "Program that looks up in a directory hierarchy for a given filename";
|
|
license = licenses.mit;
|
|
maintainers = [ maintainers.roman ];
|
|
platforms = platforms.all;
|
|
mainProgram = "locate-dominating-file";
|
|
};
|
|
}
|