a19cd4ffb1
This reverts commit 65a333600d5c88a98d674f637d092807cfc12253. This wasn't tested for correctness with something like fodwatch [0], and should not have been (self-)merged so quickly, especially without further review. It also resulted in the breakage of at least one package [1] (and that's the one we know of and was caught). A few packages that were updated in between this commit and this revert were not reverted back to using `rev`, but other than that, this is a 1:1 revert. [0]: https://codeberg.org/raphaelr/fodwatch [1]: https://github.com/NixOS/nixpkgs/pull/396904 / 758551e4587d75882aebc21a04bee960418f8ce9
68 lines
1.4 KiB
Nix
68 lines
1.4 KiB
Nix
{
|
|
lib,
|
|
stdenv,
|
|
fetchFromGitHub,
|
|
cmake,
|
|
pkg-config,
|
|
dnsutils,
|
|
nmap,
|
|
libsForQt5,
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "nmapsi4";
|
|
version = "0.5-alpha2";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "nmapsi4";
|
|
repo = "nmapsi4";
|
|
rev = "v${version}";
|
|
hash = "sha256-q3XfwJ4TGK4E58haN0Q0xRH4GDpKD8VZzyxHe/VwBqY=";
|
|
};
|
|
|
|
nativeBuildInputs = [
|
|
cmake
|
|
pkg-config
|
|
libsForQt5.wrapQtAppsHook
|
|
];
|
|
|
|
buildInputs = with libsForQt5; [
|
|
qtbase
|
|
qtscript
|
|
qtwebengine
|
|
];
|
|
|
|
postPatch = ''
|
|
substituteInPlace src/platform/digmanager.cpp \
|
|
--replace '"dig"' '"${dnsutils}/bin/dig"'
|
|
substituteInPlace src/platform/discover.cpp \
|
|
--replace '"nping"' '"${nmap}/bin/nping"'
|
|
for f in \
|
|
src/platform/monitor/monitor.cpp \
|
|
src/platform/nsemanager.cpp ; do
|
|
|
|
substituteInPlace $f \
|
|
--replace '"nmap"' '"${nmap}/bin/nmap"'
|
|
done
|
|
'';
|
|
|
|
postInstall = ''
|
|
mv $out/share/applications/kde4/*.desktop $out/share/applications
|
|
rmdir $out/share/applications/kde4
|
|
|
|
for f in $out/share/applications/* ; do
|
|
substituteInPlace $f \
|
|
--replace Qt4 Qt5
|
|
done
|
|
'';
|
|
|
|
meta = {
|
|
description = "Qt frontend for nmap";
|
|
mainProgram = "nmapsi4";
|
|
changelog = "https://github.com/nmapsi4/nmapsi4/releases/tag/${src.rev}";
|
|
license = lib.licenses.gpl2Plus;
|
|
maintainers = with lib.maintainers; [ peterhoeg ];
|
|
inherit (src.meta) homepage;
|
|
};
|
|
}
|