a19cd4ffb1
This reverts commit 65a333600d5c88a98d674f637d092807cfc12253. This wasn't tested for correctness with something like fodwatch [0], and should not have been (self-)merged so quickly, especially without further review. It also resulted in the breakage of at least one package [1] (and that's the one we know of and was caught). A few packages that were updated in between this commit and this revert were not reverted back to using `rev`, but other than that, this is a 1:1 revert. [0]: https://codeberg.org/raphaelr/fodwatch [1]: https://github.com/NixOS/nixpkgs/pull/396904 / 758551e4587d75882aebc21a04bee960418f8ce9
66 lines
1.3 KiB
Nix
66 lines
1.3 KiB
Nix
{
|
|
lib,
|
|
stdenv,
|
|
fetchFromGitHub,
|
|
janet,
|
|
}:
|
|
|
|
let
|
|
platformFiles = {
|
|
aarch64-darwin = "macos_config.janet";
|
|
aarch64-linux = "linux_config.janet";
|
|
x86_64-darwin = "macos_config.janet";
|
|
x86_64-linux = "linux_config.janet";
|
|
};
|
|
|
|
platformFile = platformFiles.${stdenv.hostPlatform.system};
|
|
|
|
in
|
|
stdenv.mkDerivation rec {
|
|
pname = "jpm";
|
|
version = "1.1.0";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "janet-lang";
|
|
repo = pname;
|
|
rev = "v${version}";
|
|
sha256 = "sha256-lPB4jew6RkJlDp8xOQ4YA9MkgLBImaBHcvv4WF/sLRc=";
|
|
};
|
|
|
|
# `auto-shebangs true` gives us a shebang line that points to janet inside the
|
|
# jpm bin folder
|
|
postPatch = ''
|
|
substituteInPlace configs/${platformFile} \
|
|
--replace 'auto-shebang true' 'auto-shebang false' \
|
|
--replace /usr/local $out
|
|
'';
|
|
|
|
dontConfigure = true;
|
|
|
|
buildInputs = [ janet ];
|
|
|
|
dontBuild = true;
|
|
|
|
installPhase = ''
|
|
runHook preInstall
|
|
|
|
mkdir -p $out/{lib/janet,share/man/man1}
|
|
|
|
janet bootstrap.janet configs/${platformFile}
|
|
|
|
runHook postInstall
|
|
'';
|
|
|
|
doInstallCheck = true;
|
|
|
|
installCheckPhase = ''
|
|
$out/bin/jpm help
|
|
'';
|
|
|
|
meta = janet.meta // {
|
|
description = "Janet Project Manager for the Janet programming language";
|
|
mainProgram = "jpm";
|
|
platforms = lib.attrNames platformFiles;
|
|
};
|
|
}
|