a19cd4ffb1
This reverts commit 65a333600d5c88a98d674f637d092807cfc12253. This wasn't tested for correctness with something like fodwatch [0], and should not have been (self-)merged so quickly, especially without further review. It also resulted in the breakage of at least one package [1] (and that's the one we know of and was caught). A few packages that were updated in between this commit and this revert were not reverted back to using `rev`, but other than that, this is a 1:1 revert. [0]: https://codeberg.org/raphaelr/fodwatch [1]: https://github.com/NixOS/nixpkgs/pull/396904 / 758551e4587d75882aebc21a04bee960418f8ce9
49 lines
1.1 KiB
Nix
49 lines
1.1 KiB
Nix
{
|
|
lib,
|
|
fetchFromGitHub,
|
|
nix-update-script,
|
|
stdenv,
|
|
testers,
|
|
validatePkgConfig,
|
|
cmake,
|
|
}:
|
|
|
|
stdenv.mkDerivation (finalAttrs: {
|
|
pname = "miniz";
|
|
version = "3.0.2";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "richgel999";
|
|
repo = "miniz";
|
|
rev = finalAttrs.version;
|
|
hash = "sha256-3J0bkr2Yk+MJXilUqOCHsWzuykySv5B1nepmucvA4hg=";
|
|
};
|
|
passthru.updateScript = nix-update-script { };
|
|
|
|
strictDeps = true;
|
|
nativeBuildInputs = [
|
|
cmake
|
|
validatePkgConfig
|
|
];
|
|
|
|
postFixup = ''
|
|
substituteInPlace "$out"/lib/pkgconfig/miniz.pc \
|
|
--replace-fail '=''${prefix}//' '=/' \
|
|
--replace-fail '=''${exec_prefix}//' '=/'
|
|
'';
|
|
|
|
passthru.tests.pkg-config = testers.hasPkgConfigModules {
|
|
package = finalAttrs.finalPackage;
|
|
versionCheck = true;
|
|
};
|
|
|
|
meta = with lib; {
|
|
description = "Single C source file zlib-replacement library";
|
|
homepage = "https://github.com/richgel999/miniz";
|
|
license = licenses.mit;
|
|
maintainers = with maintainers; [ astro ];
|
|
platforms = platforms.unix;
|
|
pkgConfigModules = [ "miniz" ];
|
|
};
|
|
})
|