a19cd4ffb1
This reverts commit 65a333600d5c88a98d674f637d092807cfc12253. This wasn't tested for correctness with something like fodwatch [0], and should not have been (self-)merged so quickly, especially without further review. It also resulted in the breakage of at least one package [1] (and that's the one we know of and was caught). A few packages that were updated in between this commit and this revert were not reverted back to using `rev`, but other than that, this is a 1:1 revert. [0]: https://codeberg.org/raphaelr/fodwatch [1]: https://github.com/NixOS/nixpkgs/pull/396904 / 758551e4587d75882aebc21a04bee960418f8ce9
84 lines
1.8 KiB
Nix
84 lines
1.8 KiB
Nix
{
|
|
stdenv,
|
|
buildGoModule,
|
|
fetchFromGitHub,
|
|
lib,
|
|
symlinkJoin,
|
|
}:
|
|
|
|
let
|
|
p2 = buildGoModule rec {
|
|
pname = "packr2";
|
|
version = "2.8.0";
|
|
|
|
src =
|
|
fetchFromGitHub {
|
|
owner = "gobuffalo";
|
|
repo = "packr";
|
|
rev = "v${version}";
|
|
hash = "sha256-UfnL3Lnq3ocXrTqKtmyar6BoKUUHHKMOFCiD5wX26PQ=";
|
|
}
|
|
+ "/v2";
|
|
|
|
subPackages = [ "packr2" ];
|
|
|
|
vendorHash = "sha256-N3u+DmEe0r72zFPb8El/MwjyIcTehQRE+MgusIII2Is=";
|
|
|
|
doCheck = false;
|
|
|
|
meta = with lib; {
|
|
description = "Simple and easy way to embed static files into Go binaries";
|
|
homepage = "https://github.com/gobuffalo/packr";
|
|
license = licenses.mit;
|
|
maintainers = with maintainers; [ mmahut ];
|
|
|
|
# golang.org/x/sys needs to be updated due to:
|
|
#
|
|
# https://github.com/golang/go/issues/49219
|
|
#
|
|
# but this package is no longer maintained.
|
|
#
|
|
broken = stdenv.hostPlatform.isDarwin;
|
|
};
|
|
};
|
|
p1 = buildGoModule rec {
|
|
pname = "packr1";
|
|
version = "2.8.0";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "gobuffalo";
|
|
repo = "packr";
|
|
rev = "v${version}";
|
|
hash = "sha256-UfnL3Lnq3ocXrTqKtmyar6BoKUUHHKMOFCiD5wX26PQ=";
|
|
};
|
|
|
|
subPackages = [ "packr" ];
|
|
|
|
vendorHash = "sha256-6mlV3q7irI0aoeB91OYSD3RvmwYcNXRNkSYowjmSflQ=";
|
|
|
|
doCheck = false;
|
|
|
|
meta = with lib; {
|
|
description = "Simple and easy way to embed static files into Go binaries";
|
|
homepage = "https://github.com/gobuffalo/packr";
|
|
license = licenses.mit;
|
|
maintainers = with maintainers; [ mmahut ];
|
|
|
|
# golang.org/x/sys needs to be updated due to:
|
|
#
|
|
# https://github.com/golang/go/issues/49219
|
|
#
|
|
# but this package is no longer maintained.
|
|
#
|
|
broken = stdenv.hostPlatform.isDarwin;
|
|
};
|
|
};
|
|
in
|
|
symlinkJoin {
|
|
name = "packr";
|
|
paths = [
|
|
p1
|
|
p2
|
|
];
|
|
}
|