nixpkgs/pkgs/by-name/ko/kord/package.nix
Ihar Hrachyshka dd0f03a56c treewide: remove usage of deprecated apple_sdk framework stubs
They are not doing anything right now. This is in preparation for their
complete removal from the tree.

Note: several changes that affect the derivation inputs (e.g. removal of
references to stub paths in build instructions) were left out. They will
be cleaned up the next iteration and will require special care.

Note: this PR is a result of a mix of ugly regex (not AST) based
automation and some manual labor. For reference, the regex automation
part was hacked in: https://github.com/booxter/nix-clean-apple_sdk

Signed-off-by: Ihar Hrachyshka <ihar.hrachyshka@gmail.com>
2025-04-19 20:28:20 -04:00

52 lines
1.4 KiB
Nix

{
lib,
stdenv,
fetchFromGitHub,
fetchpatch,
rustPlatform,
pkg-config,
alsa-lib,
}:
rustPlatform.buildRustPackage rec {
pname = "kord";
version = "0.6.1";
# kord depends on nightly features
RUSTC_BOOTSTRAP = 1;
src = fetchFromGitHub {
owner = "twitchax";
repo = "kord";
rev = "v${version}";
sha256 = "sha256-CeMh6yB4fGoxtGLbkQe4OMMvBM0jesyP+8JtU5kCP84=";
};
useFetchCargoVendor = true;
cargoHash = "sha256-DpZsi2eIhuetHnLLYGAvv871mbPfAIUevqBLaV8ljGA=";
patches = [
# Fixes build issues due to refactored Rust compiler feature annotations.
# Should be removable with the next release after v. 0.6.1.
(fetchpatch {
name = "fix-rust-features.patch";
url = "https://github.com/twitchax/kord/commit/fa9bb979b17d77f54812a915657c3121f76c5d82.patch";
hash = "sha256-XQu9P7372J2dHWzvpvbPtALS0Bh8EC+J1EyG3qlak2M=";
excludes = [ "Cargo.*" ];
})
];
nativeBuildInputs =
lib.optionals stdenv.hostPlatform.isLinux [ pkg-config ]
++ lib.optionals stdenv.hostPlatform.isDarwin [ rustPlatform.bindgenHook ];
buildInputs = lib.optionals stdenv.hostPlatform.isLinux [ alsa-lib ];
meta = with lib; {
description = "Music theory binary and library for Rust";
homepage = "https://github.com/twitchax/kord";
maintainers = with maintainers; [ kidsan ];
license = with licenses; [ mit ];
};
}