374e6bcc40
Format all Nix files using the officially approved formatter,
making the CI check introduced in the previous commit succeed:
nix-build ci -A fmt.check
This is the next step of the of the [implementation](https://github.com/NixOS/nixfmt/issues/153)
of the accepted [RFC 166](https://github.com/NixOS/rfcs/pull/166).
This commit will lead to merge conflicts for a number of PRs,
up to an estimated ~1100 (~33%) among the PRs with activity in the past 2
months, but that should be lower than what it would be without the previous
[partial treewide format](https://github.com/NixOS/nixpkgs/pull/322537).
Merge conflicts caused by this commit can now automatically be resolved while rebasing using the
[auto-rebase script](8616af08d9/maintainers/scripts/auto-rebase).
If you run into any problems regarding any of this, please reach out to the
[formatting team](https://nixos.org/community/teams/formatting/) by
pinging @NixOS/nix-formatting.
81 lines
1.5 KiB
Nix
81 lines
1.5 KiB
Nix
{
|
|
stdenv,
|
|
nodejs,
|
|
tree-sitter,
|
|
lib,
|
|
}:
|
|
|
|
# Build a parser grammar and put the resulting shared object in `$out/parser`
|
|
|
|
{
|
|
# language name
|
|
language,
|
|
version,
|
|
src,
|
|
location ? null,
|
|
generate ? false,
|
|
...
|
|
}@args:
|
|
|
|
stdenv.mkDerivation (
|
|
{
|
|
pname = "${language}-grammar";
|
|
|
|
inherit src version;
|
|
|
|
nativeBuildInputs = lib.optionals generate [
|
|
nodejs
|
|
tree-sitter
|
|
];
|
|
|
|
CFLAGS = [
|
|
"-Isrc"
|
|
"-O2"
|
|
];
|
|
CXXFLAGS = [
|
|
"-Isrc"
|
|
"-O2"
|
|
];
|
|
|
|
stripDebugList = [ "parser" ];
|
|
|
|
configurePhase =
|
|
lib.optionalString (location != null) ''
|
|
cd ${location}
|
|
''
|
|
+ lib.optionalString generate ''
|
|
tree-sitter generate
|
|
'';
|
|
|
|
# When both scanner.{c,cc} exist, we should not link both since they may be the same but in
|
|
# different languages. Just randomly prefer C++ if that happens.
|
|
buildPhase = ''
|
|
runHook preBuild
|
|
if [[ -e src/scanner.cc ]]; then
|
|
$CXX -fPIC -c src/scanner.cc -o scanner.o $CXXFLAGS
|
|
elif [[ -e src/scanner.c ]]; then
|
|
$CC -fPIC -c src/scanner.c -o scanner.o $CFLAGS
|
|
fi
|
|
$CC -fPIC -c src/parser.c -o parser.o $CFLAGS
|
|
rm -rf parser
|
|
$CXX -shared -o parser *.o
|
|
runHook postBuild
|
|
'';
|
|
|
|
installPhase = ''
|
|
runHook preInstall
|
|
mkdir $out
|
|
mv parser $out/
|
|
if [[ -d queries ]]; then
|
|
cp -r queries $out
|
|
fi
|
|
runHook postInstall
|
|
'';
|
|
}
|
|
// removeAttrs args [
|
|
"language"
|
|
"location"
|
|
"generate"
|
|
]
|
|
)
|