97eb7ee0da
ocamlPackages.base_quickcheck: 0.17.0 → 0.17.1 ocamlPackages.optcomp: 0.17.0 → 0.17.1 ocamlPackages.ppx_bench: 0.17.0 → 0.17.1 ocamlPackages.ppx_bin_prot: 0.17.0 → 0.17.1 ocamlPackages.ppx_deriving: 6.0.3 → 6.1.0 ocamlPackages.ppx_deriving_qcheck: 0.6 → 0.7 ocamlPackages.ppx_deriving_yaml: 0.3.0 → 0.4.1 ocamlPackages.ppx_deriving_yojson: 3.9.0 → 3.10.0 ocamlPackages.ppx_diff: 0.17.0 → 0.17.1 ocamlPackages.ppx_expect: 0.17.2 → 0.17.3 ocamlPackages.ppx_globalize: 0.17.0 → 0.17.2 ocamlPackages.ppx_inline_test: 0.17.0 → 0.17.1 ocamlPackages.ppx_let: 0.17.0 → 0.17.1 ocamlPackages.ppx_stable: 0.17.0 → 0.17.1 ocamlPackages.ppx_tydi: 0.17.0 → 0.17.1 ocamlPackages.ppx_typeprep_conv: 0.17.0 → 0.17.1 ocamlPackages.ppx_variants_conv: 0.17.0 → 0.17.1 ocamlPackages.sexp_conv: 0.17.0 → 0.17.1 ocamlPackages.sexp_message: 0.17.2 → 0.17.4 reason: 3.15.0 → 3.16.0 ocamlPackages.bisect_ppx: make compatible with ppxlib 0.36 ocamlPackages.config: make compatible with ppxlib 0.36 ocamlPackages.lwt_ppx: make compatible with ppxlib 0.36 ocamlPackages.melange: make compatible with ppxlib 0.36 ocamlPackages.ppx_bitstring: make compatible with ppxlib 0.36 ocamlPackages.ppx_repr: make compatible with ppxlib 0.36 ocamlPackages.bistro: mark as broken ocamlPackages.dream-html: mark as broken ocamlPackages.ocsigen-ppx-rpc: mark as broken ocamlPackages.ppx_deriving_cmdliner: mark as broken ocamlPackages.reason-react-ppx: mark as broken
67 lines
1.4 KiB
Nix
67 lines
1.4 KiB
Nix
{
|
|
lib,
|
|
buildDunePackage,
|
|
fetchFromGitHub,
|
|
ocaml,
|
|
ppxlib,
|
|
ounit,
|
|
ounit2,
|
|
ppx_deriving,
|
|
result,
|
|
yojson,
|
|
}:
|
|
|
|
let
|
|
param =
|
|
if lib.versionAtLeast ppxlib.version "0.36" then
|
|
{
|
|
version = "3.10.0";
|
|
sha256 = "sha256-Dy9egNpZdxsTPLo2mbpiFTMh5cYUXXOlOZLlQJuAK+E=";
|
|
checkInputs = [ ounit2 ];
|
|
}
|
|
else if lib.versionAtLeast ppxlib.version "0.30" then
|
|
{
|
|
version = "3.9.0";
|
|
sha256 = "sha256-0d6YcBkeFoHXffCYjLIIvruw8B9ZB6NbUijhTv9uyN8=";
|
|
checkInputs = [ ounit2 ];
|
|
}
|
|
else
|
|
{
|
|
version = "3.6.1";
|
|
sha256 = "1icz5h6p3pfj7my5gi7wxpflrb8c902dqa17f9w424njilnpyrbk";
|
|
checkInputs = [ ounit ];
|
|
propagatedBuildInputs = [ result ];
|
|
};
|
|
in
|
|
|
|
buildDunePackage rec {
|
|
pname = "ppx_deriving_yojson";
|
|
inherit (param) version;
|
|
|
|
minimalOCamlVersion = "4.07";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "ocaml-ppx";
|
|
repo = "ppx_deriving_yojson";
|
|
rev = "v${version}";
|
|
inherit (param) sha256;
|
|
};
|
|
|
|
propagatedBuildInputs = [
|
|
ppxlib
|
|
ppx_deriving
|
|
yojson
|
|
]
|
|
++ param.propagatedBuildInputs or [ ];
|
|
|
|
doCheck = lib.versionAtLeast ocaml.version "4.08";
|
|
inherit (param) checkInputs;
|
|
|
|
meta = {
|
|
description = "Yojson codec generator for OCaml >= 4.04";
|
|
inherit (src.meta) homepage;
|
|
license = lib.licenses.mit;
|
|
maintainers = [ lib.maintainers.vbgl ];
|
|
};
|
|
}
|