a19cd4ffb1
This reverts commit 65a333600d5c88a98d674f637d092807cfc12253. This wasn't tested for correctness with something like fodwatch [0], and should not have been (self-)merged so quickly, especially without further review. It also resulted in the breakage of at least one package [1] (and that's the one we know of and was caught). A few packages that were updated in between this commit and this revert were not reverted back to using `rev`, but other than that, this is a 1:1 revert. [0]: https://codeberg.org/raphaelr/fodwatch [1]: https://github.com/NixOS/nixpkgs/pull/396904 / 758551e4587d75882aebc21a04bee960418f8ce9
47 lines
1.4 KiB
Nix
47 lines
1.4 KiB
Nix
{
|
|
lib,
|
|
mkDerivation,
|
|
fetchFromGitHub,
|
|
standard-library,
|
|
}:
|
|
|
|
mkDerivation rec {
|
|
version = "0.2.0";
|
|
pname = "agda-categories";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "agda";
|
|
repo = "agda-categories";
|
|
rev = "v${version}";
|
|
sha256 = "sha256-GQuQxzYSQxAIVSJ1vf0blRC0juoxAqD1AHW66H/6NSk=";
|
|
};
|
|
|
|
postPatch = ''
|
|
# Remove this once agda-categories incorporates this fix or once Agda's
|
|
# versioning system gets an overhaul in general. Right now there is no middle
|
|
# ground between "no version constraint" and "exact match down to patch". We
|
|
# do not want to need to change this postPatch directive on each minor
|
|
# version update of the stdlib, so we get rid of the version constraint
|
|
# altogether.
|
|
sed -Ei 's/standard-library-[0-9.]+/standard-library/' agda-categories.agda-lib
|
|
|
|
# The Makefile of agda-categories uses git(1) instead of find(1) to
|
|
# determine the list of source files. We cannot use git, as $PWD will not
|
|
# be a valid Git working directory.
|
|
find src -name '*.agda' | sed -e 's|^src/[/]*|import |' -e 's|/|.|g' -e 's/.agda//' -e '/import Everything/d' | LC_COLLATE='C' sort > Everything.agda
|
|
'';
|
|
|
|
buildInputs = [ standard-library ];
|
|
|
|
meta = with lib; {
|
|
inherit (src.meta) homepage;
|
|
description = "New Categories library";
|
|
license = licenses.bsd3;
|
|
platforms = platforms.unix;
|
|
maintainers = with maintainers; [
|
|
alexarice
|
|
turion
|
|
];
|
|
};
|
|
}
|