a19cd4ffb1
This reverts commit 65a333600d5c88a98d674f637d092807cfc12253. This wasn't tested for correctness with something like fodwatch [0], and should not have been (self-)merged so quickly, especially without further review. It also resulted in the breakage of at least one package [1] (and that's the one we know of and was caught). A few packages that were updated in between this commit and this revert were not reverted back to using `rev`, but other than that, this is a 1:1 revert. [0]: https://codeberg.org/raphaelr/fodwatch [1]: https://github.com/NixOS/nixpkgs/pull/396904 / 758551e4587d75882aebc21a04bee960418f8ce9
89 lines
2.2 KiB
Nix
89 lines
2.2 KiB
Nix
{
|
|
stdenv,
|
|
buildPythonPackage,
|
|
fetchFromGitHub,
|
|
python,
|
|
bootstrapped-pip,
|
|
lib,
|
|
pipInstallHook,
|
|
setuptoolsBuildHook,
|
|
}:
|
|
|
|
let
|
|
pname = "setuptools";
|
|
version = "44.0.0";
|
|
|
|
# Create an sdist of setuptools
|
|
sdist = stdenv.mkDerivation rec {
|
|
name = "${pname}-${version}-sdist.tar.gz";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "pypa";
|
|
repo = pname;
|
|
rev = "v${version}";
|
|
sha256 = "0z3q0qinyp1rmnxkw3y5f6nbsxhqlfq5k7skfrqa6ymb3zr009y1";
|
|
name = "${pname}-${version}-source";
|
|
};
|
|
|
|
patches = [
|
|
./tag-date.patch
|
|
];
|
|
|
|
buildPhase = ''
|
|
${python.pythonOnBuildForHost.interpreter} bootstrap.py
|
|
${python.pythonOnBuildForHost.interpreter} setup.py sdist --formats=gztar
|
|
|
|
# Here we untar the sdist and retar it in order to control the timestamps
|
|
# of all the files included
|
|
tar -xzf dist/${pname}-${version}.post0.tar.gz -C dist/
|
|
tar -czf dist/${name} -C dist/ --mtime="@$SOURCE_DATE_EPOCH" ${pname}-${version}.post0
|
|
'';
|
|
|
|
installPhase = ''
|
|
echo "Moving sdist..."
|
|
mv dist/${name} $out
|
|
'';
|
|
};
|
|
in
|
|
buildPythonPackage {
|
|
inherit pname version;
|
|
# Because of bootstrapping we don't use the setuptoolsBuildHook that comes with format="setuptools" directly.
|
|
# Instead, we override it to remove setuptools to avoid a circular dependency.
|
|
# The same is done for pip and the pipInstallHook.
|
|
format = "other";
|
|
|
|
src = sdist;
|
|
|
|
nativeBuildInputs = [
|
|
bootstrapped-pip
|
|
(pipInstallHook.override { pip = null; })
|
|
(setuptoolsBuildHook.override {
|
|
setuptools = null;
|
|
wheel = null;
|
|
})
|
|
];
|
|
|
|
preBuild = lib.optionalString (!stdenv.hostPlatform.isWindows) ''
|
|
export SETUPTOOLS_INSTALL_WINDOWS_SPECIFIC_FILES=0
|
|
'';
|
|
|
|
pipInstallFlags = [ "--ignore-installed" ];
|
|
|
|
# Adds setuptools to nativeBuildInputs causing infinite recursion.
|
|
catchConflicts = false;
|
|
|
|
# Requires pytest, causing infinite recursion.
|
|
doCheck = false;
|
|
|
|
meta = with lib; {
|
|
description = "Utilities to facilitate the installation of Python packages";
|
|
homepage = "https://pypi.python.org/pypi/setuptools";
|
|
license = with licenses; [
|
|
psfl
|
|
zpl20
|
|
];
|
|
platforms = python.meta.platforms;
|
|
priority = 10;
|
|
};
|
|
}
|