a19cd4ffb1
This reverts commit 65a333600d5c88a98d674f637d092807cfc12253. This wasn't tested for correctness with something like fodwatch [0], and should not have been (self-)merged so quickly, especially without further review. It also resulted in the breakage of at least one package [1] (and that's the one we know of and was caught). A few packages that were updated in between this commit and this revert were not reverted back to using `rev`, but other than that, this is a 1:1 revert. [0]: https://codeberg.org/raphaelr/fodwatch [1]: https://github.com/NixOS/nixpkgs/pull/396904 / 758551e4587d75882aebc21a04bee960418f8ce9
55 lines
1.3 KiB
Nix
55 lines
1.3 KiB
Nix
{
|
|
lib,
|
|
stdenv,
|
|
fetchFromGitHub,
|
|
autoreconfHook,
|
|
drvName ? "geoip",
|
|
|
|
# in geoipDatabase, you can insert a package defining
|
|
# "${geoipDatabase}/share/GeoIP" e.g. geolite-legacy
|
|
geoipDatabase ? "/var/lib/geoip-databases",
|
|
}:
|
|
|
|
let
|
|
dataDir =
|
|
if lib.isDerivation geoipDatabase then "${toString geoipDatabase}/share/GeoIP" else geoipDatabase;
|
|
|
|
in
|
|
stdenv.mkDerivation rec {
|
|
pname = drvName;
|
|
version = "1.6.12";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "maxmind";
|
|
repo = "geoip-api-c";
|
|
rev = "v${version}";
|
|
sha256 = "0ixyp3h51alnncr17hqp1p0rlqz9w69nlhm60rbzjjz3vjx52ajv";
|
|
};
|
|
|
|
nativeBuildInputs = [ autoreconfHook ];
|
|
|
|
# Cross compilation shenanigans
|
|
configureFlags = lib.optionals (stdenv.hostPlatform != stdenv.buildPlatform) [
|
|
"ac_cv_func_malloc_0_nonnull=yes"
|
|
"ac_cv_func_realloc_0_nonnull=yes"
|
|
];
|
|
|
|
# Fix up the default data directory
|
|
postConfigure = ''
|
|
find . -name Makefile.in -exec sed -i -r 's#^pkgdatadir\s*=.+$#pkgdatadir = ${dataDir}#' {} \;
|
|
'';
|
|
|
|
passthru = { inherit dataDir; };
|
|
|
|
meta = with lib; {
|
|
description = "API for GeoIP/Geolocation databases";
|
|
maintainers = with maintainers; [
|
|
thoughtpolice
|
|
raskin
|
|
];
|
|
license = licenses.lgpl21;
|
|
platforms = platforms.unix;
|
|
homepage = "https://www.maxmind.com";
|
|
};
|
|
}
|