a19cd4ffb1
This reverts commit 65a333600d5c88a98d674f637d092807cfc12253. This wasn't tested for correctness with something like fodwatch [0], and should not have been (self-)merged so quickly, especially without further review. It also resulted in the breakage of at least one package [1] (and that's the one we know of and was caught). A few packages that were updated in between this commit and this revert were not reverted back to using `rev`, but other than that, this is a 1:1 revert. [0]: https://codeberg.org/raphaelr/fodwatch [1]: https://github.com/NixOS/nixpkgs/pull/396904 / 758551e4587d75882aebc21a04bee960418f8ce9
68 lines
1.4 KiB
Nix
68 lines
1.4 KiB
Nix
{
|
|
lib,
|
|
stdenv,
|
|
fetchFromGitHub,
|
|
fetchYarnDeps,
|
|
makeWrapper,
|
|
fixup-yarn-lock,
|
|
yarn,
|
|
nodejs,
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "pxder";
|
|
version = "2.12.8";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "Tsuk1ko";
|
|
repo = "pxder";
|
|
rev = "v${version}";
|
|
hash = "sha256-+WZbs10+id+nohTZzLjEofb6k8PMGd73YhY3FUTXx5Q=";
|
|
};
|
|
|
|
offlineCache = fetchYarnDeps {
|
|
yarnLock = "${src}/yarn.lock";
|
|
hash = "sha256-++MqWIUntXQwOYpgAJ3nhAtZ5nxmEreioVHQokYkw7w=";
|
|
};
|
|
|
|
nativeBuildInputs = [
|
|
makeWrapper
|
|
fixup-yarn-lock
|
|
yarn
|
|
];
|
|
|
|
configurePhase = ''
|
|
runHook preConfigure
|
|
|
|
export HOME=$(mktemp -d)
|
|
yarn config --offline set yarn-offline-mirror "$offlineCache"
|
|
fixup-yarn-lock yarn.lock
|
|
yarn --offline --frozen-lockfile --ignore-platform --ignore-scripts --no-progress --non-interactive install
|
|
|
|
runHook postConfigure
|
|
'';
|
|
|
|
installPhase = ''
|
|
runHook preInstall
|
|
|
|
yarn --offline --production install
|
|
|
|
mkdir -p "$out/lib/node_modules/pxder"
|
|
cp -r . "$out/lib/node_modules/pxder"
|
|
|
|
makeWrapper "${nodejs}/bin/node" "$out/bin/pxder" \
|
|
--add-flags "$out/lib/node_modules/pxder/bin/pxder"
|
|
|
|
runHook postInstall
|
|
'';
|
|
|
|
meta = {
|
|
description = "Download illusts from pixiv.net";
|
|
homepage = "https://github.com/Tsuk1ko/pxder";
|
|
license = lib.licenses.gpl3Plus;
|
|
mainProgram = "pxder";
|
|
maintainers = with lib.maintainers; [ vanilla ];
|
|
platforms = lib.platforms.all;
|
|
};
|
|
}
|