a19cd4ffb1
This reverts commit 65a333600d5c88a98d674f637d092807cfc12253. This wasn't tested for correctness with something like fodwatch [0], and should not have been (self-)merged so quickly, especially without further review. It also resulted in the breakage of at least one package [1] (and that's the one we know of and was caught). A few packages that were updated in between this commit and this revert were not reverted back to using `rev`, but other than that, this is a 1:1 revert. [0]: https://codeberg.org/raphaelr/fodwatch [1]: https://github.com/NixOS/nixpkgs/pull/396904 / 758551e4587d75882aebc21a04bee960418f8ce9
66 lines
1.3 KiB
Nix
66 lines
1.3 KiB
Nix
{
|
|
lib,
|
|
stdenv,
|
|
fetchFromGitHub,
|
|
autoreconfHook,
|
|
libpcap,
|
|
makeWrapper,
|
|
perlPackages,
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "arp-scan";
|
|
version = "1.10.0";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "royhills";
|
|
repo = "arp-scan";
|
|
rev = version;
|
|
sha256 = "sha256-BS+ItZd6cSMX92M6XGYrIeAiCB2iBdvbMvKdLfwawLQ=";
|
|
};
|
|
|
|
patches = [
|
|
./remove-install-exec-hook.patch
|
|
];
|
|
|
|
perlModules = with perlPackages; [
|
|
HTTPDate
|
|
HTTPMessage
|
|
LWP
|
|
TextCSV
|
|
URI
|
|
];
|
|
|
|
nativeBuildInputs = [
|
|
autoreconfHook
|
|
makeWrapper
|
|
];
|
|
buildInputs = [
|
|
perlPackages.perl
|
|
libpcap
|
|
];
|
|
|
|
postInstall = ''
|
|
for binary in get-{oui,iab}; do
|
|
wrapProgram "$out/bin/$binary" --set PERL5LIB "${perlPackages.makeFullPerlPath perlModules}"
|
|
done;
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "ARP scanning and fingerprinting tool";
|
|
longDescription = ''
|
|
Arp-scan is a command-line tool that uses the ARP protocol to discover
|
|
and fingerprint IP hosts on the local network.
|
|
'';
|
|
homepage = "https://github.com/royhills/arp-scan/wiki/arp-scan-User-Guide";
|
|
license = licenses.gpl3;
|
|
platforms = platforms.linux ++ platforms.darwin;
|
|
maintainers = with maintainers; [
|
|
bjornfor
|
|
mikoim
|
|
r-burns
|
|
];
|
|
mainProgram = "arp-scan";
|
|
};
|
|
}
|