a19cd4ffb1
This reverts commit 65a333600d5c88a98d674f637d092807cfc12253. This wasn't tested for correctness with something like fodwatch [0], and should not have been (self-)merged so quickly, especially without further review. It also resulted in the breakage of at least one package [1] (and that's the one we know of and was caught). A few packages that were updated in between this commit and this revert were not reverted back to using `rev`, but other than that, this is a 1:1 revert. [0]: https://codeberg.org/raphaelr/fodwatch [1]: https://github.com/NixOS/nixpkgs/pull/396904 / 758551e4587d75882aebc21a04bee960418f8ce9
55 lines
1.4 KiB
Nix
55 lines
1.4 KiB
Nix
{
|
|
lib,
|
|
buildGoModule,
|
|
fetchFromGitHub,
|
|
git,
|
|
}:
|
|
|
|
buildGoModule rec {
|
|
pname = "codecrafters-cli";
|
|
version = "36";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "codecrafters-io";
|
|
repo = "cli";
|
|
rev = "v${version}";
|
|
hash = "sha256-YgQPDc5BUIoEd44NLpRluxCKooW99qvcSTrFPm6qJKM=";
|
|
# A shortened git commit hash is part of the version output, and is
|
|
# needed at build time. Use the `.git` directory to retrieve the
|
|
# commit SHA, and remove the directory afterwards since it is not needed
|
|
# after that.
|
|
leaveDotGit = true;
|
|
postFetch = ''
|
|
git -C $"$out" rev-parse --short=7 HEAD > $out/COMMIT
|
|
rm -rf $out/.git
|
|
'';
|
|
};
|
|
|
|
vendorHash = "sha256-5t/bRx3mT66e/efjWbb527ZdKOn3qV3hroqiLwP180g=";
|
|
|
|
ldflags = [
|
|
"-s"
|
|
"-w"
|
|
"-X github.com/codecrafters-io/cli/internal/utils.Version=${version}"
|
|
];
|
|
|
|
# ldflags based on metadata from git
|
|
preBuild = ''
|
|
ldflags+=" -X github.com/codecrafters-io/cli/internal/utils.Commit=$(cat COMMIT)"
|
|
'';
|
|
|
|
# We need to disable tests because the tests for respecting .gitignore
|
|
# include setting up a global gitignore which doesn't work.
|
|
doCheck = false;
|
|
|
|
nativeBuildInputs = [ git ];
|
|
|
|
meta = with lib; {
|
|
description = "CodeCrafters CLI to run tests";
|
|
mainProgram = "codecrafters";
|
|
homepage = "https://github.com/codecrafters-io/cli";
|
|
maintainers = with maintainers; [ builditluc ];
|
|
license = licenses.mit;
|
|
};
|
|
}
|